# File opening
SetMTMode(5, 6)
SetMemoryMax(512)
AVISource("D:\castlevania.avi", audio=true).ConvertToYV12(interlaced=true)

Trim(0, 4109)

SetMTMode(2)

MT("""QTGMC(Preset="Placebo",\
      NoiseRemove=1, BT=5, Sigma=2, NoiseBypass=0, NoiseRestore=0,\
       Sharpness=0.0,\
      EdiMode="NNEDI3", NNSize=3, NNeurons=4, EdiQual=2,\
      Border=true, SubPel=4,\
      tr0=2, tr1=2, tr2=1)\
      .SelectEven()""", threads=1, overlap=16, splitvertical=false) # 60 fps

# Tries to dehalo the typical "analogic haloing"
dehalo_alpha(rx=2.0, ry=2.0, brightstr=1.0, darkstr=0.8)

# Crop
crop(8, 8, -8, -8)

# Resize
Spline36Resize(640, 360)

# Sharpen
MT("""LSFmod(defaults="slow", strength=80, ss_x=2.0, ss_y=2.0, soothe=false)""", threads=6, overlap=16)

# Resize x2
nnedi3_rpow2(rfactor=2, nsize=0, nns=4, qual=2, pscrn=false, cshift="Spline64Resize")

# Gamma
MT("hdragc(coef_gain=0.32, max_gain=0.32, coef_sat=1.17, max_sat=1.17, avg_lum=-128, protect=2)", threads=6, overlap=16)

# Motion compensated sharpening
SetMTMode(5)

source = last
sharp0 = source.sharpen(0.6)
sharpD = mt_makediff(source,sharp0)
zeroD = sharpD.mt_lut("x",Y=-128)

sup1   = source.MSuper(pel=2,sharp=2)
sup2   = sharpD.MSuper(pel=2,sharp=2,levels=1)
bv1    = sup1.MAnalyse(isb=true, delta=1)
fv1    = sup1.MAnalyse(isb=false,delta=1)
bv2    = sup1.MAnalyse(isb=true, delta=2)
fv2    = sup1.MAnalyse(isb=false,delta=2)

sharpD.MDegrain2(sup2,bv1,fv1,bv2,fv2)
source.mt_makediff(last,U=2,V=2)

# "crops out bad luma/chroma values, and thus helps compression"
Limiter()

FadeOut(100)