#TouhouDanmakufu[Single]
#ScriptVersion[3]
#Title["Test1"]
#Text["By AVeryConcernedSheep"]

#include"script/default_system/Default_ShotConst.txt"

let objEnemy;
let frame = 0;
let frame2 = -50;
let ac = 0;
let movecounter = -5;
@Event
{
	alternative(GetEventType())
	case(EV_REQUEST_LIFE)
	{
		SetScriptResult(2000);
	}
}

@Initialize
{
	objEnemy = ObjEnemy_Create(OBJ_ENEMY_BOSS);
	ObjEnemy_Regist(objEnemy);

	let imgExRumia = GetCurrentScriptDirectory ~ "ExRumia.png";
	ObjPrim_SetTexture(objEnemy, imgExRumia);
	ObjSprite2D_SetSourceRect(objEnemy, 64, 1, 127, 64);
	ObjSprite2D_SetDestCenter(objEnemy);

	let stx = GetStgFrameWidth() / 2;
	ObjMove_SetDestAtFrame(objEnemy, stx, 60, 60)
}

@MainLoop
{
	let ex = ObjMove_GetX(objEnemy);
	let ey = ObjMove_GetY(objEnemy);
	let px = GetPlayerX;
	let py = GetPlayerY;
	let ap = atan2(py - ey, px - ex);
	let kn = 18;
	let kl = 0;
	let str = GetStgFrameWidth() / 8;
	let stl = GetStgFrameWidth() / 8 * 7;
	let stmx = GetStgFrameWidth() / 2;
	let stmy = GetStgFrameHeight() / 2;
	let stu = 60;
	let std = GetStgFrameHeight() - 60;

	frame++;
	frame2++;

	alternative(movecounter)
	case(25){
		ObjMove_SetDestAtFrame(objEnemy, str, stmy, 150);
	}
	case(50){
		ObjMove_SetDestAtFrame(objEnemy, stmx, std, 150);
	}
	case(75){
		ObjMove_SetDestAtFrame(objEnemy, stl, stmy, 150);
	}
	case(100){
		ObjMove_SetDestAtFrame(objEnemy, stmx, stu, 150);
		movecounter = 0
	}

	if(frame == 60)
	{
		ascent(i in -4..5)
		{
			CreateShotA1(ex, ey, 2, ap + 15*i, DS_BALL_L_GREEN, 15);
		}
		frame = 0;
	}

	if(frame2 == 10)
	{
		loop(kn)
		{
			CreateShotA1(ex, ey, 3, 0 + kl + ac, DS_KUNAI_BLUE, 10);
			kl += 360 / kn;
		}
		frame2 = 0;
		ac += 7;
		movecounter++;
	}


	ObjEnemy_SetIntersectionCircleToShot(objEnemy, ex, ey, 32);
	ObjEnemy_SetIntersectionCircleToPlayer(objEnemy, ex, ey, 24);


	if(ObjEnemy_GetInfo(objEnemy, INFO_LIFE) <= 0)
	{
		Obj_Delete(objEnemy);
		CloseScript(GetOwnScriptID());
		return;
	}
}