static function PipeBomb_Explosion_BuildVisualization(XComGameState VisualizeGameState)
{
    local XComGameStateContext_Ability  AbilityContext;
    local X2Action_PlayEffect           EffectAction;
    local VisualizationActionMetadata   ActionMetadata;
    local X2Action_Delay                DelayAction;
    local X2Action_StartStopSound       SoundAction;
    local XComGameState_Unit            UnitState;
    local XComGameStateVisualizationMgr VisMgr;
    local Array<X2Action>               arrFoundActions;

    local X2Action_WaitForAbilityEffect WaitAction;
    local vector                        DukesPos, OppositePos, Diff;
    local X2Action_MoveTurn             MoveTurnAction;
    local int i;

    TypicalAbility_BuildVisualization(VisualizeGameState);

    //  Duke Unit State
    AbilityContext = XComGameStateContext_Ability(VisualizeGameState.GetContext());
    UnitState = XComGameState_Unit(`XCOMHISTORY.GetGameStateForObjectID(AbilityContext.InputContext.SourceObject.ObjectID));

    ActionMetadata.StateObject_NewState = UnitState;
    ActionMetadata.VisualizeActor = UnitState.GetVisualizer();

    VisMgr = `XCOMVISUALIZATIONMGR;

    //  Calculate the opposite looking direction relative to the explosion
    DukesPos = `XWORLD.GetPositionFromTileCoordinates(UnitState.TileLocation);
    Diff = DukesPos - AbilityContext.InputContext.TargetLocations[0];
    OppositePos = DukesPos + Diff;

    //  Make duke turn his back to the explosion
    VisMgr.GetNodesOfType(VisMgr.BuildVisTree, class'X2Action_ExitCover', arrFoundActions);
    if (arrFoundActions.Length > 0)
    {
        //X2Action_ExitCover(arrFoundActions[0]).bSkipExitCoverVisualization = true; //breaks ability animation and makes the soldier shoot primary weapon. wtf???
        X2Action_ExitCover(arrFoundActions[0]).TargetLocation = OppositePos;

        MoveTurnAction = X2Action_MoveTurn(class'X2Action_MoveTurn'.static.AddToVisualizationTree(ActionMetadata, AbilityContext, true, ArrFoundActions[0]));
        MoveTurnAction.m_vFacePoint = OppositePos;
    }

    //  make sure camera always looks at duke from the front
    VisMgr.GetNodesOfType(VisMgr.BuildVisTree, class'X2Action_StartCinescriptCamera', arrFoundActions);
    if (arrFoundActions.Length > 0)
    {
        `LOG("Focus points:" @ X2Action_StartCinescriptCamera(arrFoundActions[0]).CinescriptCamera.VisFocusPoints.Length,, 'IRIDUKE');
        for (i = 0; i < X2Action_StartCinescriptCamera(arrFoundActions[0]).CinescriptCamera.VisFocusPoints.Length; i++)
        {
            `LOG("Focus point:" @ X2Action_StartCinescriptCamera(arrFoundActions[0]).CinescriptCamera.VisFocusPoints[i].vFocusPoint,, 'IRIDUKE');
        }
    }
    else
    {
        `LOG("Could not find camera action.",, 'IRIDUKE');
    }

    //  make sure the Duke keeps looking in the opposite direction. Otherwise he snap turns before the ability camera exits.
    VisMgr.GetNodesOfType(VisMgr.BuildVisTree, class'X2Action_EnterCover', arrFoundActions);
    if (arrFoundActions.Length > 0)
    {
        //  add a delay action to the parent of the Enter Cover action
        DelayAction = X2Action_Delay(class'X2Action_Delay'.static.AddToVisualizationTree(ActionMetadata, AbilityContext, false, arrFoundActions[0].ParentActions[0]));
        DelayAction.Duration = 2.5f;

        //  reparent Enter Cover to the Delay Action
        VisMgr.DisconnectAction(arrFoundActions[0]);    //  if it is, then it is the Psi Pinions action. We disconnect it from its parents
        VisMgr.ConnectAction(arrFoundActions[0], VisMgr.BuildVisTree,, DelayAction);    //  and set it as a child of the Wait Action so that it comes after it
    }

    // use Vis Manager to find the Fire Action so we can parent the explosion FX to it
    arrFoundActions.Length = 0;
    VisMgr.GetNodesOfType(VisMgr.BuildVisTree, class'X2Action_Fire', arrFoundActions);

    //  there should be only one Fire Action, so we use the first one found
    if (arrFoundActions.Length > 0)
    {
        WaitAction = X2Action_WaitForAbilityEffect(class'X2Action_WaitForAbilityEffect'.static.AddToVisualizationTree(ActionMetadata, AbilityContext, true, arrFoundActions[0]));

        //Do the detonation
        EffectAction = X2Action_PlayEffect(class'X2Action_PlayEffect'.static.AddToVisualizationTree(ActionMetadata, AbilityContext, false, WaitAction));
        EffectAction.EffectName = "IRI_Duke.PS_PipeBombExplosion";
        EffectAction.EffectLocation = AbilityContext.InputContext.TargetLocations[0];
        EffectAction.EffectRotation = Rotator(vect(0, 0, 1));
        EffectAction.bWaitForCompletion = false;
        EffectAction.bWaitForCameraArrival = false;
        EffectAction.bWaitForCameraCompletion = false;
        EffectAction.CenterCameraOnEffectDuration = 2.0f;
        EffectAction.RevealFOWRadius = class'XComWorldData'.const.WORLD_StepSize * 5.0f;

        SoundAction = X2Action_StartStopSound(class'X2Action_StartStopSound'.static.AddToVisualizationTree(ActionMetadata, AbilityContext, false, WaitAction));
        SoundAction.Sound = new class'SoundCue';
        SoundAction.Sound.AkEventOverride = AkEvent'SoundX2CharacterFX.Proximity_Mine_Explosion';
        SoundAction.bIsPositional = true;
        SoundAction.vWorldPosition = AbilityContext.InputContext.TargetLocations[0];

        //Keep the camera there after things blow up
        //DelayAction = X2Action_Delay(class'X2Action_Delay'.static.AddToVisualizationTree(ActionMetadata, AbilityContext, true, EffectAction));
        //DelayAction.Duration = 3;
    }
}