S EnableGroup NoTanks off

S EnableGroup Force off

?Force T(500) effectTime($ChallengeAura) == 0 : Cast $ChallengeAura

?Force T(500) effectTime($SigelForce) == 0 : Cast $SigelForce

?Sounds @CreatureSay type == 2 and actor ~= me : PlaySound whisper
// ##################################################################################################
// ############################### L2Ranger Harnak Tank Script ######################################
// ##################################################################################################
// ##################################### Created By: Mr_K ###########################################
// ##################################################################################################

// ##################################################################################################
// ### PM YOURSELF "set room center"   To define center of the room.                              ###
// ### PM YOURSELF "set my location"   To define where you want to stand.                         ###
// ### PM YOURSELF "clear my location" To clear standing location.                                ###
// ###                                                                                            ###
// ### NOTE: You must define a room center to properly target mobs.                               ###
// ### NOTE: Once you define a standing location, you will periodically move towards it.          ###
// ##################################################################################################

// ##################################################################################################
// ### FEATURES:                                                                                  ###
// ### * Targets mobs within a set area (center point defined by the player)  .                   ###
// ### * Moves to a preferred location periodically (defined by the player).                      ###
// ### * Chain strikes harnak sniper mobs outside of AOE hate range.                              ###
// ### * Casts aoe hate on a fixed timer.                                                         ###
// ### * Casts single target hate on mobs attacking party members and outside of aoe hate range.  ###
// ### * Casts ultimate defense when player hp falls below 20%.                                   ###
// ### * Casts party ultimate defense when player hp falls below 25%.                             ###
// ### * Casts ChainGalaxy/GustBlade/ShieldImpact/ShieldWave when mobs in AOE range.              ###
// ##################################################################################################

// *************************************** Variables ************************************************

// Group is off by default.
L EnableGroup HarnakTank off

// Keep track of center position.
V: HarnakTank_X, HarnakTank_Y

// Action lockout variables.
V: HarnakTank_ActionStop, HarnakTank_ActionStopTime
L Assign HarnakTank_ActionStopTime = 250;
L Assign HarnakTank_ActionStop = 0;

// *************************************** Functions ************************************************

// Figure out if we have a center position stored.
F: HarnakTank_MyLocation = HarnakTank_X and HarnakTank_Y

// Find out if a target object is in range of specified distance.
F: HarnakTank_InRange(object, distance) = distance(object) < distance

// Find out if target object is in room (or close).
F: HarnakTank_InRoom(object) = inRange(1114, object) and \
    zdiff(object) < 250

// Find out if target object is in aoe range.
F: HarnakTank_AoeRange(object) = HarnakTank_InRange(object, 200) and HarnakTank_InRoom(object)

// Find out if player can perform an action (no casting, lockout, or disabled).
F: HarnakTank_CanPerformAction =  now > HarnakTank_ActionStop and not nowCasting and alive(me) and \
                                  not isMedused(me) and not isSilenced(me)                     and \
                                  not isStunned(me) and not isTranced (me)

// Find out if object is skill we can use (not on cooldown and can perform action).
F: HarnakTank_CanUseSkill(object) = not skillCoolTime(object) and HarnakTank_CanPerformAction

// Find out if object is a valid object, alive, attackable, and can see.
F: HarnakTank_ValidTarget(object) = object and alive(object) and attackable(object)

// ************************************ Range and Functors ******************************************

// Attackable, alive, inside room.
L MobFunctor 1111 (Attackable and Alive and \
                   HarnakTank_InRoom(actor))

// Attackable, alive, inside room, outside of aoe range.
L MobFunctor 1112 (Attackable and Alive              and \
                   HarnakTank_InRoom(actor))         and \
                   not HarnakTank_AoeRange(actor)

// Attackable, alive, inside room, outside of aoe range, targetting party.
L MobFunctor 1113 (Attackable and Alive              and \
                   HarnakTank_InRoom(actor))         and \
                   not HarnakTank_AoeRange(actor)    and \
                   isMember(name(target(actor)))

// Attackable, alive, inside room, inside of aoe range.
L MobFunctor 1114 (Attackable and Alive      and \
                   HarnakTank_InRoom(actor)) and \
                   HarnakTank_AoeRange(actor)

// ***************************************** Events *************************************************

// If user pm's themselfs 'set center', set the center combat point.
?HarnakTank @CreatureSay type == 2 and actor == me and text == "set room center" : \
    Display 1 ("Room center point set to " .. xpos(me) .. " " .. ypos(me) .. " " .. zpos(me)); \
    RoundRange 1114 xpos(me) ypos(me) 700;

// If user pm's themselfs 'set center', set the center combat point.
?HarnakTank @CreatureSay type == 2 and actor == me and text == "set my location" : \
    Display 1 ("My preferred location set to " .. xpos(me) .. " " .. ypos(me) .. " " .. zpos(me)); \
    Assign HarnakTank_X = xpos(me); Assign HarnakTank_Y = ypos(me);

// If user pm's themselfs 'set center', set the center combat point.
?HarnakTank @CreatureSay type == 2 and actor == me and text == "clear my location" : \
    Display 1 ("My preferred location cleared."); \
    Assign HarnakTank_X = 0; Assign HarnakTank_Y = 0;

