Candlesticks

//@version=3
study("Candlesticks",overlay=true,precision=0)

///////////////////////////////
//     Green = Bullish       //
//      Red = Bearish        //
//   Orange = Continuation   //
///////////////////////////////

////CANDLESTICKS
atr=atr(100)

redBar=close<open //ALSO BLACK BAR
greenBar=close>open //ALSO WHITE BAR
body=abs(close-open)
total=high-low //ALSO KNOWN AS RANGE
bodyTopLoc=max(open,close)
bodyBottomLoc=min(open,close)
shadowTop=high-bodyTopLoc
shadowBottom=bodyBottomLoc-low
fallingbars=barssince(greenBar) //# of CONSECUTIVE RED BARS
risingbars=barssince(redBar) //# of CONSECUTIVE GREEN BARS

percent(x,y)=>
    z=x*100/y
    z
//CUSTOMIZE THESE ONLY
SizeBottom=atr/10 //Smallest size, anything less is a Doji
SSizeBottom=atr/8 //Small bottom size, used for short candles
SSizeTop=atr/3 //Small top size, used for short candles
NSizeBottom=atr/3 //Normal bottom size, used for normal candles
NSizeTop=atr*1.1 //Normal top size, used for normal candles
LSizeBottom=atr*1.1 //Long bottom size, used for LONG candles
LSizeTop=atr*6 //Long Top size, candles longer than this will be ignored
doji=(body<SizeBottom and percent(body,total)<25) //DOJI
sBody=(body>SSizeBottom and body<SSizeTop)//SMALL BODY
nBody=(body>NSizeBottom and body<NSizeTop) //NORMAL BODY
lBody=(body>LSizeBottom and body<LSizeTop) //LONG BODY
sGap(x,y)=> //SMALL GAP
    abs(x-y)<SSizeBottom and abs(x-y)>SSizeBottom/2
nGap(x,y)=> //NORMAL GAP
    abs(x-y)>SSizeBottom and abs(x-y)<LSizeBottom/2
lGap(x,y)=> //LARGE GAP
    abs(x-y)>LSizeBottom /2
VSShadow(x)=> //VERY SMALL SHADOW
    percent(x,total)<15
SShadow(x)=> //SMALL SHADOW
    percent(x,total)>15 and percent(x,total)<30
LShadow(x)=> //LONG SHADOW
    percent(x,total)>70
SUpTrend=close>ema(close,6) //SHORT UPTREND, used in retracement calculations
LUpTrend=close>ema(close,25) //LONG UPTREND
SPeak=highestbars(25) //PEAK OF SHORT UPTREND
LPeak=highestbars(50) //PEAK OF LONG UPTREND
SDownTrend=close<ema(close,6) //SHORT DOWNTREND, used in retracement calculations
LDownTrend=close<ema(close,25) //LONG DOWNTREND
SBottom=lowestbars(25) //PEAK OF SHORT DOWNTREND
LBottom=lowestbars(50) //PEAK OF LONG DOWNTREND

//END CUSTOMIZE
lowPercDiffFall=((close-low)*100)/(open-low)
lowPercDiffRise=((open-low)*100)/(close-low)
highPercDiffFall=((high-open)*100/(high-close))
highPercDiffRise=((high-close)*100/(high-open))

// Volume Bars //

//Bearish:
//DARK RED when prices goes down and VOLUME is bigger than 150% of its (default 20 day) average, this indicates that price action is supported by a strong BEARISH VOLUME.
//RED when prices goes down and VOLUME is BETWEEN 50% AND 150% of its (default 20 day) average, this indicates that volume is neither strong or weak.
//ORANGE when prices goes down and VOLUME is less than 50% of its (default 20 day) average, so the volume is weak and doesn't support the price action.

//Bullish:
//DARK GREEN when prices goes UP and VOLUME is bigger than 150% of its (default 20 day) average, this indicates that the price action is supported by a strong BULLISH VOLUME.
//GREEN when prices goes UP and VOLUME is BETWEEN 50% AND 150% of its (default 20 day) average, this indicates that volume is neither strong or weak.
//LIGHT GREEN when prices goes UP and VOLUME is less than 50% of its (default 20 day) average, so the volume is weak and doesn't support the price action.

