;=====================================================================
; 自動ログイン TTL
;=====================================================================

;---------------------------------------------------------------------
; ホスト数
;---------------------------------------------------------------------
HOST_NUM = 1

;---------------------------------------------------------------------
; ホスト設定
;---------------------------------------------------------------------
strdim HOSTIPLIST HOST_NUM
HOSTIPLIST[0] = '255.255.255.255'

strdim HOSTNM HOST_NUM
HOSTNM[0] = 'Friendly Host Name'

for i 0 (HOST_NUM - 1)
strconcat HOSTNM[i] ' ('
strconcat HOSTNM[i] HOSTIPLIST[i]
strconcat HOSTNM[i] ')'
next

;---------------------------------------------------------------------
; ログインユーザ
;---------------------------------------------------------------------
strdim USERLIST HOST_NUM
USERLIST[0] = 'LoginUserName'

;---------------------------------------------------------------------
; ログインパスワード
;---------------------------------------------------------------------
strdim USERPWLIST HOST_NUM
USERPWLIST[0] = 'LoginPassword'

;---------------------------------------------------------------------
; 秘密鍵
;---------------------------------------------------------------------
strdim KEYLIST HOST_NUM
KEYLIST[0] = 'pem key relative path'

;---------------------------------------------------------------------
; 接続先ホスト選択
;---------------------------------------------------------------------
listbox 'Please Select the Host' 'Log on to the Selected Server' HOSTNM
HOSTID = result
if result >= 0 then
    HOSTADDR = HOSTIPLIST[result]
    USERNAME = USERLIST[result]
    PASSWORD = USERPWLIST[result]
    KEYFILE  = KEYLIST[result]
else
    end
endif

; KEY利用チェック
strlen KEYFILE
HASKEY=result

;---------------------------------------------------------------------
; 接続コマンド構築
;---------------------------------------------------------------------
COMMAND = HOSTADDR
strconcat COMMAND ':22 /ssh /2 /user='
strconcat COMMAND USERNAME
strconcat COMMAND ' /passwd='
strconcat COMMAND PASSWORD
if HASKEY != 0 then
    strconcat COMMAND ' /auth=publickey'
    strconcat COMMAND ' /keyfile='
    strconcat COMMAND KEYFILE
else
    strconcat COMMAND ' /auth=password'
endif

;---------------------------------------------------------------------
; 接続
;---------------------------------------------------------------------
connect COMMAND

;---------------------------------------------------------------------
; 接続判定1（接続出来ない場合はメッセージを表示しマクロ終了）
;---------------------------------------------------------------------
if result <> 2 then
    messagebox 'It could not be connected.' 'Connection Error'
    end
endif

;---------------------------------------------------------------------
; 接続判定2（10秒以内にプロンプトが表示されない場合TeraTerm終了）
;---------------------------------------------------------------------
timeout = 10
wait '$' '#' '>'
if result = 0 end

;---------------------------------------------------------------------
; マクロ終了
;---------------------------------------------------------------------
end