print "INIT ",pc
	%SubHorzPos()
	TYA
	STA $157C, x
	RTL

print "MAIN ",pc
PHB : PHK : PLB
	JSR SpriteCode
	PLB : RTL

XSpeed:
	db $08, $F8

Return:
	RTS

SpriteCode:
	JSR Graphics

	LDA $14C8, x
	CMP #$08
	BNE Return
	LDA $9D
	BNE Return

	LDA #$00
	%SubOffScreen()

	LDA $1588, x
	AND #$03
	BEQ NotTouchingWall

		LDA $157C, x
		EOR #$01
		STA $157C, x

	NotTouchingWall:

	LDA $1588, x
	AND #$04
	BEQ NotOnGround

		LDY $157C, x
		LDA XSpeed, y
		STA $B6, x

		LDA #$10
		STA $AA, x

	NotOnGround:

	JSL $01802A

	JSL $018032

	JSL $01A7DC
	BCC NoMarioContact

		LDA $0E
		CMP #$E6
		BPL SpriteWins

			JSL $01AB99
			JSL $01AA33
			LDA $140D
			ORA $187A
			BNE SpinKill

			LDA #$10
			STA $AA, x
			LDA #$02
			STA $14C8, x
			JSL $01802A
			LDA #$14
			STA $1DF9
			RTS

		SpinKill:
			LDA #$04
			STA $14C8, x
			LDA #$08
			STA $1DF9
			JSL $07FC3B
			RTS

		SpriteWins:

			LDA $1490
			BNE HasStar

			JSL $00F5B7
			RTS

			HasStar:
				%Star()

	NoMarioContact:

	RTS

TileMap:
	db $CA, $CC

FlipMask:
	db $40, $00

Graphics:
	%GetDrawInfo()

	LDA $157C, x
	STA $02

	LDA $00
	STA $0300, y
	LDA $01
	STA $0301, y

	PHX
	LDA $14
	LSR
	LSR
	LSR
	AND #$01
	TAX
	LDA TileMap, x
	STA $0302, y
	PLX

	LDA $15F6, x

	PHX
	LDX $02
	ORA FlipMask, x
	PLX

	ORA $64
	STA $0303, y

	LDY #$02
	LDA #$00

	JSL $01B7B3
	RTS