length1=input(20, "Volume Bars Length", minval=1)
avrg=sma(volume,length1)
vold1 = volume > avrg*1.5 and close<open
vold2 = volume >= avrg*0.5 and volume<=avrg*1.5 and close<open
vold3 = volume < avrg *0.5 and close<open
volu1 = volume > avrg*1.5 and close>open
volu2 = volume >= avrg*0.5 and volume<=avrg*1.5 and close>open
volu3 = volume< avrg*0.5 and close>open
cold1=#800000
cold2=#FF0000
cold3=orange
colu1=#006400
colu2=lime
colu3=#7FFFD4
color = vold1 ? cold1 : vold2 ? cold2 : vold3 ? cold3 : volu1 ? colu1 : volu2 ? colu2 : volu3 ? colu3 : na
barcolor(color)

//BULLISH PATTERNS

//DRAGONFLY DOJI: Theoretical performance: bullish reversal during a decline, otherwise indecision - Tested performance: Reversal 50% of the time
DFly=(doji and LShadow(shadowBottom) and VSShadow(shadowTop) and total>NSizeBottom and total<LSizeTop and ((SDownTrend)or(LDownTrend)))
plotchar(DFly and not DFly[1],  title= "Dragonfly Doji", location=location.belowbar, color=green, char='', text=" \n \nDragonfly\nDoji")

//HAMMER: Theoretical performance: Bullish reversal - Tested performance: Bullish reversal 60% of the time
Hammer=(sBody and LShadow(shadowBottom) and VSShadow(shadowTop) and total>LSizeBottom and total<LSizeBottom*2 and ((LUpTrend and SDownTrend)or(LDownTrend)))
plotchar(Hammer and not Hammer[1], title= "Hammer", location=location.belowbar, color=green, char='', text=" \n \nHammer")

//TAKURI LINE: Theoretical performance: Bullish reversal - Tested performance: Bullish reversal 66% of the time
Takuri=(sBody and LShadow(shadowBottom) and VSShadow(shadowTop) and total>LSizeBottom*2 and ((LUpTrend and SDownTrend)or(LDownTrend)))
plotchar(Takuri and not Takuri[1], title= "Takuri", location=location.belowbar, color=green, char='', text=" \n \nTakuri\nLine")

//BULLISH BELT HOLD: Theoretical performance: Bullish reversal - Tested performance: Bullish reversal 71% of the time
BBelt=((nBody or lBody) and open<=low[1] and low==open and (VSShadow(shadowTop) or SShadow(shadowTop)) and ((LUpTrend and SDownTrend))) //or(LDownTrend)
plotchar(BBelt and not Takuri[1], title= "Bullish Belt Hold", location=location.belowbar, color=green, char='', text=" \n \nBull\nBelt\nHold")

//BULLISH ENGULFING: Theoretical performance: Bullish reversal - Tested performance: Bullish reversal 63% of the time
BullEngulf=((sBody[1] or nBody[1]) and redBar[1] and close>open[1] and open<close[1] and not(VSShadow(shadowTop) or VSShadow(shadowBottom)) and greenBar and ((LUpTrend and SDownTrend))) //or(LDownTrend)
plotchar(BullEngulf, title= "Bullish Engulfing", location=location.belowbar, color=green, char='', text=" \n \nBull\nEngulf")

//HARAMI CROSS BULLISH, like 56%, very bad indicator, best used in retracement or continuation of uptrend.
HCBull=(doji and redBar[1] and high<open[1] and low>close[1] and SBottom[1]==0 and LUpTrend and (sGap(low,close[1]) or nGap(low,close[1])))
plotchar(HCBull,  title= "Bullish Harami Cross", location=location.belowbar, color=green, char='', text=" \n \nHarami\nCross")

