on *:TEXT:*:#:{
  set -l %p
  if ($gettok($readini($mircini,options,n2),30,44)) && ($left($nick($chan,$nick).pnick,1) != $left($nick,1)) %p = $v1
  set -l %nick $+(%p,$nick)
  if ((!$appactive) || ($activecid != $cid) || ($active != $target)) && ($tema_me_isin($1-,$target)) tema_mirc_echo_quote normal $target $+($chr(3),$base($tema_cnick(%p $+ $nick),10,10,2),%nick) $1-
}

on *:ACTION:*:#:{
  set -l %p
  if ($gettok($readini($mircini,options,n2),30,44)) && ($left($nick($chan,$nick).pnick,1) != $left($nick,1)) %p = $v1
  set -l %nick $+(%p,$nick)
  if ((!$appactive) || ($activecid != $cid) || ($active != $target)) && ($tema_me_isin($1-,$target)) tema_mirc_echo_quote action $target %nick $1-
}

on *:NOTICE:*:#:if ((!$appactive) || ($activecid != $cid) || ($active != $target)) && ($tema_me_isin($1-,$target)) tema_mirc_echo_quote notice $target $nick $1-

on ^$*:HOTLINK:/\[([\x23\x26].+?)\]/uS:@Citações *:if ($me !ison $regml(1)) halt

on $*:HOTLINK:/\[([\x23\x26].+?)\]/uS:@Citações *:{
  if ($me !ison $regml(1)) halt
  set -l %pos $gettok($hotlinepos,1,32)
  tokenize 32 $strip($hotline)
  window -a $regml(1)
  findtext -n $strip($line($regml(1),$line($regml(1),0)))
  findtext $1- [ $+ [ $calc(%pos - 1) ] ] $ [ $+ [ $calc(%pos + 1) ] $+ ] -
}

alias tema_mirc_echo_quote {
  window -g2 $2
  if ($tema_config(quote_tip)) && (!$appactive) noop $tip($+(tip_,$ticks,$rand(1111,9999)),$upper($1) - $4 citou seu nick,$7-,$tema_config(quote_tip_delay),$null,$null,window -a $1)
  if ($tema_config(quote_flash)) !flash
  if (!$tema_config(quote_enable)) return
  set -l %cwin $+(@Citações,$chr(160),$network,$chr(160),$cid)
  set -l %nick $3
  if (normal == $1) %nick = $+(<,%nick,$chr(3),>)
  elseif (action == $1) %nick = * %nick
  elseif (notice == $1) %nick = $+(-,%nick,:,$2,-)
  if (!$window(%cwin)) window $iif($tema_config(quote_hide),-vhw0,-vn2) %cwin
  else !echo %cwin $chr(160)
  !echo -tci2 $1 %cwin %nick $+([,$2,]) $4-
}