solarc-git PKGBUILD

# Maintainer: zach <zach {at} zach-adams {dot} com>
# Contributor: Gordian Edenhofer <gordian.edenhofer[at]yahoo[dot]de

pkgname=gtk-theme-solarc-git
_pkgname=solarc-theme
_pkgauthor=apheleia
pkgver=817.3e68bc0
pkgrel=2
pkgdesc="A flat theme with transparent elements. Based on the Arc theme: https://github.com/horst3180/arc-theme"
arch=('any')
url="https://github.com/${_pkgauthor}/${_pkgname}"
license=('GPL3')
depends=('gtk3' 'gtk-engine-murrine')
makedepends=('git' 'inkscape' 'sassc')
source=(${_pkgname}::"git+https://github.com/${_pkgauthor}/${_pkgname}.git")
sha256sums=('SKIP')
conflicts=('gtk-theme-solarc')
provides=('gtk-theme-solarc')

pkgver() {
	cd "${srcdir}/${_pkgname}"
	echo "$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

build() {
	cd "${srcdir}/${_pkgname}"
	./solarize.sh
	cd arc-theme-$(grep -e ARCVERSION= ${srcdir}/${_pkgname}/solarize.sh | cut -d '=' -f 2 | cut -d \" -f 2)
	./autogen.sh --prefix=/usr
}

package() {
#	export ${grep -e ARCVERSION= ${srcdir}/${_pkgname}/solarize.sh}
	make -C "${srcdir}/${_pkgname}/arc-theme-$(grep -e ARCVERSION= ${srcdir}/${_pkgname}/solarize.sh | cut -d '=' -f 2 | cut -d \" -f 2)"  DESTDIR="${pkgdir}" install
}