;**** Wrapper Directives  ****
#AutoIt3Wrapper_icon=..\Downloads\favicon.ico
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_Res_Comment=Made by Lan @ Syber Security.
#AutoIt3Wrapper_Res_Description=Gaiaonline Friend Adding Bot
#AutoIt3Wrapper_Res_Fileversion=1.0.0.0
#AutoIt3Wrapper_Res_LegalCopyright=Syber Security
;**** End Of Wrapper Directives ****

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <File.au3>
#include <Misc.au3>
#include "GaiaHTTP.au3"

Dim $aForm[2], $aMenu[2], $aMenuItem[3], $aMemo[1], $aGroup[2], $aBtn[3], $aLabel[3], $aInput[3], $aTrayItem[5]
Global $fToggleBool = False, $sUniversalMsg, $hTxt, $fAuthenticated

AutoItSetOption("GUIOnEventMode", 1)
AutoItSetOption("TrayMenuMode", 1)
AutoItSetOption("TrayOnEventMode", 1)

If _Singleton(@ScriptName) Then
    MsgBox(16, "Error", "An instance of this program already exists.")
    Exit
EndIf

HotKeySet("{ESC}", "Close")

$aForm[0] = GUICreate("Gaia Friend Inviter - by Syber Sec", 250, 254, 247, 125, BitOR($WS_SYSMENU, $WS_CAPTION, $WS_POPUP, $WS_POPUPWINDOW, $WS_BORDER, $WS_CLIPSIBLINGS))
GUISetFont(9, 400, 0, "Tahoma")
$aMenu[0] = GUICtrlCreateMenu("File")
$aMenuItem[0] = GUICtrlCreateMenuItem("Login", $aMenu[0])
$aMenu[1] = GUICtrlCreateMenu("Help")
$aMenuItem[1] = GUICtrlCreateMenuItem("About", $aMenu[1])
$aMemo[0] = GUICtrlCreateEdit("", 32, 24, 193, 105)
GUICtrlSetLimit(-1, 200)
$aGroup[0] = GUICtrlCreateGroup("Universal Request Message", 24, 8, 209, 129)
$aBtn[0] = GUICtrlCreateButton("...", 16, 152, 51, 25, $WS_GROUP)
$aInput[0] = GUICtrlCreateInput("", 72, 154, 161, 22, BitOR($ES_AUTOHSCROLL, $ES_READONLY))
GUICtrlSetBkColor(-1, 0xFFFFFF)
$aGroup[1] = GUICtrlCreateGroup("User List", 8, 137, 233, 47)
$aBtn[1] = GUICtrlCreateButton("Start", 72, 188, 107, 25, $WS_GROUP)
$aLabel[0] = GUICtrlCreateLabel("Status: Ready", 4, 216, 89, 15)
GUICtrlSetFont(-1, 10, 400, 0, "Tahoma")
$aTrayItem[0] = TrayCreateItem("Restore")
$aTrayItem[1] = TrayCreateItem("")
$aTrayItem[2] = TrayCreateItem("Exit")
$aTrayItem[3] = TrayCreateItem("")
$aTrayItem[4] = TrayCreateItem("Reload")
GUISetOnEvent($GUI_EVENT_CLOSE, "Close")
GUICtrlSetOnEvent($aMenuItem[0], "Login")
GUICtrlSetOnEvent($aMenuItem[1], "About")
GUICtrlSetOnEvent($aBtn[0], "UserSelection")
GUICtrlSetOnEvent($aBtn[1], "Start")
TrayItemSetOnEvent($aTrayItem[0], "Restore")
TrayItemSetOnEvent($aTrayItem[2], "Close")
TrayItemSetOnEvent($aTrayItem[4], "Reload")
GUISetState()

While 1
    Sleep(10)
WEnd

Func Close()
    Exit
EndFunc   ;==>Close