//HARAMI BULLISH, like 51%, very bad indicator, best used in retracement.
HBull=(not doji and redBar[1] and greenBar and high<open[1] and low>close[1] and SBottom[1]==0 and ((LUpTrend and SDownTrend)) and not(abs(high-high[1])<SSizeBottom and abs(low-low[1])<SSizeBottom) and not(VSShadow(shadowTop) or VSShadow(shadowBottom)) and (sGap(low,close[1]) or nGap(low,close[1])))
plotchar(HBull,  title= "Bullish Harami", location=location.belowbar, color=green, char='', text=" \n \nHarami\nBull")

//INVERTED HAMMER BULLISH, like 66% CONTINUATION, meaning it's best used in the primary downtrend to SELL, this is the BULLISH version, used in retracements in an uptrend, be careful with this one.
IHammer=(sBody and LShadow(shadowTop) and VSShadow(shadowBottom) and total>LSizeBottom and total<LSizeBottom*2 and ((LUpTrend and SDownTrend)))
plotchar(IHammer, title= "Inverted Hammer", location=location.belowbar, color=green, char='', text=" \n \nInverted\nHammer")

//PIERCING LINE, about 64%, long term overall pretty reliable, best used in retracements.
PLine=((nBody[1] or lBody[1]) and (nBody or lBody) and redBar[1] and greenBar and close>=((body[1]*50/100)+bodyBottomLoc[1]) and close<open[1] and nGap(open,close[1]) and nGap(open,close[2]) and ((LUpTrend and SDownTrend)))
plotchar(PLine, title= "Piercing Line", location=location.belowbar, color=green, char='', text=" \n \nPiercing\nLine")

//BULLISH DOJI STAR, about 70% CONTINUATION, meaning it's best used in the primary downtrend to SELL, this is the BULLISH version, used in retracements in an uptrend, be careful with this one.
BDojiStar=(doji and redBar[1] and open<close[1] and nGap(open,close[1]) and ((LUpTrend and SDownTrend)))
plotchar(BDojiStar and not DFly, title= "Bullish Doji Star", location=location.belowbar, color=green, char='', text=" \n \nBullish\nDoji\nStar")

//BULLISH MEETING LINES, about 56%, long term overall pretty reliable, best used in retracements, code uses the extra green bar to rise frequency to 80%.
BMeetLine=((nBody[2] or lBody[2]) and (nBody[1] or lBody[1]) and redBar[2] and greenBar[1] and greenBar and abs(close[2]-close[1])<SizeBottom and ((LUpTrend and SDownTrend)) and VSShadow(shadowTop[2]) and VSShadow(shadowBottom[1]) and close>open[1])
plotchar(BMeetLine, title= "Bullish Meeting Line", location=location.belowbar, color=green, char='', text=" \n \nBull\nMeeting\nLine", offset=-1)

//BULLISH HOMING PIGEON, about 57% CONTINUATION, meaning it's best used in the primary downtrend to SELL, this is the BULLISH version, used in retracements in an uptrend, be careful with this one.
HPigeon=(not doji and redBar[1] and redBar and high<open[1] and low>close[1] and ((LUpTrend and SDownTrend)) and not(abs(high-high[1])<SSizeBottom and abs(low-low[1])<SSizeBottom) and not(VSShadow(shadowTop) or VSShadow(shadowBottom)) and (sGap(low,close[1]) or nGap(low,close[1])))
plotchar(HPigeon,  title= "Bullish Homing Pigeon", location=location.belowbar, color=green, char='', text=" \n \nBull\nHoming\nPigeon")

//BULLISH MATCHING LOW, about 61% CONTINUATION, meaning it's best used in the primary downtrend to SELL, this is the BULLISH version, used in retracements in an uptrend with the added security of an extra green candle above close, be careful with this one.
BMatchLow=((nBody[2] or sBody[2]) and (nBody[1] or sBody[1]) and redBar[2] and redBar[1] and greenBar and abs(close[2]-close[1])<SizeBottom and ((LUpTrend and SDownTrend)) and VSShadow(shadowTop[1]) and VSShadow(shadowTop[2]) and close>open[1])
plotchar(BMatchLow, title= "Bullish Matching Low", location=location.belowbar, color=green, char='', text=" \n \nBull\nMatching\nLow", offset=-1)

//KICKER PATTERN, Theoretical performance: Bullish reversal - Tested performance: Bullish reversal 53% of the time.
Kicker=(high[1]<open and lGap(high[1],open) and greenBar and lBody and (SDownTrend or LDownTrend) and volume>=sma(volume,50))
plotchar(Kicker,  title= "Kicker Pattern", location=location.belowbar, color=green, char='', text=" \n \nKicker")

//BULLISH ABANDONED BABY about 70%, very infrequent though.
ABaby=((doji[1] or sBody[1]) and SDownTrend[1] and redBar[2] and (nBody[2] or lBody[2]) and greenBar and (nBody or lBody)  and high[1]<=low[2] and low>=high[1] and close>=((body[2]*40/100)+bodyBottomLoc[2]) and (sGap(low[2],high[1]) or nGap(low[2],high[1]) or lGap(low[2],high[1])) and (sGap(low,high[1]) or nGap(low,high[1]) or lGap(low,high[1])))
plotchar(ABaby,  title= "Bullish Abondoned Baby", location=location.belowbar, color=green, char='', text=" \n \nBull Abandoned\nBaby", offset=-1)

//MORNING STAR 76 or 78%, very good rates, even in bearish markets, always wait for confirmation
MStar=((doji[1] or sBody[1]) and SDownTrend[1] and redBar[2] and (nBody[2] or lBody[2]) and greenBar and (nBody or lBody)  and open[1]<=close[2] and close[1]<=close[2] and open>=close[1] and close>=((body[2]*40/100)+bodyBottomLoc[2]))
plotchar(MStar and not ABaby and not Takuri[1] and not DFly[1] and not Hammer[1],  title= "Morning Star", location=location.belowbar, color=green, char='', text=" \n \nMorning\nStar", offset=-1)

//BULLISH TRI STAR 60%, used in uptrend or retracements.
BullTriStar=(doji[1] and doji[2] and doji and LUpTrend[1] and open[1]<=close[2] and close[1]<=close[2] and open>=close[1])
plotchar(BullTriStar and not DFly,  title= "Bullish Tri Star", location=location.belowbar, color=green, char='', text=" \n \nBull\nTri\nStar")

//BULLISH DOWNSIDE GAP TWO RABBITS
BullDownTwoRabb=(((LUpTrend and SDownTrend)) and redBar[2] and (nBody[2] or lBody[2]) and greenBar[1] and greenBar and (nBody[1] or sBody[1])and (nBody or lBody) and (sGap(close[2],open[1]) or nGap(close[2],open[1])) and (sGap(close[1],open) or nGap(close[1],open)) and close[2]>open[1] and close[1]>open)
plotchar(BullDownTwoRabb,  title= "Bullish Downside Gap Two Rabbits", location=location.belowbar, color=green, char='', text=" \n \nBull\nDown Gap\nTwo\nRabbits")

//BULLISH UNIQUE THREE RIVER BOTTOM, about 60% CONTINUATION, meaning it's best used in the primary downtrend to SELL, this is the BULLISH version, used in retracements in an uptrend, be careful with this one.
BullUnThreeRiver=(((LUpTrend and SDownTrend)) and (nBody[2] or lBody[2]) and redBar[2] and redBar[1] and greenBar and open[1]>close[2] and close[1]<close[2] and low[1]>low[2] and (nBody[1] or sBody[1]) and (sGap(close[2],open[1]) or nGap(close[2],open[1])) and not  VSShadow(shadowBottom) and sBody and open<close[1] and (sGap(close[1],open) or nGap(close[1],open)))
plotchar(BullUnThreeRiver and not BullEngulf,  title= "Bullish Unique Three River Bottom", location=location.belowbar, color=green, char='', text=" \n \nBull\nUnique\nThree\nRiver\nBottom")

