ttf-ia-writer-fonts-git PKGBUILD

# Maintainer: Zirak <zirakertan at gmail dot com>
# Contributor: Stephen Brown II <Stephen dot Brown2 at gmail dot com>
pkgbase=ttf-ia-writer-fonts-git
pkgdesc="TTF iA Writer fonts collection"
pkgname=('ttf-ia-writer-duospace-git' 'ttf-ia-writer-mono-git' 'ttf-ia-writer-duo-git' 'ttf-ia-writer-quattro-git')
pkgver=r38.ba31f88
pkgrel=1
_project_name="iA-Fonts"
url="https://github.com/iaolo/$_project_name"
arch=('any')
license=('custom')
_tarname=iA-Fonts-$_commitid
source=("$_project_name::git+$url.git")
sha256sums=('SKIP')
makedepends=('git')


pkgver() {
  cd $_project_name
  ( set -o pipefail
    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}


package_ttf-ia-writer-duospace-git() {
  pkgdesc="iA Writer Duospace font (TTF)"
  url="https://ia.net/topics/in-search-of-the-perfect-writing-font"
  conflicts=('ttf-ia-writer-duospace')
  provides=('ttf-ia-writer-duospace')
  cd "$_project_name/iA Writer Duospace"
  install -Dt "$pkgdir/usr/share/fonts/TTF" -m644 "TTF (PC)"/*.ttf
  install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_ttf-ia-writer-mono-git() {
  pkgdesc="iA Writer Mono font"
  url="https://ia.net/writer/blog/a-typographic-christmas"
  cd "$_project_name/iA Writer Mono"
  for variation in "Static" "Variable"; do
    install -Dt "$pkgdir/usr/share/fonts/TTF" -m644 $variation/*.ttf
  done
  install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_ttf-ia-writer-duo-git() {
  pkgdesc="iA Writer Duo font"
  url="https://ia.net/writer/blog/a-typographic-christmas"
  cd "$_project_name/iA Writer Duo"
  for variation in "Static" "Variable"; do
    install -Dt "$pkgdir/usr/share/fonts/TTF" -m644 $variation/*.ttf
  done
  install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_ttf-ia-writer-quattro-git() {
  pkgdesc="iA Writer Quattro font"
  url="https://ia.net/writer/blog/a-typographic-christmas"
  cd "$_project_name/iA Writer Quattro"
  for variation in "Static" "Variable"; do
    install -Dt "$pkgdir/usr/share/fonts/TTF" -m644 $variation/*.ttf
  done
  install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}