API tools faq
paste
Advertisement
Guest User

Untitled

a guest
Jul 21st, 2017
60
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
C++ 29.14 KB | None | 0 0
raw download clone embed print report
  1. #include common_scripts\utility;
  2. #include maps\mp\_utility;
  3. #include maps\mp\gametypes\_hud_util;
  4. /*
  5.     Domination
  6.     Objective:  Capture all the flags by touching them
  7.     Map ends:   When one team captures all the flags, or time limit is reached
  8.     Respawning: No wait / Near teammates
  9.  
  10.     Level requirements
  11.     ------------------
  12.         Spawnpoints:
  13.             classname       mp_tdm_spawn
  14.             All players spawn from these. The spawnpoint chosen is dependent on the current locations of owned flags, teammates and
  15.             enemies at the time of spawn. Players generally spawn behind their teammates relative to the direction of enemies.
  16.             Optionally, give a spawnpoint a script_linkto to specify which flag it "belongs" to (see Flag Descriptors).
  17.  
  18.         Spectator Spawnpoints:
  19.             classname       mp_global_intermission
  20.             Spectators spawn from these and intermission is viewed from these positions.
  21.             Atleast one is required, any more and they are randomly chosen between.
  22.  
  23.         Flags:
  24.             classname       trigger_radius
  25.             targetname      flag_primary or flag_secondary
  26.             Flags that need to be captured to win. Primary flags take time to capture; secondary flags are instant.
  27.        
  28.         Flag Descriptors:
  29.             classname       script_origin
  30.             targetname      flag_descriptor
  31.             Place one flag descriptor close to each flag. Use the script_linkname and script_linkto properties to say which flags
  32.             it can be considered "adjacent" to in the level. For instance, if players have a primary path from flag1 to flag2, and
  33.             from flag2 to flag3, flag2 would have a flag_descriptor with these properties:
  34.             script_linkname flag2
  35.             script_linkto flag1 flag3
  36.            
  37.             Set scr_domdebug to 1 to see flag connections and what spawnpoints are considered connected to each flag.
  38. */
  39.  
  40. /*QUAKED mp_dom_spawn (0.5 0.5 1.0) (-16 -16 0) (16 16 72)
  41. Players spawn near their flags at one of these positions.*/
  42.  
  43. /*QUAKED mp_dom_spawn_axis_start (1.0 0.0 1.0) (-16 -16 0) (16 16 72)
  44. Axis players spawn away from enemies and near their team at one of these positions at the start of a round.*/
  45.  
  46. /*QUAKED mp_dom_spawn_allies_start (0.0 1.0 1.0) (-16 -16 0) (16 16 72)
  47. Allied players spawn away from enemies and near their team at one of these positions at the start of a round.*/
  48.  
  49. main()
  50. {
  51.     if(getdvar("mapname") == "mp_background")
  52.         return;
  53.  
  54.     maps\mp\gametypes\_globallogic::init();
  55.     maps\mp\gametypes\_callbacksetup::SetupCallbacks();
  56.     maps\mp\gametypes\_globallogic::SetupCallbacks();
  57.  
  58.     registerTimeLimitDvar( level.gameType, 30, 0, 1440 );
  59.     registerScoreLimitDvar( level.gameType, 300, 0, 1000 );
  60.     registerRoundLimitDvar( level.gameType, 1, 0, 10 );
  61.     registerWinLimitDvar( level.gameType, 1, 0, 10 );
  62.     registerNumLivesDvar( level.gameType, 0, 0, 10 );
  63.     registerHalfTimeDvar( level.gameType, 0, 0, 1 );
  64.  
  65.     level.teamBased = true;
  66.     level.onStartGameType = ::onStartGameType;
  67.     level.getSpawnPoint = ::getSpawnPoint;
  68.     level.onPlayerKilled = ::onPlayerKilled;
  69.     level.onPrecacheGameType = ::onPrecacheGameType;
  70.     level.initGametypeAwards = ::initGametypeAwards;
  71.     level.onSpawnPlayer = ::onSpawnPlayer;
  72.    
  73.     game["dialog"]["gametype"] = "domination";
  74.  
  75.     if ( getDvarInt( "g_hardcore" ) )
  76.         game["dialog"]["gametype"] = "hc_" + game["dialog"]["gametype"];
  77.     else if ( getDvarInt( "camera_thirdPerson" ) )
  78.         game["dialog"]["gametype"] = "thirdp_" + game["dialog"]["gametype"];
  79.     else if ( getDvarInt( "scr_diehard" ) )
  80.         game["dialog"]["gametype"] = "dh_" + game["dialog"]["gametype"];
  81.     else if (getDvarInt( "scr_" + level.gameType + "_promode" ) )
  82.         game["dialog"]["gametype"] = game["dialog"]["gametype"] + "_pro";
  83.  
  84.     game["dialog"]["offense_obj"] = "capture_objs";
  85.     game["dialog"]["defense_obj"] = "capture_objs";
  86. }
  87.  
  88.  
  89. onPrecacheGameType()
  90. {
  91.     precacheShader( "waypoint_captureneutral" );
  92.     precacheShader( "waypoint_capture" );
  93.     precacheShader( "waypoint_defend" );
  94.     precacheShader( "waypoint_captureneutral_a" );
  95.     precacheShader( "waypoint_capture_a" );
  96.     precacheShader( "waypoint_defend_a" );
  97.     precacheShader( "waypoint_captureneutral_b" );
  98.     precacheShader( "waypoint_capture_b" );
  99.     precacheShader( "waypoint_defend_b" );
  100.     precacheShader( "waypoint_captureneutral_c" );
  101.     precacheShader( "waypoint_capture_c" );
  102.     precacheShader( "waypoint_defend_c" );
  103.  
  104.     precacheShader( "waypoint_captureneutral" );
  105.     precacheShader( "waypoint_capture" );
  106.     precacheShader( "waypoint_defend" );
  107.     precacheShader( "waypoint_captureneutral_a" );
  108.     precacheShader( "waypoint_capture_a" );
  109.     precacheShader( "waypoint_defend_a" );
  110.     precacheShader( "waypoint_captureneutral_b" );
  111.     precacheShader( "waypoint_capture_b" );
  112.     precacheShader( "waypoint_defend_b" );
  113.     precacheShader( "waypoint_captureneutral_c" );
  114.     precacheShader( "waypoint_capture_c" );
  115.     precacheShader( "waypoint_defend_c" );
  116. }
  117.  
  118.  
  119. onStartGameType()
  120. {  
  121.     setObjectiveText( "allies", &"OBJECTIVES_DOM" );
  122.     setObjectiveText( "axis", &"OBJECTIVES_DOM" );
  123.  
  124.     if ( level.splitscreen )
  125.     {
  126.         setObjectiveScoreText( "allies", &"OBJECTIVES_DOM" );
  127.         setObjectiveScoreText( "axis", &"OBJECTIVES_DOM" );
  128.     }
  129.     else
  130.     {
  131.         setObjectiveScoreText( "allies", &"OBJECTIVES_DOM_SCORE" );
  132.         setObjectiveScoreText( "axis", &"OBJECTIVES_DOM_SCORE" );
  133.     }
  134.     setObjectiveHintText( "allies", &"OBJECTIVES_DOM_HINT" );
  135.     setObjectiveHintText( "axis", &"OBJECTIVES_DOM_HINT" );
  136.  
  137.     setClientNameMode("auto_change");
  138.  
  139.     level.spawnMins = ( 0, 0, 0 );
  140.     level.spawnMaxs = ( 0, 0, 0 );
  141.     maps\mp\gametypes\_spawnlogic::placeSpawnPoints( "mp_dom_spawn_allies_start" );
  142.     maps\mp\gametypes\_spawnlogic::placeSpawnPoints( "mp_dom_spawn_axis_start" );
  143.     maps\mp\gametypes\_spawnlogic::addSpawnPoints( "allies", "mp_dom_spawn" );
  144.     maps\mp\gametypes\_spawnlogic::addSpawnPoints( "axis", "mp_dom_spawn" );
  145.    
  146.     level.mapCenter = maps\mp\gametypes\_spawnlogic::findBoxCenter( level.spawnMins, level.spawnMaxs );
  147.     setMapCenter( level.mapCenter );
  148.    
  149.     level.spawn_all = maps\mp\gametypes\_spawnlogic::getSpawnpointArray( "mp_dom_spawn" );
  150.     level.spawn_axis_start = maps\mp\gametypes\_spawnlogic::getSpawnpointArray( "mp_dom_spawn_axis_start" );
  151.     level.spawn_allies_start = maps\mp\gametypes\_spawnlogic::getSpawnpointArray( "mp_dom_spawn_allies_start" );
  152.    
  153.     level.startPos["allies"] = level.spawn_allies_start[0].origin;
  154.     level.startPos["axis"] = level.spawn_axis_start[0].origin;
  155.    
  156.     level.flagBaseFXid[ "allies" ] = loadfx( maps\mp\gametypes\_teams::getTeamFlagFX( "allies" ) );
  157.     level.flagBaseFXid[ "axis"   ] = loadfx( maps\mp\gametypes\_teams::getTeamFlagFX( "axis" ) );
  158.    
  159.     allowed[0] = "dom";
  160. //  allowed[1] = "hardpoint";
  161.     maps\mp\gametypes\_gameobjects::main(allowed);
  162.  
  163.     maps\mp\gametypes\_rank::registerScoreInfo( "kill", 50 );
  164.     maps\mp\gametypes\_rank::registerScoreInfo( "headshot", 50 );
  165.     maps\mp\gametypes\_rank::registerScoreInfo( "assist", 10 );
  166.  
  167.     maps\mp\gametypes\_rank::registerScoreInfo( "capture", 150 );
  168.  
  169.     maps\mp\gametypes\_rank::registerScoreInfo( "defend", 50 );
  170.     maps\mp\gametypes\_rank::registerScoreInfo( "defend_assist", 10 );
  171.  
  172.     maps\mp\gametypes\_rank::registerScoreInfo( "assault", 50 );
  173.     maps\mp\gametypes\_rank::registerScoreInfo( "assault_assist", 10 );
  174.        
  175.     thread domFlags();
  176.     thread updateDomScores();  
  177. }
  178.  
  179.  
  180. getSpawnPoint()
  181. {
  182.     spawnpoint = undefined;
  183.    
  184.     if ( !level.useStartSpawns )
  185.     {
  186.         flagsOwned = 0;
  187.         enemyFlagsOwned = 0;
  188.         myTeam = self.pers["team"];
  189.         enemyTeam = getOtherTeam( myTeam );
  190.         for ( i = 0; i < level.flags.size; i++ )
  191.         {
  192.             team = level.flags[i] getFlagTeam();
  193.             if ( team == myTeam )
  194.                 flagsOwned++;
  195.             else if ( team == enemyTeam )
  196.                 enemyFlagsOwned++;
  197.         }
  198.        
  199.         if ( flagsOwned == level.flags.size )
  200.         {
  201.             // own all flags! pretend we don't own the last one we got, so enemies can spawn there
  202.             enemyBestSpawnFlag = level.bestSpawnFlag[ getOtherTeam( self.pers["team"] ) ];
  203.            
  204.             spawnpoint = maps\mp\gametypes\_spawnlogic::getSpawnpoint_NearTeam( level.spawn_all, getSpawnsBoundingFlag( enemyBestSpawnFlag ) );
  205.         }
  206.         else if ( flagsOwned > 0 )
  207.         {
  208.             // spawn near any flag we own that's nearish something we can capture
  209.             spawnpoint = maps\mp\gametypes\_spawnlogic::getSpawnpoint_NearTeam( level.spawn_all, getBoundaryFlagSpawns( myTeam ) );
  210.         }
  211.         else
  212.         {
  213.             // own no flags!
  214.             bestFlag = undefined;
  215.             if ( enemyFlagsOwned > 0 && enemyFlagsOwned < level.flags.size )
  216.             {
  217.                 // there should be an unowned one to use
  218.                 bestFlag = getUnownedFlagNearestStart( myTeam );
  219.             }
  220.             if ( !isdefined( bestFlag ) )
  221.             {
  222.                 // pretend we still own the last one we lost
  223.                 bestFlag = level.bestSpawnFlag[ self.pers["team"] ];
  224.             }
  225.             level.bestSpawnFlag[ self.pers["team"] ] = bestFlag;
  226.            
  227.             spawnpoint = maps\mp\gametypes\_spawnlogic::getSpawnpoint_NearTeam( level.spawn_all, bestFlag.nearbyspawns );
  228.         }
  229.     }
  230.    
  231.     if ( !isdefined( spawnpoint ) )
  232.     {
  233.         if (self.pers["team"] == "axis")
  234.             spawnpoint = maps\mp\gametypes\_spawnlogic::getSpawnpoint_Random(level.spawn_axis_start);
  235.         else
  236.             spawnpoint = maps\mp\gametypes\_spawnlogic::getSpawnpoint_Random(level.spawn_allies_start);
  237.     }
  238.    
  239.     //spawnpoint = maps\mp\gametypes\_spawnlogic::getSpawnpoint_NearTeam( level.spawn_all );
  240.    
  241.     assert( isDefined(spawnpoint) );
  242.    
  243.     return spawnpoint;
  244. }
  245.  
  246.  
  247. domFlags()
  248. {
  249.     level.lastStatus["allies"] = 0;
  250.     level.lastStatus["axis"] = 0;
  251.    
  252.     game["flagmodels"] = [];
  253.     game["flagmodels"]["neutral"] = "prop_flag_neutral";
  254.  
  255.     game["flagmodels"]["allies"] = maps\mp\gametypes\_teams::getTeamFlagModel( "allies" );
  256.     game["flagmodels"]["axis"] = maps\mp\gametypes\_teams::getTeamFlagModel( "axis" );
  257.    
  258.     precacheModel( game["flagmodels"]["neutral"] );
  259.     precacheModel( game["flagmodels"]["allies"] );
  260.     precacheModel( game["flagmodels"]["axis"] );
  261.    
  262.     precacheString( &"MP_SECURING_POSITION" ); 
  263.    
  264.     primaryFlags = getEntArray( "flag_primary", "targetname" );
  265.     secondaryFlags = getEntArray( "flag_secondary", "targetname" );
  266.    
  267.     if ( (primaryFlags.size + secondaryFlags.size) < 2 )
  268.     {
  269.         printLn( "^1Not enough domination flags found in level!" );
  270.         maps\mp\gametypes\_callbacksetup::AbortLevel();
  271.         return;
  272.     }
  273.    
  274.     level.flags = [];
  275.     for ( index = 0; index < primaryFlags.size; index++ )
  276.         level.flags[level.flags.size] = primaryFlags[index];
  277.    
  278.     for ( index = 0; index < secondaryFlags.size; index++ )
  279.         level.flags[level.flags.size] = secondaryFlags[index];
  280.    
  281.     level.domFlags = [];
  282.     for ( index = 0; index < level.flags.size; index++ )
  283.     {
  284.         trigger = level.flags[index];
  285.         if ( isDefined( trigger.target ) )
  286.         {
  287.             visuals[0] = getEnt( trigger.target, "targetname" );
  288.         }
  289.         else
  290.         {
  291.             visuals[0] = spawn( "script_model", trigger.origin );
  292.             visuals[0].angles = trigger.angles;
  293.         }
  294.  
  295.         visuals[0] setModel( game["flagmodels"]["neutral"] );
  296.  
  297.         domFlag = maps\mp\gametypes\_gameobjects::createUseObject( "neutral", trigger, visuals, (0,0,100) );
  298.         domFlag maps\mp\gametypes\_gameobjects::allowUse( "enemy" );
  299.         domFlag maps\mp\gametypes\_gameobjects::setUseTime( 10.0 );
  300.         domFlag maps\mp\gametypes\_gameobjects::setUseText( &"MP_SECURING_POSITION" );
  301.         label = domFlag maps\mp\gametypes\_gameobjects::getLabel();
  302.         domFlag.label = label;
  303.         domFlag maps\mp\gametypes\_gameobjects::set2DIcon( "friendly", "waypoint_defend" + label );
  304.         domFlag maps\mp\gametypes\_gameobjects::set3DIcon( "friendly", "waypoint_defend" + label );
  305.         domFlag maps\mp\gametypes\_gameobjects::set2DIcon( "enemy", "waypoint_captureneutral" + label );
  306.         domFlag maps\mp\gametypes\_gameobjects::set3DIcon( "enemy", "waypoint_captureneutral" + label );
  307.         domFlag maps\mp\gametypes\_gameobjects::setVisibleTeam( "any" );
  308.         domFlag.onUse = ::onUse;
  309.         domFlag.onBeginUse = ::onBeginUse;
  310.         domFlag.onUseUpdate = ::onUseUpdate;
  311.         domFlag.onEndUse = ::onEndUse;
  312.        
  313.        
  314.         traceStart = visuals[0].origin + (0,0,32);
  315.         traceEnd = visuals[0].origin + (0,0,-32);
  316.         trace = bulletTrace( traceStart, traceEnd, false, undefined );
  317.    
  318.         upangles = vectorToAngles( trace["normal"] );
  319.         domFlag.baseeffectforward = anglesToForward( upangles );
  320.         domFlag.baseeffectright = anglesToRight( upangles );
  321.        
  322.         domFlag.baseeffectpos = trace["position"];
  323.        
  324.         // legacy spawn code support
  325.         level.flags[index].useObj = domFlag;
  326.         level.flags[index].adjflags = [];
  327.         level.flags[index].nearbyspawns = [];
  328.        
  329.         domFlag.levelFlag = level.flags[index];
  330.        
  331.         level.domFlags[level.domFlags.size] = domFlag;
  332.     }
  333.    
  334.     // level.bestSpawnFlag is used as a last resort when the enemy holds all flags.
  335.     level.bestSpawnFlag = [];
  336.     level.bestSpawnFlag[ "allies" ] = getUnownedFlagNearestStart( "allies", undefined );
  337.     level.bestSpawnFlag[ "axis" ] = getUnownedFlagNearestStart( "axis", level.bestSpawnFlag[ "allies" ] );
  338.    
  339.     flagSetup();
  340.    
  341.     /#
  342.     thread domDebug();
  343.     #/
  344. }
  345.  
  346. getUnownedFlagNearestStart( team, excludeFlag )
  347. {
  348.     best = undefined;
  349.     bestdistsq = undefined;
  350.     for ( i = 0; i < level.flags.size; i++ )
  351.     {
  352.         flag = level.flags[i];
  353.        
  354.         if ( flag getFlagTeam() != "neutral" )
  355.             continue;
  356.        
  357.         distsq = distanceSquared( flag.origin, level.startPos[team] );
  358.         if ( (!isDefined( excludeFlag ) || flag != excludeFlag) && (!isdefined( best ) || distsq < bestdistsq) )
  359.         {
  360.             bestdistsq = distsq;
  361.             best = flag;
  362.         }
  363.     }
  364.     return best;
  365. }
  366.  
  367. /#
  368. domDebug()
  369. {
  370.     while(1)
  371.     {
  372.         if (getdvar("scr_domdebug") != "1") {
  373.             wait 2;
  374.             continue;
  375.         }
  376.        
  377.         while(1)
  378.         {
  379.             if (getdvar("scr_domdebug") != "1")
  380.                 break;
  381.             // show flag connections and each flag's spawnpoints
  382.             for (i = 0; i < level.flags.size; i++) {
  383.                 for (j = 0; j < level.flags[i].adjflags.size; j++) {
  384.                     line(level.flags[i].origin, level.flags[i].adjflags[j].origin, (1,1,1));
  385.                 }
  386.                
  387.                 for (j = 0; j < level.flags[i].nearbyspawns.size; j++) {
  388.                     line(level.flags[i].origin, level.flags[i].nearbyspawns[j].origin, (.2,.2,.6));
  389.                 }
  390.                
  391.                 if ( level.flags[i] == level.bestSpawnFlag["allies"] )
  392.                     print3d( level.flags[i].origin, "allies best spawn flag" );
  393.                 if ( level.flags[i] == level.bestSpawnFlag["axis"] )
  394.                     print3d( level.flags[i].origin, "axis best spawn flag" );
  395.             }
  396.             wait .05;
  397.         }
  398.     }
  399. }
  400. #/
  401.  
  402. onBeginUse( player )
  403. {
  404.     ownerTeam = self maps\mp\gametypes\_gameobjects::getOwnerTeam();
  405.     self.didStatusNotify = false;
  406.  
  407.     if ( ownerTeam == "neutral" )
  408.     {
  409.         statusDialog( "securing"+self.label, player.pers["team"] );
  410.         self.objPoints[player.pers["team"]] thread maps\mp\gametypes\_objpoints::startFlashing();
  411.         return;
  412.     }
  413.        
  414.     if ( ownerTeam == "allies" )
  415.         otherTeam = "axis";
  416.     else
  417.         otherTeam = "allies";
  418.  
  419.     self.objPoints["allies"] thread maps\mp\gametypes\_objpoints::startFlashing();
  420.     self.objPoints["axis"] thread maps\mp\gametypes\_objpoints::startFlashing();
  421. }
  422.  
  423.  
  424. onUseUpdate( team, progress, change )
  425. {
  426.     if ( progress > 0.05 && change && !self.didStatusNotify )
  427.     {
  428.         ownerTeam = self maps\mp\gametypes\_gameobjects::getOwnerTeam();
  429.         if ( ownerTeam == "neutral" )
  430.         {
  431.             statusDialog( "securing"+self.label, team );
  432.         }
  433.         else
  434.         {
  435.             statusDialog( "losing"+self.label, ownerTeam );
  436.             statusDialog( "securing"+self.label, team );
  437.         }
  438.  
  439.         self.didStatusNotify = true;
  440.     }
  441. }
  442.  
  443.  
  444. statusDialog( dialog, team, forceDialog )
  445. {
  446.     time = getTime();
  447.    
  448.     if ( getTime() < level.lastStatus[team] + 5000 && (!isDefined( forceDialog ) || !forceDialog) )
  449.         return;
  450.        
  451.     thread delayedLeaderDialog( dialog, team );
  452.     level.lastStatus[team] = getTime();
  453. }
  454.  
  455.  
  456. onEndUse( team, player, success )
  457. {
  458.     self.objPoints["allies"] thread maps\mp\gametypes\_objpoints::stopFlashing();
  459.     self.objPoints["axis"] thread maps\mp\gametypes\_objpoints::stopFlashing();
  460. }
  461.  
  462.  
  463. resetFlagBaseEffect()
  464. {
  465.     if ( isdefined( self.baseeffect ) )
  466.         self.baseeffect delete();
  467.    
  468.     team = self maps\mp\gametypes\_gameobjects::getOwnerTeam();
  469.    
  470.     if ( team != "axis" && team != "allies" )
  471.         return;
  472.    
  473.     fxid = level.flagBaseFXid[ team ];
  474.  
  475.     self.baseeffect = spawnFx( fxid, self.baseeffectpos, self.baseeffectforward, self.baseeffectright );
  476.     triggerFx( self.baseeffect );
  477. }
  478.  
  479. onUse( player )
  480. {
  481.     team = player.pers["team"];
  482.     oldTeam = self maps\mp\gametypes\_gameobjects::getOwnerTeam();
  483.     label = self maps\mp\gametypes\_gameobjects::getLabel();
  484.    
  485.     //player logString( "flag captured: " + self.label );
  486.    
  487.     self.captureTime = getTime();
  488.    
  489.     self maps\mp\gametypes\_gameobjects::setOwnerTeam( team );
  490.     self maps\mp\gametypes\_gameobjects::set2DIcon( "enemy", "waypoint_capture" + label );
  491.     self maps\mp\gametypes\_gameobjects::set3DIcon( "enemy", "waypoint_capture" + label );
  492.     self.visuals[0] setModel( game["flagmodels"][team] );
  493.    
  494.     self resetFlagBaseEffect();
  495.    
  496.     level.useStartSpawns = false;
  497.    
  498.     assert( team != "neutral" );
  499.    
  500.     if ( oldTeam == "neutral" )
  501.     {
  502.         otherTeam = getOtherTeam( team );
  503.         thread printAndSoundOnEveryone( team, otherTeam, undefined, undefined, "mp_war_objective_taken", undefined, player );
  504.        
  505.         statusDialog( "secured"+self.label, team, true );
  506.         statusDialog( "enemy_has"+self.label, otherTeam, true );
  507.     }
  508.     else
  509.     {
  510.         thread printAndSoundOnEveryone( team, oldTeam, undefined, undefined, "mp_war_objective_taken", "mp_war_objective_lost", player );
  511.        
  512. //      thread delayedLeaderDialogBothTeams( "obj_lost", oldTeam, "obj_taken", team );
  513.  
  514.         if ( getTeamFlagCount( team ) == level.flags.size )
  515.         {
  516.             statusDialog( "secure_all", team );
  517.             statusDialog( "lost_all", oldTeam );
  518.         }
  519.         else
  520.         {  
  521.             statusDialog( "secured"+self.label, team, true );
  522.             statusDialog( "lost"+self.label, oldTeam, true );
  523.         }
  524.        
  525.         level.bestSpawnFlag[ oldTeam ] = self.levelFlag;
  526.     }
  527.    
  528.     player notify( "objective", "captured" );
  529.     self thread giveFlagCaptureXP( self.touchList[team] );
  530. }
  531.  
  532. giveFlagCaptureXP( touchList )
  533. {
  534.     level endon ( "game_ended" );
  535.    
  536.     players = getArrayKeys( touchList );
  537.     for ( index = 0; index < players.size; index++ )
  538.     {
  539.         player = touchList[players[index]].player;
  540.         player thread maps\mp\gametypes\_hud_message::SplashNotify( "capture", maps\mp\gametypes\_rank::getScoreInfoValue( "capture" ) );
  541.         player thread updateCPM();
  542.         player thread maps\mp\gametypes\_rank::giveRankXP( "capture", maps\mp\gametypes\_rank::getScoreInfoValue( "capture" ) * player getCapXPScale() );
  543.         printLn( maps\mp\gametypes\_rank::getScoreInfoValue( "capture" ) * player getCapXPScale() );
  544.         maps\mp\gametypes\_gamescore::givePlayerScore( "capture", player );
  545.         player incPlayerStat( "pointscaptured", 1 );
  546.     }
  547.    
  548.     player = self maps\mp\gametypes\_gameobjects::getEarliestClaimPlayer();
  549.  
  550.     level thread teamPlayerCardSplash( "callout_securedposition" + self.label, player );
  551.  
  552.     player thread maps\mp\_matchdata::logGameEvent( "capture", player.origin );
  553. }
  554.  
  555. delayedLeaderDialog( sound, team )
  556. {
  557.     level endon ( "game_ended" );
  558.     wait .1;
  559.     WaitTillSlowProcessAllowed();
  560.    
  561.     leaderDialog( sound, team );
  562. }
  563. delayedLeaderDialogBothTeams( sound1, team1, sound2, team2 )
  564. {
  565.     level endon ( "game_ended" );
  566.     wait .1;
  567.     WaitTillSlowProcessAllowed();
  568.    
  569.     leaderDialogBothTeams( sound1, team1, sound2, team2 );
  570. }
  571.  
  572.  
  573. updateDomScores()
  574. {
  575.     level endon ( "game_ended" );
  576.    
  577.     while ( !level.gameEnded )
  578.     {
  579.         domFlags = getOwnedDomFlags();
  580.        
  581.         if ( domFlags.size )
  582.         {
  583.             for ( i = 1; i < domFlags.size; i++ )
  584.             {
  585.                 domFlag = domFlags[i];
  586.                 flagScore = getTime() - domFlag.captureTime;
  587.                 for ( j = i - 1; j >= 0 && flagScore > (getTime() - domFlags[j].captureTime); j-- )
  588.                     domFlags[j + 1] = domFlags[j];
  589.                 domFlags[j + 1] = domFlag;
  590.             }
  591.            
  592.             foreach( domFlag in domFlags )
  593.             {
  594.                 team = domFlag maps\mp\gametypes\_gameobjects::getOwnerTeam();
  595.                 assert( team == "allies" || team == "axis" );
  596.                 maps\mp\gametypes\_gamescore::giveTeamScoreForObjective( team, 1 );
  597.             }
  598.         }
  599.        
  600.         // end the game if people aren't playing
  601.         if ( (((getTimePassed() / 1000) > 120 && domFlags.size < 2) || ((getTimePassed() / 1000) > 300 && domFlags.size < 3)) && matchMakingGame() )
  602.         {
  603.             thread maps\mp\gametypes\_gamelogic::endGame( "none", game["strings"]["time_limit_reached"] );
  604.             return;        
  605.         }
  606.        
  607.         wait ( 5.0 );
  608.         maps\mp\gametypes\_hostmigration::waitTillHostMigrationDone();
  609.     }
  610. }
  611.  
  612.  
  613. onPlayerKilled( eInflictor, attacker, iDamage, sMeansOfDeath, sWeapon, vDir, sHitLoc, psOffsetTime, deathAnimDuration, killId )
  614. {
  615.     if ( !isPlayer( attacker ) || (!self.touchTriggers.size && !attacker.touchTriggers.size) || attacker.pers["team"] == self.pers["team"] )
  616.         return;
  617.  
  618.     awardedAssault = false;
  619.     awardedDefend = false;
  620.  
  621.     foreach ( trigger in self.touchTriggers )
  622.     {
  623.         // TODO: way to check for dom specific triggers
  624.         if ( !isDefined( trigger.useObj ) )
  625.             continue;
  626.        
  627.         ownerTeam = trigger.useObj.ownerTeam;
  628.         team = self.pers["team"];
  629.  
  630.         if ( ownerTeam == "neutral" )
  631.             continue;
  632.        
  633.         if ( team == ownerTeam )
  634.         {
  635.             awardedAssault = true;
  636.             attacker thread maps\mp\gametypes\_hud_message::SplashNotify( "assault", maps\mp\gametypes\_rank::getScoreInfoValue( "assault" ) );
  637.             attacker thread maps\mp\gametypes\_rank::giveRankXP( "assault" );
  638.             maps\mp\gametypes\_gamescore::givePlayerScore( "assault", attacker );
  639.  
  640.             thread maps\mp\_matchdata::logKillEvent( killId, "defending" );
  641.         }
  642.         else
  643.         {
  644.             awardedDefend = true;
  645.             attacker thread maps\mp\gametypes\_hud_message::SplashNotify( "defend", maps\mp\gametypes\_rank::getScoreInfoValue( "defend" ) );
  646.             attacker thread maps\mp\gametypes\_rank::giveRankXP( "defend" );
  647.             maps\mp\gametypes\_gamescore::givePlayerScore( "defend", attacker );
  648.  
  649.             thread maps\mp\_matchdata::logKillEvent( killId, "assaulting" );
  650.         }
  651.     }
  652.  
  653.     foreach ( trigger in attacker.touchTriggers )
  654.     {
  655.         // TODO: way to check for dom specific triggers
  656.         if ( !isDefined( trigger.useObj ) )
  657.             continue;
  658.        
  659.         ownerTeam = trigger.useObj.ownerTeam;
  660.         team = attacker.pers["team"];
  661.        
  662.         if ( ownerTeam == "neutral" )
  663.             continue;
  664.        
  665.         if ( team == ownerTeam )
  666.         {
  667.             if ( !awardedDefend )
  668.                 attacker thread maps\mp\gametypes\_hud_message::SplashNotify( "defend", maps\mp\gametypes\_rank::getScoreInfoValue( "defend" ) );
  669.             attacker thread maps\mp\gametypes\_rank::giveRankXP( "defend" );
  670.             maps\mp\gametypes\_gamescore::givePlayerScore( "defend", attacker );
  671.  
  672.             thread maps\mp\_matchdata::logKillEvent( killId, "assaulting" );
  673.         }
  674.         else
  675.         {
  676.             if ( !awardedAssault )
  677.                 attacker thread maps\mp\gametypes\_hud_message::SplashNotify( "assault", maps\mp\gametypes\_rank::getScoreInfoValue( "assault" ) );
  678.             attacker thread maps\mp\gametypes\_rank::giveRankXP( "assault" );
  679.             maps\mp\gametypes\_gamescore::givePlayerScore( "assault", attacker );      
  680.  
  681.             thread maps\mp\_matchdata::logKillEvent( killId, "defending" );
  682.         }
  683.     }
  684. }
  685.  
  686.  
  687. getOwnedDomFlags()
  688. {
  689.     domFlags = [];
  690.     foreach ( domFlag in level.domFlags )
  691.     {
  692.         if ( domFlag maps\mp\gametypes\_gameobjects::getOwnerTeam() != "neutral" && isDefined( domFlag.captureTime ) )
  693.             domFlags[domFlags.size] = domFlag;
  694.     }
  695.    
  696.     return domFlags;
  697. }
  698.  
  699.  
  700. getTeamFlagCount( team )
  701. {
  702.     score = 0;
  703.     for (i = 0; i < level.flags.size; i++)
  704.     {
  705.         if ( level.domFlags[i] maps\mp\gametypes\_gameobjects::getOwnerTeam() == team )
  706.             score++;
  707.     }  
  708.     return score;
  709. }
  710.  
  711. getFlagTeam()
  712. {
  713.     return self.useObj maps\mp\gametypes\_gameobjects::getOwnerTeam();
  714. }
  715.  
  716. getBoundaryFlags()
  717. {
  718.     // get all flags which are adjacent to flags that aren't owned by the same team
  719.     bflags = [];
  720.     for (i = 0; i < level.flags.size; i++)
  721.     {
  722.         for (j = 0; j < level.flags[i].adjflags.size; j++)
  723.         {
  724.             if (level.flags[i].useObj maps\mp\gametypes\_gameobjects::getOwnerTeam() != level.flags[i].adjflags[j].useObj maps\mp\gametypes\_gameobjects::getOwnerTeam() )
  725.             {
  726.                 bflags[bflags.size] = level.flags[i];
  727.                 break;
  728.             }
  729.         }
  730.     }
  731.    
  732.     return bflags;
  733. }
  734.  
  735. getBoundaryFlagSpawns(team)
  736. {
  737.     spawns = [];
  738.    
  739.     bflags = getBoundaryFlags();
  740.     for (i = 0; i < bflags.size; i++)
  741.     {
  742.         if (isdefined(team) && bflags[i] getFlagTeam() != team)
  743.             continue;
  744.        
  745.         for (j = 0; j < bflags[i].nearbyspawns.size; j++)
  746.             spawns[spawns.size] = bflags[i].nearbyspawns[j];
  747.     }
  748.    
  749.     return spawns;
  750. }
  751.  
  752. getSpawnsBoundingFlag( avoidflag )
  753. {
  754.     spawns = [];
  755.  
  756.     for (i = 0; i < level.flags.size; i++)
  757.     {
  758.         flag = level.flags[i];
  759.         if ( flag == avoidflag )
  760.             continue;
  761.        
  762.         isbounding = false;
  763.         for (j = 0; j < flag.adjflags.size; j++)
  764.         {
  765.             if ( flag.adjflags[j] == avoidflag )
  766.             {
  767.                 isbounding = true;
  768.                 break;
  769.             }
  770.         }
  771.        
  772.         if ( !isbounding )
  773.             continue;
  774.        
  775.         for (j = 0; j < flag.nearbyspawns.size; j++)
  776.             spawns[spawns.size] = flag.nearbyspawns[j];
  777.     }
  778.    
  779.     return spawns;
  780. }
  781.  
  782. // gets an array of all spawnpoints which are near flags that are
  783. // owned by the given team, or that are adjacent to flags owned by the given team.
  784. getOwnedAndBoundingFlagSpawns(team)
  785. {
  786.     spawns = [];
  787.  
  788.     for (i = 0; i < level.flags.size; i++)
  789.     {
  790.         if ( level.flags[i] getFlagTeam() == team )
  791.         {
  792.             // add spawns near this flag
  793.             for (s = 0; s < level.flags[i].nearbyspawns.size; s++)
  794.                 spawns[spawns.size] = level.flags[i].nearbyspawns[s];
  795.         }
  796.         else
  797.         {
  798.             for (j = 0; j < level.flags[i].adjflags.size; j++)
  799.             {
  800.                 if ( level.flags[i].adjflags[j] getFlagTeam() == team )
  801.                 {
  802.                     // add spawns near this flag
  803.                     for (s = 0; s < level.flags[i].nearbyspawns.size; s++)
  804.                         spawns[spawns.size] = level.flags[i].nearbyspawns[s];
  805.                     break;
  806.                 }
  807.             }
  808.         }
  809.     }
  810.    
  811.     return spawns;
  812. }
  813.  
  814. // gets an array of all spawnpoints which are near flags that are
  815. // owned by the given team
  816. getOwnedFlagSpawns(team)
  817. {
  818.     spawns = [];
  819.  
  820.     for (i = 0; i < level.flags.size; i++)
  821.     {
  822.         if ( level.flags[i] getFlagTeam() == team )
  823.         {
  824.             // add spawns near this flag
  825.             for (s = 0; s < level.flags[i].nearbyspawns.size; s++)
  826.                 spawns[spawns.size] = level.flags[i].nearbyspawns[s];
  827.         }
  828.     }
  829.    
  830.     return spawns;
  831. }
  832.  
  833. flagSetup()
  834. {
  835.     maperrors = [];
  836.     descriptorsByLinkname = [];
  837.  
  838.     // (find each flag_descriptor object)
  839.     descriptors = getentarray("flag_descriptor", "targetname");
  840.    
  841.     flags = level.flags;
  842.    
  843.     for (i = 0; i < level.domFlags.size; i++)
  844.     {
  845.         closestdist = undefined;
  846.         closestdesc = undefined;
  847.         for (j = 0; j < descriptors.size; j++)
  848.         {
  849.             dist = distance(flags[i].origin, descriptors[j].origin);
  850.             if (!isdefined(closestdist) || dist < closestdist) {
  851.                 closestdist = dist;
  852.                 closestdesc = descriptors[j];
  853.             }
  854.         }
  855.        
  856.         if (!isdefined(closestdesc)) {
  857.             maperrors[maperrors.size] = "there is no flag_descriptor in the map! see explanation in dom.gsc";
  858.             break;
  859.         }
  860.         if (isdefined(closestdesc.flag)) {
  861.             maperrors[maperrors.size] = "flag_descriptor with script_linkname \"" + closestdesc.script_linkname + "\" is nearby more than one flag; is there a unique descriptor near each flag?";
  862.             continue;
  863.         }
  864.         flags[i].descriptor = closestdesc;
  865.         closestdesc.flag = flags[i];
  866.         descriptorsByLinkname[closestdesc.script_linkname] = closestdesc;
  867.     }
  868.    
  869.     if (maperrors.size == 0)
  870.     {
  871.         // find adjacent flags
  872.         for (i = 0; i < flags.size; i++)
  873.         {
  874.             if (isdefined(flags[i].descriptor.script_linkto))
  875.                 adjdescs = strtok(flags[i].descriptor.script_linkto, " ");
  876.             else
  877.                 adjdescs = [];
  878.             for (j = 0; j < adjdescs.size; j++)
  879.             {
  880.                 otherdesc = descriptorsByLinkname[adjdescs[j]];
  881.                 if (!isdefined(otherdesc) || otherdesc.targetname != "flag_descriptor") {
  882.                     maperrors[maperrors.size] = "flag_descriptor with script_linkname \"" + flags[i].descriptor.script_linkname + "\" linked to \"" + adjdescs[j] + "\" which does not exist as a script_linkname of any other entity with a targetname of flag_descriptor (or, if it does, that flag_descriptor has not been assigned to a flag)";
  883.                     continue;
  884.                 }
  885.                 adjflag = otherdesc.flag;
  886.                 if (adjflag == flags[i]) {
  887.                     maperrors[maperrors.size] = "flag_descriptor with script_linkname \"" + flags[i].descriptor.script_linkname + "\" linked to itself";
  888.                     continue;
  889.                 }
  890.                 flags[i].adjflags[flags[i].adjflags.size] = adjflag;
  891.             }
  892.         }
  893.     }
  894.    
  895.     // assign each spawnpoint to nearest flag
  896.     spawnpoints = maps\mp\gametypes\_spawnlogic::getSpawnpointArray( "mp_dom_spawn" );
  897.     for (i = 0; i < spawnpoints.size; i++)
  898.     {
  899.         if (isdefined(spawnpoints[i].script_linkto)) {
  900.             desc = descriptorsByLinkname[spawnpoints[i].script_linkto];
  901.             if (!isdefined(desc) || desc.targetname != "flag_descriptor") {
  902.                 maperrors[maperrors.size] = "Spawnpoint at " + spawnpoints[i].origin + "\" linked to \"" + spawnpoints[i].script_linkto + "\" which does not exist as a script_linkname of any entity with a targetname of flag_descriptor (or, if it does, that flag_descriptor has not been assigned to a flag)";
  903.                 continue;
  904.             }
  905.             nearestflag = desc.flag;
  906.         }
  907.         else {
  908.             nearestflag = undefined;
  909.             nearestdist = undefined;
  910.             for (j = 0; j < flags.size; j++)
  911.             {
  912.                 dist = distancesquared(flags[j].origin, spawnpoints[i].origin);
  913.                 if (!isdefined(nearestflag) || dist < nearestdist)
  914.                 {
  915.                     nearestflag = flags[j];
  916.                     nearestdist = dist;
  917.                 }
  918.             }
  919.         }
  920.         nearestflag.nearbyspawns[nearestflag.nearbyspawns.size] = spawnpoints[i];
  921.     }
  922.    
  923.     if (maperrors.size > 0)
  924.     {
  925.         println("^1------------ Map Errors ------------");
  926.         for(i = 0; i < maperrors.size; i++)
  927.             println(maperrors[i]);
  928.         println("^1------------------------------------");
  929.        
  930.         error("Map errors. See above");
  931.         maps\mp\gametypes\_callbacksetup::AbortLevel();
  932.        
  933.         return;
  934.     }
  935. }
  936.  
  937. initGametypeAwards()
  938. {
  939.     maps\mp\_awards::initStatAward( "pointscaptured", 0, maps\mp\_awards::highestWins );
  940. }
  941.  
  942. onSpawnPlayer()
  943. {
  944. }
  945.  
  946. updateCPM()
  947. {
  948.     if ( !isDefined( self.CPM ) )
  949.     {
  950.         self.numCaps = 0;
  951.         self.CPM = 0;
  952.     }
  953.    
  954.     self.numCaps++;
  955.    
  956.     if ( getMinutesPassed() < 1 )
  957.         return;
  958.        
  959.     self.CPM = self.numCaps / getMinutesPassed();
  960. }
  961.  
  962. getCapXPScale()
  963. {
  964.     if ( self.CPM < 4 )
  965.         return 1;
  966.     else
  967.         return 0.25;
  968. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!