PKBUILD python2-pillow

# Maintainer: Eli Schwartz <eschwartz@archlinux.org>
# Maintainer: Kyle Keen <keenerd@gmail.com>
# Contributor: minder

_pkgname=Pillow
pkgname=python2-pillow
pkgver=6.2.2
pkgrel=1
pkgdesc="Python Imaging Library (PIL) fork."
arch=('x86_64')
url="https://python-pillow.github.io/"
license=('BSD')
depends=('python2' 'lcms2' 'libtiff' 'openjpeg2' 'libimagequant')
makedepends=('python2-setuptools' 'freetype2' 'libraqm' 'libwebp' 'tk')
optdepends=('freetype2: for the ImageFont module'
            'ghostscript: for EPS images'
            'libraqm: for complex text scripts'
            'libwebp: for webp images'
            'tk: for the ImageTK module'
            'python2-olefile: OLE2 file support')
checkdepends=('python2-pytest' 'xorg-server-xvfb' 'python2-olefile'
              'python2-cffi' 'python2-numpy' 'ghostscript')
provides=('python2-imaging' 'python2-pillow6')
conflicts=('python2-imaging' 'python2-pillow6')
replaces=('python2-imaging' 'python2-pillow6')
source=("https://files.pythonhosted.org/packages/source/${_pkgname:0:1}/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
md5sums=('46cad14f0044a5ac4b2d801271528893')
b2sums=('fcea6b26dbb0abaefa618a8b204c95637018764b066b86da3bd98aebfaf5f9dea7b43cfe5fb248275e6504dac8adc02fb7b3ebcadc76e2af249aca64819d83b0')

build() {
    cd "${srcdir}"/${_pkgname}-${pkgver}

    python2 setup.py build
}

check() {
    cd "${srcdir}"/${_pkgname}-${pkgver}

    export PYTHONPATH="$PWD/build/lib.linux-$CARCH-2.7"
    python2 selftest.py
    # 99.5% of tests pass, just some font rendering giving trouble?
    xvfb-run python2 -m pytest -k "not test_variation_set_by_axes and \
                                   not test_variation_set_by_name and \
                                   not test_complex_unicode_text and \
                                   not test_custom_metadata and \
                                   not test_text_direction_ttb and \
                                   not test_text_direction_ttb_stroke"
}

package() {
    cd "${srcdir}"/${_pkgname}-${pkgver}

    python2 setup.py install --root="${pkgdir}/" --optimize=1
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

    install -dm755 "${pkgdir}/usr/include/python2.7/"
    install -m644 -t "${pkgdir}/usr/include/python2.7/" src/libImaging/*.h
}