#include "\task_force_radio\functions\common.sqf";

/*
The first part of the array is the squad name.  If blueforce tracker is on this is the name that will display on the map.
The second number in the array is the channel number for short range radios that will be displayed in the hint provided to players upon start.
The remainder of the array is the units that make up each squad.
The below are examples, change as neccessary.
The last group array should NOT have a comma at the end.
Any changes made here must also be reflected in setpatch.sqf in order to display insignia.
*/

TFD_ORBAT = [
	["Command",8,"s1","s2"],
	["Anna",1,"s3","s4","s5","s6","s7"],
	["Borris",2,"s8","s9","s10","s11","s12"],
	["Vasily",3,"s13","s14","s15","s16","s17"],
	["Gregory",4,"s18","s19","s20","s21","s22"],
	["Dmitri",5,"s23","s24","s25","s26","s27"],
	["Yelena",6,"s28","s29","s30","s31","s32"],
	["Ivan",7,"s33","s34","s35","s36","s37"]
];


[] spawn {

_name = format ["%1", player];
_role =  getText (configFile >> "CfgVehicles" >> typeOf player >> "displayname");
	{
	if (_name in _x) then {

		_channel = (_x select 1);
		waitUntil {[] call TFAR_fnc_haveSWRadio};
		// Channels are 0 indexed so must be _channel - 1
		[(call TFAR_fnc_activeSwRadio), _channel - 1] call TFAR_fnc_setSwChannel;
		sleep 0.5;

	"Attention" hintC [
	if ( player == s1 ) then {
			"You are the mission commander.";
		} else {
			format[ "Mission commander is %1." , name s1 ];
		},
		format[ "You are in %1." , (_x select 0) ],
		if ( _role == "Squad Leader" || _role == "Team Leader" || _role == "Officer" ) then {
			"You are the leader of your group, please report to the command area for briefing.";
		} else {
			format[ "Your group leader is %1, please wait in your rally area until the mission begins." , (name leader group player) ];
		},
		format[ "Your SR channel is %1." , _channel ],
		"LR comms are channel 1." //Edit here if neccessary to define LR channels.
		];
	};
	}  forEach TFD_ORBAT;

};