#include "script_macros.hpp"
/*
	File: initPlayerLocal.sqf

	Description:
	Starts the initialization of the player.
*/
if (!hasInterface && !isServer) exitWith {
    [] spawn compile PreprocessFileLineNumbers "\life_hc\initHC.sqf";
}; //This is a headless client.
CONST(BIS_fnc_endMission,BIS_fnc_endMission);
[] execVM "core\functions\fn_emptyFuel.sqf";
[] execVM "core\init.sqf";
[] execVM "addons\init.sqf";

//Execute JIP code.
if((_this select 1)) then {
	[] execVM "core\jip.sqf";
};

AP_CUSTOM_RAPPEL_POINTS = [
	["EC635_Unarmed",[[0.75,0.9,-1],[-0.75,0.9,-1],[0.75,2,-1],[-0.75,2,-1]]],
	["EC635_Gendarmerie",[[0.75,0.9,-1],[-0.75,0.9,-1],[0.75,2,-1],[-0.75,2,-1]]]
];

[false] spawn life_fnc_simulationManager;

//Paramètres touches

["AmepanLife.com","interaction_key", ["Touche d'intéraction", "Permet de récolter et d'intéragir avec les bâtiments"], {
	[] spawn {
		[] call life_fnc_actionKeyHandler;
		life_action_inUse = false;
	};
}, "", [157, [false, false, false]]] call CBA_fnc_addKeybind; //Touche Ctrl Droit

["AmepanLife.com","player_menu_key", ["Menu principal", "Affiche la tablette permetant d'accéder aux clés, téléphone, gangs, etc (Le menu du joueur)"], {
	if((!dialog && isNull (findDisplay 49)) && !life_action_inUse) then {
		[] call life_fnc_p_openMenu;
	};
}, "", [21, [false, false, false]]] call CBA_fnc_addKeybind; //Touche Y

["AmepanLife.com","trunk_key", ["Coffre", "Permet d'ouvrir le coffre virtuel d'un véhicule ou d'un bâtiment"], {call life_fnc_trunkHandler}, "", [20, [false, false, false]]] call CBA_fnc_addKeybind; //Touche T
["AAmepanLife.com","lock_key", ["Verrouiller", "Permet de verrouiller ou de déverrouiller un véhicule ou une porte"], {call life_fnc_lockHandler}, "", [22, [false, false, false]]] call CBA_fnc_addKeybind; //Touche U

["AmepanLife.com","surrend_key", ["Se rendre", "Permet de mettre les mains sur la tête"],
{
	if (vehicle player == player && !(player getVariable ["ACE_Captives_isHandcuffed", false])) then {
		[player, !(player getVariable ["ACE_Captives_isSurrendering",false])] call ACE_captives_fnc_setSurrendered;
	};
}, "", [38, [true, false, false]]] call CBA_fnc_addKeybind; //Touche Shift + L

["AmepanLife.com","knockout_key", ["Assomer", "Permet d'assomer un joueur si l'on possède une arme"],
{
	if(!isNull cursorTarget && (cursorTarget isKindOf "Man") && isPlayer cursorTarget && alive cursorTarget && (cursorTarget distance player < 4) && (speed cursorTarget < 1)) then {
		if (!((animationState cursorTarget) isEqualTo "Incapacitated") && !((animationState cursorTarget) isEqualTo"CL3_anim_Knockout1In") && !((animationState cursorTarget) isEqualTo"Helper_InjuredRfl") && (currentWeapon player isEqualTo primaryWeapon player OR currentWeapon player == handgunWeapon player) && (currentWeapon player != "") && !life_knockout && !(player GVAR ["ACE_Captives_isHandcuffed",false]) && !life_istazed) then {
			[cursorTarget] spawn life_fnc_knockoutAction;
		};
	};
}, "", [34, [true, false, false]]] call CBA_fnc_addKeybind; //Touche Shift + G

["AmepanLife.com","earplugs_key", ["Bouchons d'oreilles", "Permet de réduire le son du jeu (à condition de posséder une paire de bouchons)"], {call life_fnc_handleEarplugs}, "", [59, [false, false, false]]] call CBA_fnc_addKeybind;

["AmepanLife.com","radar_key", ["Radar (Gendarme)", "Permet de connaître la vitesse d'un véhicule (Gendarme)"],
{
	if (isNull (objectParent player)) then { [] call life_fnc_radar; } else { [] call life_fnc_vehRadar; };
}, "", [38, [false, false, false]]] call CBA_fnc_addKeybind; //Touche L

["AmepanLife.com","restrain_key", ["Menotter (Gendarme / Armée)", "Permet de menotter un joueur (Gendarme / Armée)"],
{
	if(playerSide in [west,east] && !isNull cursorTarget && (cursorTarget isKindOf "Man") && (isPlayer cursorTarget) && (alive cursorTarget && cursorTarget distance player < 3.5) && (speed cursorTarget < 1)) then {
		[] call life_fnc_restrainAction;
	};
}, "", [19, [true, false, false]]] call CBA_fnc_addKeybind; //Touche Shift + R