// *********************************** Movement Intervals *******************************************

// If we have a preferred location defined, move to it.
?HarnakTank T(3000) HarnakTank_MyLocation             and \
                    Zone ~= 12                          : \
    Display 1 ("Moving to my preferred location ["     .. \
        HarnakTank_X .. " " .. HarnakTank_Y .. "].");     \
    MoveTo HarnakTank_X HarnakTank_Y zpos(me);

// ******************************* Targetting/Attack Intervals **************************************

// If can perform action, and not valid target or targetting player and have mob.
?HarnakTank T(1000) HarnakTank_CanPerformAction                                 and \
                    not HarnakTank_ValidTarget(target(me))                      and \
                    mobsFind(1111)                                                : \
    Assign HarnakTank_ActionStop = now + HarnakTank_ActionStopTime;                 \
    Display 1 ("Selecting and attacking a new target [" .. npc(lastFound) .. "]."); \
    Select(lastFound) safe > Attack;

// *************************************** Intervals ************************************************

// If at least one mob is around, and hate aura is not on cooldown.
?HarnakTank T(1000, 2500) HarnakTank_CanUseSkill($SuperiorHateAura) and \
                          mobsCount(1111)                             : \
    Assign HarnakTank_ActionStop = now + HarnakTank_ActionStopTime;     \
    Display 1 ("[" .. mobsCount(1111) .. "] mobs in room, using ["   .. \
        skillName($SuperiorHateAura) .. "].");                          \
    Cast $SuperiorHateAura;

// If mob attacking someone, use single target hate.
?HarnakTank T(1001, 2500) HarnakTank_CanUseSkill($SuperiorHate)                and \
                          mobsFind(1113) :                                         \
    Assign HarnakTank_ActionStop = now + HarnakTank_ActionStopTime;                \
    Display 1 ("[" .. name(target(lastFound)) .. "] is being attacked, using [" .. \
        skillName($SuperiorHate) .. "].");                                         \
    Select (lastFound) > Cast $SuperiorHate;

// If a sniper is found matching our mob criteria, chain strike it.
?HarnakTank T(1002, 2500) HarnakTank_CanUseSkill($ChainStrike)                         and \
                          mobsFind(1112)                                                 : \
    Assign HarnakTank_ActionStop = now + HarnakTank_ActionStopTime;                        \
    Display 1 ("Using [" .. skillName($ChainStrike) .. "] on a mob ouside of aoe range."); \
    Select(lastFound) > Cast $ChainStrike;

// If hp falls below 20% target self and use ultimate defense.
?HarnakTank T(1003, 5000) HarnakTank_CanUseSkill($FinalUltimateDefense)         and \
                          php(me) < 20                                            : \
    Assign HarnakTank_ActionStop = now + HarnakTank_ActionStopTime;                 \
    Display 1 ("HP below 20% using [" .. skillName($FinalUltimateDefense) .. "]."); \
    SelectSelf > Cast $FinalUltimateDefense;

// If hp falls below 25% use party ultimate defense.
?HarnakTank T(1004, 5000) HarnakTank_CanUseSkill($ProtectionOfFaith)         and \
                          php(me) < 25                                         : \
    Assign HarnakTank_ActionStop = now + HarnakTank_ActionStopTime;              \
    Display 1 ("HP below 25% using [" .. skillName($ProtectionOfFaith) .. "]."); \
    Cast $ProtectionOfFaith;

// ********************************** Within AOE Intervals ******************************************

// If at least two mobs inside aoe range, use chain galaxy.
?HarnakTank T(1005, 2500) HarnakTank_CanUseSkill($ChainGalaxy)      and \
                          mobsFind(1114) > 1                          : \
    Assign HarnakTank_ActionStop = now + HarnakTank_ActionStopTime;     \
    Display 1 ("Using [" .. skillName($ChainGalaxy) .. "].");           \
    Cast $ChainGalaxy;

// If at least two mobs inside aoe range, use gust blade.
?HarnakTank T(1006, 2500) HarnakTank_CanUseSkill($GustBlade)        and \
                          mobsFind(1114) > 1                          : \
    Assign HarnakTank_ActionStop = now + HarnakTank_ActionStopTime;     \
    Display 1 ("Using [" .. skillName($GustBlade) .. "].");             \
    Cast $GustBlade;

// If at least two mobs inside aoe range, use shield impact.
?HarnakTank T(1007, 2500) HarnakTank_CanUseSkill($ShieldImpact)     and \
                          mobsFind(1114) > 1                          : \
    Assign HarnakTank_ActionStop = now + HarnakTank_ActionStopTime;     \
    Display 1 ("Using [" .. skillName($ShieldImpact) .. "].");          \
    Cast $ShieldImpact;

// If at least two mobs inside aoe range, use shield wave.
?HarnakTank T(1008, 2500) HarnakTank_CanUseSkill($ShieldWave)     and \
                          mobsFind(1114) > 1                        : \
    Assign HarnakTank_ActionStop = now + HarnakTank_ActionStopTime;   \
    Display 1 ("Using [" .. skillName($ShieldWave) .. "].");          \
    Cast $ShieldWave;