spawnPlayer()
{
	self notify("spawned");
	self notify("end_respawn");

	resettimeout();

	self.sessionteam = self.pers["team"];
	self.sessionstate = "playing";
	self.spectatorclient = -1;
	self.archivetime = 0;
	self.friendlydamage = undefined;

	spawnpointname = "mp_teamdeathmatch_spawn";
	if( self.pers["team"] == "allies" && level.hunterSpawns.size > 0 )
		spawnpointname = "mp_brax_hunter_spawn";
	else if( self.pers["team"] == "axis" && level.zombieSpawns.size > 0 )
		spawnpointname = "mp_brax_zombie_spawn";

	spawnpoints = getentarray(spawnpointname, "classname");
	if( !spawnpoints.size )
	{
		spawnpointname = "mp_deathmatch_spawn";
		spawnpoints = getentarray(spawnpointname, "classname");
	}
	if( self.pers["team"] == "allies" )
		spawnpoint = maps\mp\gametypes\_spawnlogic::getSpawnpoint_NearTeam(spawnpoints);
	else
		spawnpoint = getZomSpawn( spawnpoints );

	if(isDefined(spawnpoint))
		self spawn(spawnpoint.origin, spawnpoint.angles);
	else
		maps\mp\_utility::error("NO " + spawnpointname + " SPAWNPOINTS IN MAP");

	//	BraX
/*
	if( level.map == "o'fuck" || level.map == "o'shit" )
	{
		trace = bulletTrace( self.origin + (0,0,20), self.origin - (0,0,2048), false, self );
		self setOrigin( trace["position"] );
	}
	*/
	if( self getWeaponSlotWeapon("primary") == "none" && self getWeaponSlotWeapon("pistol") == "none" )
		self giveWeapon( self.pers["weapon"] );

	self giveMaxAmmo(self.pers["weapon"]);
	self setSpawnWeapon(self.pers["weapon"]);

	self thread maps\mp\gametypes\_zombie::spawnPlayer();
	if(self.pers["team"] == "allies")
		self setClientCvar("cg_objectiveText", "Hunt ^1Zombies^7 or be hunted!");
	else if(self.pers["team"] == "axis")
		self setClientCvar("cg_objectiveText", "Eat some human's brains!");

	if(self.pers["team"] == "allies")
	{
		self.headicon = game["headicon_allies"];
		self.headiconteam = "allies";
		self.statusicon = "gfx/hud/hud@hunter.dds";
	}
	else
	{
		self.headicon = game["headicon_axis"];
		self.headiconteam = "axis";
		self.statusicon = "gfx/hud/hud@zombie.dds";
	}
}