# Maintainer: Thomas Krug <t.krug@elektronenpumpe.de>
# Contributor: Thomas Krug <t.krug@elektronenpumpe.de>

pkgname=gerbv-git
_pkgname=gerbv
pkgver=r1515.83a3fb6
pkgrel=1
pkgdesc="An open source Gerber file (RS-274X only) viewer"
url="http://gerbv.geda-project.org/"
license=('GPL')
arch=('i686' 'x86_64')
depends=('gtk2')
provides=('gerbv')
conflicts=('gerbv')
optdepends=('cairo: for better graphics')
makedepends=('git' 'gettext')
install=$pkgname.install
source=("$_pkgname"::'git://git.geda-project.org/gerbv.git' 'https://sourceforge.net/p/gerbv/patches/70/attachment/0001-put-space-between-flags.patch')
md5sums=('SKIP' '944cd5faa69e80934b558ebc396ea13b')

pkgver() {
  cd "$srcdir/$_pkgname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/$_pkgname"
  patch -p1 < ../0001-put-space-between-flags.patch
  ./autogen.sh
  sed -i 's|am_aux_dir=`cd $ac_aux_dir|am_aux_dir=`cd $srcdir|' configure
}

build ()
{
  cd "$srcdir/$_pkgname"

  ./configure --prefix=/usr \
              --disable-update-desktop-database
  make
}

package()
{
  cd "$srcdir/$_pkgname"
  make DESTDIR="$pkgdir" install
}