Advertisement
Guest User

Untitled

a guest
May 15th, 2017
594
0
Never
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
text 23.63 KB | None | 0 0
  1. #############################################################################
  2. ; # Options alias/menu #
  3. ; #############################################################################
  4. alias Startup_Manager {
  5. dialog $iif($dialog(Startup),-v,-m) Startup Startup
  6. }
  7. menu * {
  8. Startup Manager:/Startup_Manager
  9. }
  10. ; #############################################################################
  11. ; # Options dialog #
  12. ; #############################################################################
  13. dialog -l Startup {
  14. title "Auto Startup Manager"
  15. size -1 -1 275 240
  16. option dbu
  17. box "Networks", 1, 4 2 130 100
  18. list 2, 10 10 65 85, size
  19. button "Add", 3, 78 10 40 15
  20. button "Delete", 4, 78 30 40 15
  21. button "Move up", 5, 78 50 40 15
  22. button "Move down", 6, 78 70 40 15
  23. box "Channels", 7, 140 2 130 100
  24. list 8, 146 10 65 85, size
  25. button "Add", 9, 214 11 40 15
  26. button "Delete", 10, 214 30 40 15
  27. button "Move up", 11, 214 50 40 15
  28. button "Move down", 12, 214 70 40 15
  29. box "Network Information and Options", 13, 4 105 130 125
  30. text "Address:", 16, 8 112 42 8
  31. text "Port:", 17, 101 112 14 8
  32. edit "", 18, 8 120 86 10
  33. text ":", 19, 94 120 4 8, center
  34. edit "", 20, 97 120 19 10, limit 4
  35. text "Description:", 21, 8 132 30 8
  36. edit "", 22, 8 140 121 10, autohs
  37. text "Nick on this network:", 23, 8 155 53 8
  38. edit "", 24, 59 153 50 10
  39. check "Connect on startup", 25, 8 165 58 10
  40. button "Perform commands", 14, 70 165 60 10
  41. check "Enable Auto ID/Auth", 26, 8 176 63 10
  42. check "Enable auto ghost", 27, 72 176 54 10
  43. text "Auth Type:", 28, 6 190 30 8, right
  44. combo 29, 38 190 50 10, drop
  45. text "User name:", 30, 6 203 30 8, right
  46. edit "", 31, 38 202 50 10, autohs
  47. text Pasword:, 32, 6 214 30 8, right
  48. edit "", 33, 38 213 50 10, password autohs
  49. box "Channel Information and Options", 34, 140 105 130 117
  50. text "Description:", 35, 144 112 34 8
  51. edit "", 36, 144 120 121 10, autohs
  52. check "Message when you join (identifiers allowed)", 37, 144 133 115 10
  53. edit "", 38, 144 143 121 10, autohs
  54. check "Message when others join (identifiers allowed)", 43, 144 156 120 10
  55. edit "", 44, 144 166 121 10, autohs
  56. check "Join on connect", 45, 144 180 50 10
  57. text "Key:", 46, 195 181 10 10
  58. edit "", 47, 210 180 50 10, password autohs
  59. check "Identify to Chanserv", 39, 144 190 63 10
  60. text Pasword:, 40, 145 200 30 8, right
  61. edit "", 41, 176 200 50 10, password autohs
  62. check "Set +q (founder access)", 42, 152 210 71 10
  63. button "Close", 48, 229 224 40 15, ok
  64. }
  65. ; #############################################################################
  66. ; # Perform dialog #
  67. ; #############################################################################
  68. dialog -l Perform {
  69. title "Perfoms"
  70. size -1 -1 135 139
  71. option dbu
  72. box "", 2, 3 3 128 115
  73. box "Performs", 1, 3 3 128 25
  74. text "Enter any commands to be performed upon connecting. One command per line.", 3, 9 11 119 16, center
  75. text "Network:", 4, 8 32 23 8
  76. combo 5, 33 31 60 10, drop
  77. edit "", 6, 7 45 120 70, multi hsbar vsbar return
  78. button "Close", 7, 94 121 37 15, ok
  79. }
  80. ; #############################################################################
  81. ; # Dialog Initiation events #
  82. ; #############################################################################
  83. on *:dialog:Startup:init:*: {
  84. var %x = 1, %networks = $readini(Startup.ini,Config,networks), %total = $numtok(%networks,44)
  85. while (%x <= %total) {
  86. var %network = $gettok(%networks,%x,44)
  87. did -a $dname 2 %network
  88. inc %x
  89. }
  90. did -a $dname 29 Nickserv
  91. did -a $dname 29 Authserv
  92. did -a $dname 29 Quakenet (Q)
  93. did -a $dname 29 Undernet (X)
  94. did -a $dname 29 NetGamers (P)
  95. did -b $dname 9,10,11,12,14,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33,35,36,37,38,39,40,41,42,43,44,45,46,47
  96. }
  97. on *:dialog:Perform:init:*: {
  98. var %Network = %Perform.Network | unset %Perform.Network
  99. var %networks = $readini(Startup.ini,config,networks)
  100. var %x = 1, %total = $numtok(%networks,44)
  101. while (%x <= %total) {
  102. var %net = $gettok(%networks,%x,44)
  103. if (%net == %Network) did -ac $dname 5 %net
  104. else did -a $dname 5 %net
  105. inc %x
  106. }
  107. LoadPerforms %network
  108. }
  109. ; #############################################################################
  110. ; # Dialog Sclick events #
  111. ; #############################################################################
  112. on *:dialog:Startup:sclick:*: {
  113. var %network = $did(2).seltext, %networks = $readini(Startup.ini,config,networks)
  114. var %channel = $did(8).seltext, %chans = $readini(Startup.ini,$replace(%network,$chr(32),-),channels)
  115. if ($did == 2) && ($did(2).sel) {
  116. did -e $dname 9,10,11,12,14,16,17,18,19,20,21,22,23,24,25,26,27
  117. LoadOptions network $did(2).seltext
  118. ClearChanOptions
  119. }
  120. elseif ($did == 3) {
  121. var %network = $$?="Enter the name of the network you wish to add $crlf $crlf $+ Note: This MUST be proper name of the network. If you are unsure of the proper name type //echo -a $ $+ network and copy the result."
  122. if ($istok(%networks,%network,44)) var %x = $input(%network has already been added,oh,Error)
  123. else {
  124. did -a $dname 2 %network
  125. writeini -n Startup.ini $replace(%network,$chr(32),-) name %network
  126. writeini -n Startup.ini $replace(%network,$chr(32),-) nick $me
  127. writeini -n Startup.ini $replace(%network,$chr(32),-) connect 1
  128. writeini -n Startup.ini $replace(%network,$chr(32),-) Authtype 1
  129. var %x = 1, %total = $scon(0)
  130. while (%x <= %total) {
  131. if ($scon(%x).network == %network) {
  132. writeini -n Startup.ini $replace(%network,$chr(32),-) nick $scon(%x).me
  133. writeini -n Startup.ini $replace(%network,$chr(32),-) address $scon(%x).server
  134. writeini -n Startup.ini $replace(%network,$chr(32),-) port $scon(%x).port
  135. }
  136. inc %x
  137. }
  138. var %x = $input(%network has been successfully added. $crlf $+ Edit the network information and options below. $crlf $+ Edit channel options for this server to the right,oi,Success)
  139. }
  140. ArrangeNetworks
  141. }
  142. elseif ($did == 4) {
  143. if ($did(2).sel) {
  144. if ($input(Would you also like to delete the settings saved for %network $+ ?,yq,Delete settings?)) {
  145. remini Startup.ini $replace(%network,$chr(32),-)
  146. }
  147. did -d $dname 2 $did(2).sel
  148. did -b $dname 9,10,11,12,14,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33
  149. did -r $dname 8,18,20,22,24,31,33
  150. did -u $dname 25,26,27
  151. did -c $dname 29 0
  152. }
  153. ArrangeNetworks
  154. }
  155. elseif ($did isnum 5-6) {
  156. var %pos = $did(2).sel, %newpos = $calc($did(2).sel $iif($did == 5,-,+) 1)
  157. if (%newpos == 0) || (%newpos > $did(2).lines) return
  158. else {
  159. did -d $dname 2 %pos
  160. did -i $dname 2 %newpos %network
  161. did -c $dname 2 %newpos
  162. }
  163. ArrangeNetworks
  164. }
  165. elseif ($did == 14) {
  166. set %Perform.network %network
  167. dialog $iif($dialog(Perform),-v,-m) Perform Perform
  168. }
  169. elseif ($did == 25) {
  170. writeini -n Startup.ini %network Connect $did(25).state
  171. }
  172. elseif ($did == 26) {
  173. writeini -n Startup.ini %network Auth $did(26).state
  174. if ($did(26).state == 1) {
  175. did -e $dname 28,29,32,33
  176. if ($did(29).sel > 1) did -e $dname 30,31
  177. else did -b $dname 30,31
  178. }
  179. elseif ($did(27).state == 0) did -b $dname 28,29,30,31,32,33
  180. }
  181. elseif ($did == 27) {
  182. writeini -n Startup.ini %network Ghost $did(27).state
  183. if ($did(27).state == 1) {
  184. did -e $dname 28,29,32,33
  185. if ($did(29).sel > 1) did -e $dname 30,31
  186. else did -b $dname 30,31
  187. }
  188. elseif ($did(26).state == 0) did -b $dname 28,29,30,31,32,33
  189. }
  190. elseif ($did == 29) {
  191. var %Authtype = $did(29).sel
  192. if (%Authtype == 1) { did -b $dname 30,31 | LoadOptions Channel %network %channel }
  193. else { did -e $dname 30,31 | did -b $dname 39,40,41,42 }
  194. if (%Authtype isnum 3-4) did -b $dname 27
  195. else did -e $dname 27
  196. writeini -n Startup.ini %network AuthType %Authtype
  197. }
  198. elseif ($did == 8) && ($did(8).sel) {
  199. did -e $dname 35,36,37,38,43,44,45,46,47
  200. LoadOptions Channel %network $did(8).seltext
  201. }
  202. elseif ($did == 9) {
  203. var %channel = $$?="Enter the name of the channel you wish to add"
  204. var %chans = $readini(Startup.ini,%network,channels)
  205. if ($istok(%chans,%channel,44)) var %x = $input(%channel has already been added,oh,Error)
  206. elseif ($istok(%chans,$+($chr(35),%channel),44)) var %x = $input($+($chr(35),%channel) has already been added,oh,Error)
  207. elseif ($numtok(%channel,32) > 1) var %x = $input(Channel names can not contain spaces,oh,Error)
  208. else {
  209. if ($left(%channel,1) != $chr(35)) var %channel = $+($chr(35),%channel)
  210. did -a $dname 8 %channel
  211. writeini -n Startup.ini $replace(%network,$chr(32),-) %channel NULL¦0¦NULL¦0¦NULL¦1¦0¦NULL¦0
  212. writeini -n Startup.ini $replace(%network,$chr(32),-) channels $addtok(%chans,%channel,44)
  213. }
  214. }
  215. elseif ($did == 10) {
  216. if ($did(8).sel) {
  217. if ($input(Would you also like to delete the settings saved for %channel $+ ?,yq,Delete settings?)) {
  218. remini Startup.ini $replace(%network,$chr(32),-) %channel
  219. }
  220. if ($did(8).lines == 1) remini Startup.ini $replace(%network,$chr(32),-) channels
  221. else writeini -n Startup.ini $replace(%network,$chr(32),-) channels $remtok(%chans,%channel,1,44)
  222. ClearChanOptions
  223. did -d $dname 8 $did(8).sel
  224. }
  225. }
  226. elseif ($did isnum 11-12) {
  227. var %pos = $did(8).sel, %newpos = $calc($did(8).sel $iif($did == 11,-,+) 1)
  228. if (%newpos == 0) || (%newpos > $did(8).lines) return
  229. else {
  230. did -d $dname 8 %pos
  231. did -i $dname 8 %newpos %channel
  232. did -c $dname 8 %newpos
  233. }
  234. ArrangeChans %network
  235. }
  236. elseif ($did == 39) {
  237. if ($did(39).state == 1) did -e $dname 40,41,42
  238. else did -b $dname 40,41,42
  239. SaveChanOptions %network %channel
  240. }
  241. elseif ($did == 37) {
  242. SaveChanOptions %network %channel
  243. if ($did(37).state == 1) did -e $dname 38
  244. else did -b $dname 38
  245. }
  246. elseif ($did == 43) {
  247. SaveChanOptions %network %channel
  248. if ($did(43).state == 1) did -e $dname 44
  249. else did -b $dname 44
  250. }
  251. elseif ($did == 42) || ($did == 45) {
  252. SaveChanOptions %network %channel
  253. }
  254. }
  255. on *:dialog:Perform:sclick:5: {
  256. LoadPerforms $did(5).seltext
  257. }
  258. ; #############################################################################
  259. ; # Dialog Edit events #
  260. ; #############################################################################
  261. on *:dialog:Startup:edit:*: {
  262. var %network = $did(2).seltext, %pos = $did(2).sel
  263. var %channel = $did(8).seltext
  264. if ($did($did)) {
  265. if ($did == 18) writeini -n Startup.ini %network Address $did(18)
  266. elseif ($did == 20) writeini -n Startup.ini %network Port $did(20)
  267. elseif ($did == 22) writeini -n Startup.ini %network Description $did(22)
  268. elseif ($did == 24) writeini -n Startup.ini %network Nick $did(24)
  269. elseif ($did == 31) writeini -n Startup.ini %network User $did(31)
  270. elseif ($did == 33) writeini -n Startup.ini %network Pass $ifencode($did(33),m)
  271. }
  272. else {
  273. if ($did == 18) remini Startup.ini %network Address
  274. elseif ($did == 20) remini Startup.ini %network Port
  275. elseif ($did == 22) remini Startup.ini %network Description
  276. elseif ($did == 24) remini Startup.ini %network Nick
  277. elseif ($did == 31) remini Startup.ini %network User
  278. elseif ($did == 33) remini Startup.ini %network Pass
  279. }
  280. if ($did == 36) || ($did == 38) || ($did == 41) || ($did == 44) || ($did == 47) {
  281. if ($chr(166) isin $did($did)) {
  282. did -ra $dname $did $remove($did($did),$chr(166))
  283. var %x = $input(Due to the character $+(',$chr(166),') being used as a data seperator it may not be used here,oh,Error)
  284. }
  285. SaveChanOptions %network %channel
  286. }
  287. }
  288. on *:dialog:Perform:edit:6: {
  289. var %network = $did(5).seltext
  290. var %x = 1, %total = $did(6).lines
  291. remini StartupPerform.ini %network
  292. while (%x <= %total) {
  293. if ($did(6,%x)) writeini -n StartupPerform.ini %network %x $did(6,%x)
  294. inc %x
  295. }
  296. }
  297.  
  298. ; #############################################################################
  299. ; # Aliases #
  300. ; #############################################################################
  301. alias -l SaveChanOptions {
  302. var %dname = Startup, %network = $1, %channel = $2
  303. var %desc = $iif($did(%dname,36),$ifmatch,NULL)
  304. var %sendmsgme = $did(%dname,37).state
  305. var %joinmsgme = $iif($did(%dname,38),$ifmatch,NULL)
  306. var %sendmsgother = $did(%dname,43).state
  307. var %joinmsgother = $iif($did(%dname,44),$ifmatch,NULL)
  308. var %join = $did(%dname,45).state
  309. var %ID = $did(%dname,39).state
  310. var %Pass = $iif($did(%dname,41),$ifencode($ifmatch,m),NULL)
  311. var %Setq = $did(%dname,42).state
  312. var %key = $iif($did(%dname,47),$ifencode($ifmatch,m),NULL)
  313. var %s = $chr(166)
  314. var %data = $+(%desc,%s,%sendmsgme,%s,%joinmsgme,%s,%sendmsgother,%s,%joinmsgother,%s,%join,%s,%ID,%s,%pass,%s,%Setq,%s,%key)
  315. writeini Startup.ini %network %channel %data
  316. }
  317. alias -l ClearChanOptions {
  318. var %dname = Startup
  319. did -b %dname 35,36,37,38,39,40,41,42,43,44,45,46,47
  320. did -r %dname 36,38,41,44,47
  321. did -u %dname 37,39,42,43,45
  322. }
  323. alias -l LoadOptions {
  324. var %dname = Startup
  325. if ($1 == network) {
  326. var %network = $2
  327. did -r %dname 8
  328. if ($readini(Startup.ini,%network,channels)) {
  329. var %chans = $v1
  330. var %x = 1, %total = $numtok(%chans,44)
  331. while (%x <= %total) {
  332. var %chan = $gettok(%chans,%x,44)
  333. did -a %dname 8 %chan
  334. inc %x
  335. }
  336. }
  337. did -ra %dname 18 $readini(Startup.ini,%network,Address)
  338. did -ra %dname 20 $readini(Startup.ini,%network,Port)
  339. did -ra %dname 22 $readini(Startup.ini,%network,Description)
  340. did -ra %dname 24 $readini(Startup.ini,%network,Nick)
  341. if ($readini(Startup.ini,%network,Connect) == 1) did -c %dname 25 | else did -u %dname 25
  342. if ($readini(Startup.ini,%network,Auth) == 1) did -c %dname 26 | else did -u %dname 26
  343. if ($readini(Startup.ini,%network,Ghost) == 1) did -c %dname 27 | else did -u %dname 27
  344. did -c %dname 29 $readini(Startup.ini,%network,AuthType)
  345. did -ra %dname 31 $readini(Startup.ini,%network,User)
  346. did -ra %dname 33 $ifdecode($readini(Startup.ini,%network,Pass),m)
  347. if ($readini(Startup.ini,%network,Auth) == 1) || ($readini(Startup.ini,%network,Ghost) == 1) {
  348. did -e $dname 28,29,30,31,32,33
  349. if ($readini(Startup.ini,%network,Authtype == 1)) did -b $dname 31
  350. else did -e $dname 31
  351. }
  352. else did -b $dname 28,29,30,31,32,33
  353. }
  354. else {
  355. var %network = $2, %channel = $3
  356. if (!%network) || (!%channel) return
  357. var %data = $readini(Startup.ini,n,%network,%channel)
  358. tokenize 166 %data
  359. if ($1 != NULL) did -ra %dname 36 $1
  360. if ($2 == 1) { did -c %dname 37 | did -e %dname 38 }
  361. else { did -u %dname 37 | did -b %dname 38 }
  362. if ($3 != NULL) did -ra %dname 38 $3
  363. if ($4 == 1) { did -c %dname 43 | did -e %dname 44 }
  364. else { did -u %dname 43 | did -b %dname 44 }
  365. if ($5 != NULL) did -ra %dname 44 $5
  366. if ($6 == 1) did -c %dname 45
  367. else did -u %dname 45
  368. if ($7 == 1) { did -c %dname 39 | did -e %dname 40,41,42 }
  369. else { did -u %dname 39 | did -b %dname 40,41,42 }
  370. if ($8 != NULL) did -ra %dname 41 $ifdecode($8,m)
  371. if ($9 == 1) did -c %dname 42 | else did -u %dname 42
  372. if ($10 != NULL) did -ra %dname 47 $ifdecode($10,m)
  373. if ($did(29).sel != 1) did -b $dname 39,40,41,42
  374. else did -e $dname 39
  375. }
  376. }
  377. alias -l LoadPerforms {
  378. var %dname = Perform, %network = $1
  379. did -r %dname 6
  380. var %x = 1, %total = $ini(StartupPerform.ini,%network,0)
  381. while (%x <= %total) {
  382. did -i %dname 6 %x $readini(StartupPerform.ini,-n,%network,%x)
  383. inc %x
  384. }
  385. }
  386. alias -l ArrangeNetworks {
  387. var %dname = Startup, %x = 1, %total = $did(%dname,2).lines
  388. while (%x <= %total) {
  389. var %networks = $addtok(%networks,$did(2,%x),44)
  390. inc %x
  391. }
  392. if (%networks) writeini -n Startup.ini Config Networks %networks
  393. }
  394. alias -l ArrangeChans {
  395. var %dname = Startup, %network = $1, %x = 1, %total = $did(%dname,8).lines
  396. while (%x <= %total) {
  397. var %chans = $addtok(%chans,$did(8,%x),44)
  398. inc %x
  399. }
  400. if (%chans) writeini -n Startup.ini %network channels %chans
  401. }
  402. ; #############################################################################
  403. ; # Start event #
  404. ; #############################################################################
  405. on *:start: {
  406. var %networks = $readini(Startup.ini,config,networks)
  407. var %x = 1, %total = $numtok(%networks,44), %connects = 1
  408. while (%x <= %total) {
  409. var %network = $gettok(%networks,%x,44), %server = $readini(Startup.ini,%network,address)
  410. var %port = $iif($readini(Startup.ini,%network,port),$ifmatch,6667)
  411. if ($readini(Startup.ini,%network,connect) == 1) {
  412. if (%connects == 1) server %server %port
  413. else server -m %server %port
  414. inc %connects
  415. }
  416. inc %x
  417. }
  418. }
  419. ; #############################################################################
  420. ; # Connect event #
  421. ; #############################################################################
  422. on *:connect: {
  423. if ($ini(Startup.ini,$network)) {
  424. nick $readini(Startup.ini,$network,nick)
  425. if ($readini(Startup.ini,$network,auth) == 1) {
  426. var %authtype = $readini(Startup.ini,$network,AuthType)
  427. var %user = $readini(Startup.ini,$network,User)
  428. var %pass = $ifdecode($readini(Startup.ini,$network,pass),m)
  429. if (%authtype == 1) .msg nickserv identify %pass
  430. elseif (%authtype == 2) .msg AuthServ auth %user %pass
  431. elseif (%authtype == 3) .msg Q@CServe.quakenet.org auth %user %pass
  432. elseif (%authtype == 4) .msg x@channels.undernet.org login %user %pass
  433. elseif (%authtype == 5) .msg P@cservice.netgamers.org login %user %pass
  434. }
  435. var %x = 1
  436. while ($readini(StartupPerform.ini,$network,%x)) {
  437. $v1
  438. inc %x
  439. }
  440. var %chans = $readini(Startup.ini,$network,channels)
  441. var %x = 1, %total = $numtok(%chans,44)
  442. while (%x <= %total) {
  443. var %chan = $gettok(%chans,%x,44), %chandata = $readini(Startup.ini,n,$network,%chan)
  444. var %key = $iif($gettok(%chandata,10,166) != $null,$ifdecode($v1,m))
  445. if ($gettok(%chandata,6,166) == 1) join %chan %key
  446. inc %x
  447. }
  448. }
  449. }
  450. ; #############################################################################
  451. ; # Join event #
  452. ; #############################################################################
  453. on *:join:#: {
  454. if ($readini(Startup.ini,n,$network,$chan)) {
  455. tokenize 166 $v1
  456. if ($nick == $me) {
  457. if ($2 == 1) && ($3 != NULL) msg $chan $($3,2)
  458. if ($7 == 1) {
  459. if ($8 != NULL) .msg chanserv identify $chan $ifdecode($8,m)
  460. if ($9 == 1) .msg chanserv owner $chan
  461. }
  462. }
  463. else {
  464. if ($4 == 1) && ($5 != NULL) msg $chan $($5,2)
  465. }
  466. }
  467. }
  468. ; #############################################################################
  469. ; # Auto ID on nickserv notice. Auth to authserv if @... is required #
  470. ; #############################################################################
  471. on *:notice:*:?: {
  472. if ($readini(Startup.ini,$network,auth) == 1) {
  473. if ($nick == nickserv) || ($nick == authserv) {
  474. var %user = $readini(Startup.ini,$network,user)
  475. var %pass = $ifdecode($readini(Startup.ini,$network,pass),m)
  476. if (*registered and protected* iswm $1-) .msg nickserv identify %pass
  477. elseif ($regex($1-,/Authserv@([^ ]*)/Si)) .msg $regml(1) auth %user %pass
  478. }
  479. }
  480. }
  481.  
  482. ; #############################################################################
  483. ; # Nick in use raw - Auto ghost/recover #
  484. ; #############################################################################
  485. raw 433:*: {
  486. if ($2 == $readini(Startup.ini,$network,nick)) && (!%GhostTimer) {
  487. var %nick = $2
  488. var %authtype = $readini(Startup.ini,$network,AuthType)
  489. var %user = $readini(Startup.ini,$network,User)
  490. var %pass = $ifdecode($readini(Startup.ini,$network,pass),m)
  491. if (%authtype == 1) {
  492. if ($($+(%,dc.,$network),2)) .msg nickserv ghost %nick %pass
  493. else {
  494. .msg nickserv recover %nick %pass
  495. .msg nickserv release %nick %pass
  496. }
  497. }
  498. elseif (%authtype == 2) .msg authserv ghost %nick %pass
  499. elseif (%authtype == 5) .msg P@cservice.netgamers.org recover %nick %user %pass
  500. set -u5 %GhostTimer on
  501. .timer 1 2 nick %nick
  502. }
  503. }
  504. ; #############################################################################
  505. ; # Disconnect event. Set variable to decide between ns ghost and ns release #
  506. ; #############################################################################
  507. on *:disconnect: {
  508. set -u120 $+(%,dc.,$network)
  509. }
  510.  
  511. alias -l ifencode {
  512. if ($version == 6.17) return $1
  513. else return $encode($1)
  514. }
  515. alias -l ifdecode {
  516. if ($version == 6.17) return $1
  517. else return $decode($1)
  518. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement