ON for a time (60 sec) when button pushed - ver 2

/*
  This is a combination of the examples
  - "Button" and
  - "Blink without Delay" and
  - a state-machine


  Function of the sketch:

  Turns a light emitting diode(LED) connected to digital pin 13,
  ON for a time interval (here 60 seconds),
  when pressing a pushbutton attached to pin 2 (or pulling pin 2 HIGH).

  The time is 60 seconds from the button is pushed.
  A new ON period can be activated only after the 60 seconds have passed.

  Because we use the method from "Blink without Delay"
  other code can run at the same time without
  being interrupted/stopped by the timeout needed to
  turn the LED on and off.


  The circuit:

  - LED attached from pin 13 to ground
  - pushbutton attached to pin 2 from +5V
  - 10K resistor attached to pin 2 from ground


  - Note: on most Arduinos there is already an LED on the board
    attached to pin 13.

  - Note 2: The pushbutton is connected to be active on a HIGH of pin 2.

*/

//// Button/input constants and variables
// constants won't change.
const int buttonPin = 2;     // the number of the pushbutton pin
const int ledPin =  13;      // the number of the LED pin

// variables will change:
int buttonState = 0;         // variable for reading the pushbutton status
int state_idx = 0;           // variable indication current state of state-machine


//// Timeout constants and variables
// constants won't change.
const long interval = 60000;             // interval (in milliseconds) to keep the LED ON for (60 seconds)

// variables will change:
unsigned long previousMillis = 0;        // will store last time the LED was turned ON


void setup() {
  // initialize the LED pin as an output:
  pinMode(ledPin, OUTPUT);
  // initialize the pushbutton pin as an input:
  pinMode(buttonPin, INPUT);
}



void loop() {
  // check to see if it's time to blink the LED (or to turn the LED on or off) ;
  // that is, if the difference between the current time
  // and last time you blinked the LED (or turned the LED on) is bigger than
  // the interval at which you want to blink the LED (turn the LED off).
  unsigned long currentMillis = millis();

  // state-machine
  switch(state_idx) {

    case 0: // read button / input pin
      // read the state of the pushbutton value:
      buttonState = digitalRead(buttonPin);

      // check if the pushbutton is pressed. If it is, the buttonState is HIGH:
      if (buttonState == HIGH) {

        // remember the start time
        previousMillis = currentMillis;

        // turn LED on:
        digitalWrite(ledPin, HIGH);

        // and move into next state of state-machine -> to waite for the timeout to happen
        state_idx = 1;

      } else {
        // turn/make sure LED off:
        digitalWrite(ledPin, LOW);
      }
      break;  // case 0 is done

    case 1:  // waite for some time - until interval has passed
      if (currentMillis - previousMillis >= interval) {
        // time to turn off the LED
        digitalWrite(ledPin, LOW);

        // and move back to first state of state-machine -> read the button /input pin
        state_idx = 0;

      } else {
        // turn/make sure LED on:
        digitalWrite(ledPin, HIGH);
      }
      break; // case 1 is done
  }
}