var skin_critters 1

goto analyze
analyze_pp:
    pause
analyze:
    matchre analyze_pp ^\.\.\.wait
    matchre analyze ^You fail to find any holes
    matchre analyze_weakness_check ^You reveal (a|an) (\w+) weakness
    matchre analyze_weakness_check ^Your analysis reveals (a|an) (\w+) opening
    matchre analyze_weakness_check_engage ^You must be closer
    matchre face_next ^Analyze what
    put analyze
    matchwait

analyze_weakness_check_facenext_pp:
    pause
analyze_weakness_check_facenext:
    matchre analyze_weakness_check_facenext_pp ^\.\.\.wait
    matchre analyze_weakness_check ^You turn to face
    matchre analyze_weakness_check_facenext ^There is nothing else to face!
    put face next
    matchwait


analyze_weakness_check_engage_pp:
    pause
analyze_weakness_check_engage:
    matchre analyze_weakness_check_engage_pp ^\.\.\.wait
    matchre analyze_weakness_check_pp ^You begin to advance
    matchre analyze_weakness_check_pp ^You are already advancing
    matchre analyze_weakness_check ^You are already at melee
    matchre analyze_weakness_check_facenext ^What do you want to advance towards?
    put engage
    matchwait
analyze_weakness_check_pp:
    pause
analyze_weakness_check:
    if $2!=massive && $2!=exceptional then goto analyze
analyze_weakness_refresh:
    matchre analyze_weakness_check_pp ^\.\.\.wait
    matchre analyze_weakness_check ^You fail to find any holes
    matchre analyze_weakness_check_engage ^You must be closer
    matchre store_combo ^Armor reduction can be inflicted by landing (a|an) (.+)\.
    matchre store_combo ^Balance reduction can be inflicted upon the enemy by landing (a|an) (.+)\.
    matchre store_combo ^Balance reduction can be inflicted by landing (a|an) (.+)\.
    matchre store_combo ^A chance for a stun can be inflicted upon the enemy by landing (a|an) (.+)\.
    matchre store_combo ^A chance for a stun can be inflicted by landing (a|an) (.+)\.
    matchre face_next ^Analyze what
    put analyze
    matchwait

store_combo:
    var combo_list $2
    eval combo_list replacere("%combo_list","(, a |, an | and a | and an )","|")
    var combo_time $gametime
    echo combo_list is %combo_list
    goto do_combo_init
face_next_pp:
    pause
face_next:
    matchre face_next_pp ^\.\.\.wait
    put face next
    matchwait 1
    goto analyze

do_combo_init:
    counter set 0
    goto do_combo
do_combo_decrement:
    counter subtract 1
    goto do_combo
do_combo_pp:
    counter subtract 1
    pause
do_combo:
    if %c>count("%combo_list","|") then goto done
    evalmath timediff $gametime-%combo_time
    if %timediff>20 then goto analyze_weakness_refresh
    echo counter is %c move is %combo_list(%c)
    var action %combo_list(%c)
    counter add 1
    matchre do_combo_pp ^\.\.\.wait
    matchre done Utilizing flawless tactics you outmaneuver
    matchre done falls the the ground and lies still.
    matchre done shudders and then suddenly stops all movement
    matchre done shuddering and moaning until it ceases all movement
    matchre attack_hit The $righthandnoun lands
    match do_combo_decrement Roundtime
    put %action
    matchwait

attack_hit:
    if %skin_critters then
    {
        if contains("$roomobjs","which appears dead") then goto skin
    }
    goto do_combo

skin_pp:
    pause
skin:
    matchre skin_pp ^\.\.\.wait
    matchre loot ^Skin what
    matchre loot ^You carefully fit
    match drop_skin Roundtime
    put skin
    matchwait

drop_skin_pp:
    pause
drop_skin:
    matchre loot ^What were you referring
    matchre loot ^You drop
    matchre drop_skin_pp ^\.\.\.wait
    put drop $lefthandnoun
    matchwait

loot_pp:
    pause
loot:
    matchre loot_pp ^\.\.\.wait
    matchre done ^You search the
    matchre done ^I could not find what
    put loot treasure
    matchwait


done:
if $Tactics.LearningRate<34 then
{
    if $stamina>90 then
    {
        echo Starting a new combo!
        goto analyze
    }
    pause 1
    echo Pausing for low stamina!
    goto done
}

echo Tactics locked!