DESCRIPTION = "GSTREAMER Plugin (gstreamer-ti) for TI ARM/DSP processors, DDOMPE branch"
DEPENDS = "ti-dmai gstreamer gst-plugins-base gst-plugins-good gst-plugins-ugly"
PROVIDES = "gstreamer-ti"
PV = "svnr${SRCREV}"

SRC_URI = "\
  svn://gforge.ti.com/svn/gstreamer_ti/branches/BRANCH_DDOMPE/gstreamer_ti/ti_build;module=ticodecplugin;proto=https;user=anonymous;pswd='' \
  file://gstreamer-ti-rc.sh \
"
SRC_URI_append_omap3 = " \
  file://gstreamer-ti-ddompe-add-omapfb.patch \
"
# use local loadmodules.sh for these platform
# TODO: must be removed onces these loadmodules goes in gstreamer.ti.com
SRC_URI_append_dm365 = " file://loadmodules.sh"
SRC_URI_append_omapl137 = " file://loadmodules.sh"
SRC_URI_append_omapl138 = " file://loadmodules.sh "
SRC_URI_append_omap3 = " file://loadmodules.sh "

S = "${WORKDIR}/ticodecplugin"
SRCREV = "851"

EXTRA_OECONF_dm6446 = "--with-preset=dm6446"
EXTRA_OECONF_dm6467 = "--with-preset=dm6447"
EXTRA_OECONF_omap3 = "--with-preset=omap35x"
EXTRA_OECONF_dm365 = "--with-preset=dm365"
EXTRA_OECONF_dm355 = "--with-preset=dm355"
EXTRA_OECONF_omapl138 = "--with-preset=omapl138"

do_configure_prepend() {
    # XDCPATH fixups
    sed -i -e 's:(LINK_INSTALL_DIR)/packages:(LINK_XDC_ROOT):g' ${S}/src/Makefile.am
    sed -i -e 's:(XDC_USER_PATH);:(XDC_USER_PATH);$(EDMA3_LLD_INSTALL_DIR)/packages;$(C6ACCEL_INSTALL_DIR)/soc/c6accelw;$(C6ACCEL_INSTALL_DIR)/soc/packages:g' ${S}/src/Makefile.am
}
do_install_prepend() {
    # keep gstreamer-ti.inc's do_install_prepend happy
    mkdir -p ${WORKDIR}/gstreamer_ti/gstreamer_demo/shared
}

# add ${OE_TOP}/recipes/ti/gstreamer-ti to FILESPATH for inclusion of its gstreamer-ti-rc.sh
FILESPATH =. "${OE_TOP}/recipes/ti/gstreamer-ti:"
# add our local path to override for loadmodules.sh
FILESPATHPKG =. "gstreamer-ti:"

pkg_postinst_gstreamer-ti-demo-script () {
        ln -sf ${installdir}/ti-codecs-server/* ${installdir}/gst/${PLATFORM}/
}

require recipes/ti/gstreamer-ti.inc

# ti-dspbios-tree needs to be in includes - not clear where the other INCLUDES are setup
CPPFLAGS_append = " -I${BIOS_INSTALL_DIR}/packages"