'Fire particle Test
' NB: Bitmaps in DefData by matibee
SuperStrict

SeedRnd MilliSecs()

Graphics 800, 600

AutoMidHandle(True)

RestoreData Cloud001_png
Global smoke:TImage = DataToImage()

RestoreData Flame_png
Global flame:TImage = DataToImage()

RestoreData Particle005_png
Global ember:TImage = DataToImage()

Global intervalSmoke# = 4
Global intervalSmokeCounter# = intervalSmoke

Global intervalEmber# = 20
Global intervalEmberCounter# = intervalEmber

Global intervalClsColor# = 200
Global intervalClsColorCounter% = intervalClsColor

Global fps_counter% = 0
Global update_frequency% = 5
Global fps_milli% = MilliSecs()
Global fps%

SetClsColor (0, 0, 0)

Repeat
    Update()
    Render()
    Delay(1)
Until AppTerminate() Or KeyHit(KEY_ESCAPE)

Function Update()
    If intervalClsColorCounter> 0
        intervalClsColorCounter:-1
        If intervalClsColorCounter <= 0
            SetClsColor (Rand(255), Rand(255), Rand(255))
            intervalClsColorCounter = intervalClsColor
        EndIf
    EndIf

    Local x# = 400 + Rand(-100,100)
    Local y# = 550

    For Local i% = 0 To 1
        CreateFlameParticle(x, y)
    Next
    CreateSmokeParticle(x, y - 140)
    CreateEmberParticle(x, y - 150)

    TParticle.UpdateAll()
End Function

Function Render()
    Cls
        TParticle.DrawAll(True)
        TParticle.DrawAll(False)
        SetColor 255, 255, 255
        SetAlpha 1
        SetBlend ALPHABLEND
        SetScale 1, 1
        SetRotation 0
        Local tx%, ty% = 10
        Local gap% = 15
        DrawText "FPS:"+fps, tx, ty
        ty:+gap
        DrawText "No. of Particles = " + TParticle.list.Count(), tx, ty
        ty:+gap
        DrawText "Changing Cls Colour in = "+ intervalClsColorCounter, tx, ty


        ' FPS counter
        fps_counter:+1
        If fps_counter = update_frequency
             fps = 1000 / Float(((MilliSecs() - fps_milli)) / update_frequency)
             fps_milli = MilliSecs()
             fps_counter = 0
        EndIf
    Flip 1
End Function