//THREE WHITE SOLDIERS, about 83% but somewhat infrequent due to being 3 normal or large green bars.
TGSol=((nBody[2] or lBody[2]) and (nBody[1] or lBody[1]) and (nBody or lBody) and greenBar[2] and greenBar[1] and greenBar and close[2]<close[1] and close[1]<close and high[2]<high[1] and high[1]<high and open[1]<=close[2] and open<=close[1] and VSShadow(shadowTop[2]) and VSShadow(shadowTop[1]) and VSShadow(shadowTop))
plotchar(TGSol and not TGSol[1], title= "Three White Soldiers", location=location.belowbar, color=green, char='', text=" \n \nThree\nWhite\nSoldiers")

//BULLISH DESCENT BLOCK, supposedly 62%,
BullDescBlock=((nBody[2] or lBody[2]) and (nBody[1] or lBody[1]) and (nBody or lBody) and redBar[2] and redBar[1] and redBar and close[2]>close[1] and close[1]>close and open[1]>=close[2] and open>=close[1] and (not VSShadow(shadowBottom[1]) or SShadow(shadowBottom[1])) and (not VSShadow(shadowBottom[1]) or SShadow(shadowBottom[1])) and body<body[1])
plotchar(BullDescBlock and not BullDescBlock[1], title= "Bullish Descent Block", location=location.belowbar, color=green, char='', text=" \n \nBull\nDescent\nBlock")

//BULLISH DELIBERATION BLOCK, this one is the counterpart to deliberation which has like 74% to actually continue... be EXTREMELY CAREFUL WITH THIS ONE.
BullDeliBlock=(((LUpTrend and SDownTrend)) and (nBody[2] or lBody[2]) and (nBody[1] or lBody[1]) and (sBody or doji) and redBar[2] and redBar[1] and redBar and close[2]>close[1] and close[1]>close and open[1]>=close[2] and (sGap(open,close[1]) or nGap(open,close[1])) and open<close)
plotchar(BullDeliBlock, title= "Bullish Deliberation Block", location=location.belowbar, color=green, char='', text=" \n \nBull\nDeliberation\nBlock")

//DELIBERATION BLOCK, this one is the counterpart to deliberation which has like 74% to actually continue falling, that's why it's here.
BullDeliBlock2=(not LUpTrend and (nBody[2] or lBody[2]) and (nBody[1] or lBody[1]) and (sBody or doji) and redBar[2] and redBar[1] and redBar and close[2]>close[1] and close[1]>close and open[1]>=close[2] and (sGap(open,close[1]) or nGap(open,close[1])) and open<close)
plotchar(BullDeliBlock2, title= "Deliberation Block", location=location.belowbar, color=green, char='', text=" \n \nDeliberation\nBlock")

//BULLISH DELIBERATION: Theoretical performance: Bearish reversal - Tested performance: Bullish continuation 77% of the time
Deliberation=(not LDownTrend and (nBody[2] or lBody[2]) and (nBody[1] or lBody[1]) and (sBody or doji) and greenBar[2] and greenBar[1] and greenBar and close[2]<close[1] and close[1]<close and open[1]<=close[2] and (sGap(open,close[1]) or nGap(open,close[1])) and open>close)
plotchar(Deliberation, title= "Bullish Deliberation", location=location.belowbar, color=green, char='', text=" \n \nBull\nDeliberation")

//DELIBERATION, about 74% CONTINUATION, meaning it's best used in the primary uptrend to BUY, despite being called a bearish indicator.
Deliberation2=(((LDownTrend and SUpTrend)) and (nBody[2] or lBody[2]) and (nBody[1] or lBody[1]) and (sBody or doji) and greenBar[2] and greenBar[1] and greenBar and close[2]<close[1] and close[1]<close and open[1]<=close[2] and (sGap(open,close[1]) or nGap(open,close[1])) and open>close)
plotchar(Deliberation2, title= "Deliberation", location=location.belowbar, color=green, char='', text=" \n \nDeliberation")

//BULLISH TWO RABBITS, counterpart to two crows, 54%, almost random
TwoRabbits=(LUpTrend and (nBody[2] or lBody[2]) and redBar[2] and open[1]<close[2] and greenBar[1] and greenBar and (nBody[1] or sBody[1]) and (nBody or lBody) and (sGap(open[1],close[2]) or nGap(open[1],close[2]) or lGap(open[1],close[2])) and open<=close[1] and close>=((body[2]*15/100)+bodyBottomLoc[2]))
plotchar(TwoRabbits and not BullDownTwoRabb, title= "Two Rabbits", location=location.belowbar, color=green, char='', text=" \n \nTwo\nRabbits")

//CANDLESTICK SANDWICH
CSandwich=(((nBody[2] and nBody[1] and nBody) or ((lBody[2] and lBody[1] and lBody))) and redBar[2] and greenBar[1] and redBar and abs(close-close[2])<atr/6 and abs(open-open[2])<atr/6)
plotchar(CSandwich, title= "Candlestick Sandwich", location=location.belowbar, color=green, char='', text=" \n \nCandleStick\nSandwich")

//THREE LINE STRIKE
TLS=(close[1]<close[2] and close[2]<close[3] and open[3]>close[3] and close>high[3])
plotchar(TLS,  title= "Three Line Strike", location=location.belowbar, color=green, char='', text=" \n \nThree\nLine\nStrike")

//BULLISH HOOK REVERSAL
BullHR=(greenBar and redBar[1] and open-low[1]<atr/6 and low> low[1] and high<high[1] and high[1]-high<atr/4 and volume>=sma(volume,50)/2 and SBottom[1]==0 and abs(close[1]-open[1]) > atr/3 and open[1]-close<atr/6 and open-close[1]<atr/6)
plotchar(BullHR,  title= "Bullish Hook Reversal", location=location.belowbar, color=green, char='', text=" \n \nBull\nHook\nReversal")

//BULLISH BULL SAN KU PATTERN
SanKuBull=(redBar and close[1]<open[1] and close[2]<open[2] and close[2]-open[1]>atr/6 and close[1]-open>atr/6 and abs(close[2]-open[2]) > atr/7 and abs(close[1]-open[1]) > atr/7 and body > atr/7)
plotchar(SanKuBull,  title= "Bullish San Ku Pattern", location=location.belowbar, color=green, char='', text=" \n \nSan Ku\nBull")

//BULLISH ISLAND REVERSAL
BullIR=(low[2]>open[1] and low[2]-open[1]> atr[1]/3 and abs(close[1]-open[1])<atr[1]/8 and close[1]<low and high-close[1]>atr/3 and volume[1]>=sma(volume,50)/2)
plotchar(BullIR,  title= "Bullish Island Reversal", location=location.belowbar, color=green, char='', text=" \n \nBull\nIsland\nReversal")


//BEARISH PATTERNS


//TWO BLACK GAPPING MODIFIED:
TwoBGap=(close<close[1] and close[1]<close[2] and close[2]<close[3] and LPeak[3]==0 and high[2]<high[3] and open[2]-close[1]>(close[3]-open[3])*3 and open[3]<close[3] and close[3]-open[3]>atr[3])
plotchar(TwoBGap,  title= "Two Black Gapping", location=location.abovebar, color=red, char='', text=" \n \nTwo\nBlack\nGapping")

//THREE BLACK CROWS:
TBC=(LPeak[2]>=-1 and close<close[1] and close[1] < close[2] and low< low[1] and low[1]< low[2] and lowPercDiffFall<45 and lowPercDiffFall[1]<45 and lowPercDiffFall[2]<45)
plotchar(TBC,  title= "Three Black Crows", location=location.abovebar, color=red, char='', text=" \n \nThree\nBlack\nCrows")

//EVENING STAR:
EStar=((doji[1] or sBody[1]) and LPeak[1]==0 and (close[2]-open[2])>atr[2]*1.25 and ((redBar and open-close < atr/2) or highPercDiffFall>30 or highPercDiffRise>50)  and close<(close[2]-((close[2]-open[2])*34/100)) and redBar and high[1]-low[1]<atr/1.5)
plotchar(EStar,  title= "Evening Star", location=location.abovebar, color=red, char='', text=" \n \nEvening\nStar")

//BEARISH ISLAND REVERSAL:
BearIR=(high[2]<open[1] and open[1]-high[2]> atr[1]/3 and abs(close[1]-open[1])<atr[1]/8 and close[1]>high and close[1]-high>atr/3 and volume[1]>=sma(volume,50)/2)
plotchar(BearIR,  title= "Bearish Island Reversal", location=location.abovebar, color=red, char='', text=" \n \nBear\nIsland\nReversal")

//BEARISH HOOK REVERSAL:
BearHR=(redBar and greenBar[1] and high[1]-open<atr/6 and low> low[1] and high<high[1] and low-low[1]<atr/4 and volume>=sma(volume,50)/2 and SPeak[1]==0 and abs(close[1]-open[1]) > atr/3 and close-open[1]<atr/6 and close[1]-open<atr/6)
plotchar(BearHR,  title= "Bearish Hook Reversal", location=location.abovebar, color=red, char='', text=" \n \nBear\nHook\nReversal")

//BEAR SAN KU PATTERN:
SanKuBear=(greenBar and close[1]>open[1] and close[2]>open[2] and open[1]-close[2]>atr/6 and open-close[1]>atr/6 and abs(close[2]-open[2]) > atr/7 and abs(close[1]-open[1]) > atr/7 and body > atr/7)
plotchar(SanKuBear,  title= "Bearish San Ku Patterm", location=location.abovebar, color=red, char='', text=" \n \nSan Ku\nBear")

//HARAMI CROSS BEARISH:
HCBear=(doji and high<close[1] and low>open[1] and close[1]>open[1] and SPeak[1]==0)
plotchar(HCBear,  title= "Bearish Harami Cross", location=location.abovebar, color=red, char='', text=" \n \nHarami\nCross")

//SHOOTING STAR:
SStar=(sBody and shadowBottom/(high-low)<0.15 and shadowTop/(high-low)>0.7 and SPeak[1]==0 and redBar and high-low>atr*1.25)
plotchar(SStar, title= "Shooting Star", location=location.abovebar, color=red, char='', text=" \n \nShooting\nStar")

//HANGING MAN:
Hanging=(sBody and shadowBottom/(high-low)>0.7 and shadowTop/(high-low)<0.15 and SPeak[1]==0 and open>=close[1])
plotchar(Hanging, title= "Hanging Man", location=location.abovebar, color=red,char='', text=" \n \nHanging\nMan")

//UPSIDE GAP TWO CROWS:
UpsideGapTwoCrows=(greenBar[2] and redBar[1] and redBar and body[2]>atr[2] and open[1]>=close[2] and sBody[1] and open>=open[1] and close<close[1] and close>close[2] and body>atr/1.5)
plotchar(UpsideGapTwoCrows, title= "Upside Gap Two Crows",location=location.abovebar, color=red, char='', text=" \n \nUpside\nGap\nTwo\nCrows")

//DARK CLOUD COVER: Theoretical performance: Bearish reversal - Tested performance: Bearish reversal 60% of the time
DarkCC=(body[1]>atr[1]/2 and body>atr/2 and open>=high[1] and close<(open[1]+close[1])/2 and close > open[1] and redBar and SUpTrend)
plotchar(DarkCC, title= "Dark Cloud Cover",location=location.abovebar, color=red, char='', text=" \n \nDark\nCloud\nCover")

//BEARISH ENGULFING:
BearEngulf=((sBody[1] or doji[1]) and LPeak[1]==0 and body>atr*1.15 and redBar and close<low[1] and shadowBottom/(high-low)<0.1)
plotchar(BearEngulf, title= "Bearish Engulfing",location=location.abovebar, color=red, char='', text=" \n \nBear\nEngulf")

