Excel VBA: Print Current Page Containing Cursor Only

'EXCEL VBA: Print current page containing cursor only

Sub PrintPageContainingCursor()
'Leo Heuser, 4 Feb. 2004
Dim Hpb As HPageBreak
Dim HorizPagebreak As Long
Dim NumberOfHorizPages As Long
Dim NumberOfVertiPages As Long
Dim PageNumber As Long
Dim Vpb As VPageBreak
Dim VertiPagebreak As Long

    With ActiveSheet
        NumberOfHorizPages = .HPageBreaks.Count + 1
        NumberOfVertiPages = .VPageBreaks.Count + 1

        For Each Vpb In .VPageBreaks
            If Vpb.Location.Column < ActiveCell.Column Then
                VertiPagebreak = VertiPagebreak + 1
            End If
        Next Vpb

        For Each Hpb In .HPageBreaks
            If Hpb.Location.Row < ActiveCell.Row Then
                HorizPagebreak = HorizPagebreak + 1
            End If
        Next Hpb

        If .PageSetup.Order = xlOverThenDown Then
            PageNumber = NumberOfVertiPages * HorizPagebreak + VertiPagebreak + 1
        Else
            PageNumber = NumberOfHorizPages * VertiPagebreak + HorizPagebreak + 1
        End If

        .PrintOut , from:=PageNumber, to:=PageNumber, copies:=1
    End With
End Sub