regexMatches

-- regexMatches :: String -> String -> [[String]]
on regexMatches(strRegex, strHay)
    set ca to current application
    set NSNotFound to a reference to 9.22337203685477E+18 + 5807 -- for some reason ca's NSNotFound doesn't work
    set oRgx to ca's NSRegularExpression's regularExpressionWithPattern:strRegex ¬
        options:((ca's NSRegularExpressionAnchorsMatchLines as integer)) |error|:(missing value)
    set oString to ca's NSString's stringWithString:strHay
    set oMatches to oRgx's matchesInString:oString options:0 range:{location:0, |length|:oString's |length|()}

    set xs to {}
    repeat with omatch in oMatches
        set intMax to ((numberOfRanges of omatch) as integer) - 1

        set subs to {}
        repeat with i from 0 to intMax
            tell (omatch's rangeAtIndex:i)
                set intfrom to its location
                if intfrom ≠ NSNotFound then
                    set end of subs to text (intfrom + 1) thru (intfrom + (its |length|)) of strHay
                else
                    set end of subs to missing value
                end if
            end tell
        end repeat
        set end of xs to subs

    end repeat
    return xs
end regexMatches