//GRAVESTONE DOJI
Gravestone=(doji and (max(open,close)-low)/(high-low)<0.25 and high-low>(atr/2) and SUpTrend)
plotchar(Gravestone,  title= "Gravestone Doji", location=location.abovebar, color=red, char='', text=" \n \nGravestone\nDoji")

//BEARISH ABANDONED BABY
BearABaby=((doji[1] or sBody[1]) and SUpTrend[1] and greenBar[2] and (nBody[2] or lBody[2]) and redBar and (nBody or lBody)  and low[1]>=high[2] and high<=low[1] and close<=((body[2]*40/100)+bodyBottomLoc[2]) and (sGap(high[2],low[1]) or nGap(high[2],low[1]) or lGap(high[2],low[1])) and (sGap(high,low[1]) or nGap(high,low[1]) or lGap(high,low[1])))
plotchar(BearABaby,  title= "Bearish Abondoned Baby", location=location.abovebar, color=red, char='', text=" \n \nBear\nAbandoned\nBaby", offset=-1)


//CONTINUATION PATTERNS


//INVERTED HAMMER, like 66% CONTINUATION, meaning it's best used in the primary downtrend to SELL, despite being called a bullish indicator
IHammer2=(sBody and LShadow(shadowTop) and VSShadow(shadowBottom) and total>LSizeBottom and total<LSizeBottom*2 and LDownTrend)
plotchar(IHammer2 and not MStar, title= "Continuation Inverted Hammer", location=location.abovebar, color=orange, char='', text=" \n \nInverted\nHammer")

//BULLISH MATCHING LOW: 61% CONTINUATION meaning it's best used in the primary downtrend to SELL, despite being called a bullish indicator.
BMatchLow2=((nBody[1] or sBody[1]) and (nBody or sBody) and redBar[1] and redBar and abs(close[1]-close)<SizeBottom and LDownTrend and VSShadow(shadowTop[1]) and VSShadow(shadowTop))
plotchar(BMatchLow2, title= "Continuation Bull Matching Low", location=location.abovebar, color=orange, char='', text=" \n \nBull\nMatching\nLow")

//BULLISH HOMING PIGEON: 57% CONTINUATION, meaning it's best used in the primary downtrend to SELL, despite being called a bullish indicator.
HPigeon2=(not doji and redBar[1] and redBar and high<open[1] and low>close[1] and LDownTrend and not(abs(high-high[1])<SSizeBottom and abs(low-low[1])<SSizeBottom) and not(VSShadow(shadowTop) or VSShadow(shadowBottom)) and (sGap(low,close[1]) or nGap(low,close[1])))
plotchar(HPigeon2,  title= "Continuation Bull Homing Pigeon", location=location.belowbar, color=orange, char='', text=" \n \nBull\nHoming\nPigeon")

//BULLISH DOJI STAR: about 70% CONTINUATION, meaning it's best used in the primary downtrend to SELL, despite being called a bullish indicator.
BDojiStar2=(doji and redBar[1] and open<close[1] and nGap(open,close[1]) and LDownTrend)
plotchar(BDojiStar2, title= "Continuation Bull Doji Star", location=location.abovebar, color=orange, char='', text=" \n \nBullish\nDoji\nStar")

//BULLISH UNIQUE THREE RIVER BOTTOM, about 60% CONTINUATION, meaning it's best used in the primary downtrend to SELL, despite being called a bullish indicator.
BullUnThreeRiver2=(LDownTrend and (nBody[2] or lBody[2]) and redBar[2] and redBar[1] and greenBar and open[1]>close[2] and close[1]<close[2] and low[1]>low[2] and (nBody[1] or sBody[1]) and (sGap(close[2],open[1]) or nGap(close[2],open[1])) and not  VSShadow(shadowBottom) and sBody and open<close[1] and (sGap(close[1],open) or nGap(close[1],open)))
plotchar(BullUnThreeRiver2,  title= "Continuation Bull Unique Three River Bottom", location=location.belowbar, color=orange, char='', text=" \n \nBull\nUnique\nThree\nRiver\nBottom")

// End //