Function CreateEmberParticle(x#, y#)
    If intervalEmberCounter> 0
        intervalEmberCounter:-1
        If intervalEmberCounter<= 0
            Local p:TParticle = TParticle.Create(ember, x, y)
            p.SetRGB(255, 128, 0)
            p.dy = Rnd(-2, -1)
            p.rotationSpeed = Rnd(-.5, .5)
            p.gravityY = 0.01
            p.scale = Rnd(0.03, 0.05)
            p.SetFade(10, 60, 40)
            p.rotation = Rnd(360)
            p.blend = LIGHTBLEND

            intervalEmberCounter = intervalEmber
        EndIf
    EndIf
End Function

Function CreateSmokeParticle(x#, y#)
    If intervalSmokeCounter > 0
        intervalSmokeCounter:-1
        If intervalSmokeCounter <= 0
            Local p:TParticle = TParticle.Create(smoke, x, y)
            p.SetRGB(128, 128, 128)
            p.dy = Rnd(-1, 0)
            p.rotationSpeed = Rnd(-.5, .5)
            p.gravityY = -0.02
            p.scale = 1 + Rnd(.25)
            p.SetFade(80, 10, 80)
            p.maxAlpha = .1
            p.rotation = Rnd(360)
            p.blend = ALPHABLEND

            intervalSmokeCounter = intervalSmoke
        EndIf
    EndIf
End Function

Function CreateFlameParticle(x#, y#)
    Local p:TParticle = TParticle.Create(flame, x, y)
    p.SetRGB(255, 80, 0)
    p.dy = Rnd(-1, 0)
    p.rotationSpeed = Rnd(-1, 1)
    p.gravityY = -0.02
    p.scaleSpeed = -0.001
    p.scale = .35
    p.SetFade(30, 30, 35)
    p.rotation = Rnd(360)
    p.blend = LIGHTBLEND
End Function

Type TParticle
    Field x#, y#
    Field dx#, dy#
    Field gravityX#, gravityY#
    Field rotation#
    Field rotationSpeed#
    Field scale# = 1
    Field scaleSpeed#
    Field alpha# = 1
    Field maxAlpha# = 1
    Field image:TImage
    Field blend% = ALPHABLEND
    Field r% = 255, g% = 255, b% = 255
    Field fadeIn# = 0
    Field fadeSustainCounter# = 0
    Field fadeCounter# = 0
    Field fadeInLength# = 0
    Field fadeLength#=0

    Global list:TList

    Function Create:TParticle(image:TImage, x#, y#)
        If list = Null Then list = New TList
        Local p:TParticle = New TParticle
        p.image = image
        p.x = x
        p.y = y
        list.AddLast p
        Return p
    End Function

    Function DrawAll(drawmask:Int = False)
        If Not list Return
        For Local p:TParticle = EachIn list
            p.Draw(drawmask)
        Next
    End Function

    Function UpdateAll()
        If Not list Return
        For Local p:TParticle = EachIn list
            p.Update()
        Next
    End Function

    Method SetFade(theFadeInLength%, theSustain%, theFadeLength%)
        If theFadeInLength > 0 Then
            fadeIn = 1
            alpha = 0
        Else
            fadeIn = 0
        EndIf
        fadeInLength = theFadeInLength
        fadeSustainCounter = theSustain
        fadeLength = theFadeLength

        If fadeIn = 0 Then
            fadeCounter = fadeLength
        Else
            fadeCounter = 0
        EndIf
    End Method

    Method Update()
        x :+ dx
        y :+ dy
        If gravityY <> 0
            dy :+ gravityY
        EndIf
        If gravityX <> 0
            dx :+ gravityX
        EndIf
        If rotationSpeed <> 0
            rotation :+ rotationSpeed
        EndIf
        If scaleSpeed <> 0
            scale :+ scaleSpeed
            If scale < 0 Then scale = 0
        EndIf

        If fadeIn
            fadeCounter:+1
            If fadeCounter >= fadeInLength
                fadeCounter = fadeLength
                fadeIn = 0
                alpha = maxAlpha
            End If
        Else If fadeSustainCounter > 0
            fadeSustainCounter:-1
            If fadeSustainCounter <= 0 Then
                fadeSustainCounter = 0
                fadeCounter = fadeLength
            End If
        Else If fadeCounter > 0 Then
            fadeCounter:-1
            If fadeCounter <= 0 Then
                alpha = 0
                Kill()
            EndIf
        EndIf
    End Method

    Method Kill()
        list.Remove(Self)
    End Method

    Method Draw(drawmask:Int = False)
        If fadeCounter > 0 Then
            If fadeIn Then
                alpha = fadeCounter / fadeInLength
                If alpha > maxAlpha Then alpha = maxAlpha
            Else
                alpha = fadeCounter / fadeLength
                If alpha > maxAlpha Then alpha = maxAlpha
            EndIf
        EndIf
        SetAlpha alpha
        SetScale scale, scale
        SetRotation rotation
        If drawmask Then
            SetColor 0, 0, 0
            SetBlend ALPHABLEND
            DrawImage image, x, y
        Else
            SetColor r, g, b
            SetBlend blend
            DrawImage image, x, y
        EndIf
    End Method

    Method SetRGB(r%, g%, b%)
        Self.r = r
        Self.g = g
        Self.b = b
    End Method

End Type

'graphics

Function DataToImage:TImage( flags:Int = -1 )
    Local myhex$ = "0123456789ABCDEF"
    Local w:Int, h:Int, line$
    ReadData w
    ReadData h
    Local img:TImage = CreateImage( w, h, 1, flags )
    Local tp:TPixmap = LockImage( img )
    For Local y:Int = 0 To h - 1
        ReadData line$
        For Local x:Int = 0 To w - 1
            Local word$ = Mid$( line$, x * 8 + 1, 8 )
            Local pixel:Int = 0
            Local shift:Int = 28
            For Local i:Int = 1 To 8
                pixel :+ (Instr( myhex$, Mid$(word$, i, 1) ) - 1) Shl shift
                shift :- 4
            Next
            WritePixel( tp, x, y, pixel )
        Next
    Next
    UnlockImage( img )
    Return img
End Function