cogl 1.22.2+10+g3baa2d7a with fglrx/catalyst patch

# $Id: PKGBUILD 274756 2016-08-27 14:41:34Z heftig $
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgname=cogl
pkgver=1.22.2+10+g3baa2d7a
pkgrel=1.1
pkgdesc="An object oriented GL/GLES Abstraction/Utility Layer"
arch=('i686' 'x86_64')
url="http://www.clutter-project.org/"
license=('GPL2')
depends=('mesa' 'libdrm' 'libxext' 'libxdamage' 'libxcomposite' 'gdk-pixbuf2' 'pango' 'libxrandr')
makedepends=('gobject-introspection' 'git' 'gtk-doc')
options=(!emptydirs)
_commit=3baa2d7a65bc94b74d6e49392fe14e4ed65724a5  # cogl-1.22
source=("git+https://git.gnome.org/browse/cogl#commit=$_commit"
        cogl-driver-glsl_v2.patch)
sha256sums=('SKIP'
            '449c9bcdc5cec45d0cb928b6456fb37eb26f15a964fc68de9bdb5f6c23182f1e')

pkgver() {
  cd $pkgname
  git describe | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname

  patch -Np1 -i ../cogl-driver-glsl_v2.patch

  ./configure --prefix=/usr \
    --enable-gles{1,2} \
    --enable-{kms,wayland}-egl-platform \
    --enable-wayland-egl-server

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make -j1
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}









cogl-driver-glsl_v2.patch
------------------------------------
--- 1222/cogl/driver/gl/gl/cogl-driver-gl.c 2016-10-17 18:16:05.638995324 +0200
+++ 1222b/cogl/driver/gl/gl/cogl-driver-gl.c    2016-10-17 18:23:58.703175772 +0200
@@ -416,9 +416,14 @@
                                       &ctx->glsl_minor);
     }

-  if (COGL_CHECK_GL_VERSION (ctx->glsl_major, ctx->glsl_minor, 1, 2))
-    /* We want to use version 120 if it is available so that the
-     * gl_PointCoord can be used. */
+
+  if (COGL_CHECK_GL_VERSION (ctx->glsl_major, ctx->glsl_minor, 1, 5))
+    ctx->glsl_version_to_use = 150;
+  else if (COGL_CHECK_GL_VERSION (ctx->glsl_major, ctx->glsl_minor, 1, 4))
+    ctx->glsl_version_to_use = 140;
+  else if (COGL_CHECK_GL_VERSION (ctx->glsl_major, ctx->glsl_minor, 1, 3))
+    ctx->glsl_version_to_use = 130;
+  else if (COGL_CHECK_GL_VERSION (ctx->glsl_major, ctx->glsl_minor, 1, 2))
     ctx->glsl_version_to_use = 120;
   else
     ctx->glsl_version_to_use = 110;