Func Login()
    $aForm[1] = GUICreate("Gaia Friend Adder | Gaia Online Login", 254, 100, 192, 124, -1, BitOR($WS_EX_TOOLWINDOW, $WS_EX_WINDOWEDGE))
    GUISetFont(9, 400, 0, "Tahoma")
    $aInput[1] = GUICtrlCreateInput("", 75, 8, 169, 22)
    $aLabel[1] = GUICtrlCreateLabel("Username:", 8, 10, 67, 20)
    GUICtrlSetFont(-1, 10, 400, 0, "Tahoma")
    $aInput[2] = GUICtrlCreateInput("", 75, 40, 169, 22, BitOR($ES_PASSWORD, $ES_AUTOHSCROLL))
    $aLabel[2] = GUICtrlCreateLabel("Password:", 8, 42, 64, 20)
    GUICtrlSetFont(-1, 10, 400, 0, "Tahoma")
    $aBtn[2] = GUICtrlCreateButton("Submit", 88, 72, 91, 25, $WS_GROUP)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Close")
    GUICtrlSetOnEvent($aBtn[2], "_Login")
    GUISetState(@SW_SHOW)
EndFunc   ;==>Login

Func _Close()
    GUIDelete($aForm[1])
EndFunc   ;==>_Close

Func _Login()
    $fsSID = _GLogin(_URLEncode(GUICtrlRead($aInput[1])), GUICtrlRead($aInput[2]))
    If StringLen($fsSID) >= 47 Then
        MsgBox(64, "Success", "Login successful; access granted!")
        $fAuthenticated = 1
        _Close()
    Else
        MsgBox(16, "Failure", "Login unsuccessful. Please enter valid user information and try again.")
        GUICtrlSetData($aInput[1], "")
        GUICtrlSetData($aInput[2], "")
    EndIf
EndFunc   ;==>_Login

Func About()
    MsgBox(4096, "About", "Created by The UnIntellgible/Lan of Syber Security." & @CRLF & @CRLF & "Copyright (c) 2011 Syber Security.")
EndFunc   ;==>About

Func UserSelection()
    $hTxt = FileOpenDialog("Choose users via Text file", @ScriptDir & "\", "Text Files (*.txt;*.text)", 1 + 4)
    If $hTxt <> '' Then
        MsgBox(64, "", "User list successfully loaded!")
    Else
        MsgBox(16, "", "No txt file selected. Please try again.")
    EndIf
    GUICtrlSetData($aInput[0], $hTxt)
EndFunc   ;==>UserSelection

Func Main()
    $iSuccesses = 0
    $iLines = _FileCountLines($hTxt)
    For $i = 1 To $iLines
        $sUser = FileReadLine($hTxt, $i)
        $fResult = _AddFriend($sUser, $sUniversalMsg)
        If $fResult Then $iSuccesses += 1
    Next
    If $fToggleBool <> False Then
        TrayTip("Gaia Friend Adder", "Friend request(s) successfully sent to approximately " & $iSuccesses & '/' & $iLines & _
        " people.", 3000)
    EndIf
    $fToggleBool = False
    GUICtrlSetData($aBtn[1], "Start")
    AdlibUnRegister("Main")
    GUICtrlSetData($aLabel[0], "Status: Ready")
EndFunc   ;==>Main

Func Start()
    If $fAuthenticated And GUICtrlRead($aInput[0]) <> $sNullStr Then
        If $fToggleBool Then
            $fToggleBool = False
            GUICtrlSetData($aBtn[1], "Start")
            AdlibUnRegister("Main")
            TrayTip("Gaia Friend Adder", "Autonomous friend adding process has stopped.", 2000)
            GUICtrlSetData($aLabel[0], "Status: Ready")
        Else
            $fToggleBool = True
            TrayTip("Gaia Friend Adder", "Autonomous friend adding process has started.", 2000)
            GUICtrlSetData($aBtn[1], "Stop")
            $sUniversalMsg = GUICtrlRead($aMemo[0])
            AdlibRegister("Main", 100)
            GUICtrlSetData($aLabel[0], "Status: Active")
        EndIf
    Else
        MsgBox(16, "Technical Error", "No user authenticated and/or user list loaded. Please meet these requirements and try again.")
    EndIf
EndFunc   ;==>Start

Func Restore()
    WinActivate($aForm[0])
EndFunc   ;==>Restore

Func Reload()
    ShellExecute(@ScriptFullPath)
    Exit
EndFunc   ;==>Reload