API tools faq
paste
Advertisement
Guest User

srestore v2.795

a guest
Jul 11th, 2018
439
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Avisynth 21.05 KB | None | 0 0
raw download clone embed print report diff
  1. ###### srestore v2.795 ######
  2. # ==================================================================================================================================
  3. # Change List
  4. #
  5. # 07/11/2018 AmjadSONY
  6. # - Update v2.794 -> v2.795
  7. #  update to masktools 2.2.17, clean up
  8. #
  9. # 06/12/2018
  10. # - Update v2.793 -> v2.794
  11. #  fix another bug in 12bit (StainlessS)
  12. #
  13. # 06/10/2018
  14. # - Update v2.792 -> v2.793
  15. #  fix bug in 12bit (StainlessS)
  16. #
  17. # 03/14/2018 AmjadSONY
  18. # - Update v2.791 -> v2.792
  19. #  native ReplaceStr using in avs+
  20. #
  21. # 11/22/2017 AmjadSONY
  22. # - Update v2.78 -> v2.791
  23. #  some edit in speed parameter (in avs26 or avs+ will get different result now)
  24. #
  25. # 06/15/2017 AmjadSONY
  26. # - Update v2.77 -> v2.78
  27. #  some fix
  28. #
  29. # 05/25/2017 AmjadSONY
  30. # - Update v2.76 -> v2.77
  31. #  fix high bit depth
  32. #
  33. # 03/31/2017 AmjadSONY
  34. # - Update v2.75 -> v2.76
  35. #  update to masktools 2.2.5
  36. #
  37. # 03/09/2017 AmjadSONY
  38. # - Update v2.7i -> v2.75
  39. #  now work with all high bit depth in avs+
  40. #
  41. # 02/09/2017 AmjadSONY
  42. # - Update v2.7h -> v2.7i
  43. #  clean up and add YUY2 and other format
  44. #
  45. # 03/23/2014 AmjadSONY
  46. # - Update v2.7g -> v2.7h
  47. #  update to use new Average by tp7
  48. #
  49. # 11/12/2013 martin53
  50. # - Update v2.7f -> v2.7g
  51. #  Refactored to use a single line ScriptClip() call like v2.7e - Neccessary to save AviSynth string heap space when RTE is called
  52. #
  53. # 10/28/2013 martin53
  54. # - Update v2.7e -> v2.7f
  55. # Callable more than once from the same script with help of unique global variables per instance.
  56. # Moderate reformatting to re-establish readability with the new variable names.
  57. # Needs GRunT plugin
  58. #
  59. # ==================================================================================================================================
  60.  
  61. function Srestore(clip sourceo, float "frate", "omode", float "speed", float "blocks", int "mode", float "thresh", int "cache", clip "dclip")
  62. {
  63. avs26=!(VersionNumber() < 2.6)
  64. nonyuy2=avs26 && sourceo.isyuy2()
  65. source=nonyuy2 ? sourceo.nonyuy2clipin(true) : sourceo
  66. ssispmt   = Findstr(VersionString(), "AviSynth+") != 0 && Findstr(VersionString(), "r1576") == 0
  67. sislumaonly = ssispmt ? sourceo.isy() : !avs26 ? false : sourceo.isy8()
  68. sis444 = ssispmt ? sourceo.is444() : !avs26 ? false : sourceo.isyv24()
  69. ###### parameters & other necessary vars ######
  70.     dm      = default(mode, 2)
  71.      sisproslumonl = (!(dm<0) && avs26)
  72.     srad  = sisproslumonl || sis444 || sislumaonly ? isfloat(speed) && abs(speed)>=1 ? sqrt(abs(speed)) : 9 : isfloat(speed) && abs(speed)>=1 ? sqrt(abs(speed))*4 : 12
  73.     cache = default(cache, -1)
  74.     irate = framerate(source)
  75.     bsize = isfloat(speed) && speed>0 ? 16 : 32
  76.  
  77.     om      = default(omode, 6)
  78.     bom     = isstring(om)
  79.     thr     = abs(default(thresh, 16))+0.01
  80.     frfac   = bom || abs(om-3)<2.5 ? 1 : isfloat(frate) ? frate*5<irate || frate>irate ? 1 :
  81.             \ abs(frate)/irate : round(irate*10010)%30000==0 ? 1001./2400. : 480./1001.
  82.  
  83.     numr    = abs(frfac*1001-round(frfac*1001))<0.01 ? round(frfac*1001) :
  84.             \ abs(1001/frfac-round(1001/frfac))<0.01 ? 1001 : round(frfac*9000)
  85.     numr    = isfloat(frate) && abs(irate*numr/float(round(numr/frfac))-frate) >
  86.             \ abs(irate*round(frate*100)/float(round(irate*100))-frate) ? round(frate*100) : numr
  87.     denm    = round(numr/frfac)
  88.  
  89.     ###### source preparation & lut ######
  90.     out = source
  91.     mec = abs(dm)<2 || bom ? nop() : mergeluma(mergechroma(out, out.trim(1, 0), 0.5), out.trim(1, 0), 0.5)
  92.     det = default(dclip, source).killaudio()
  93.     sis420  = ssispmt ? det.is420() : det.isyv12()
  94.     det = dm<0 || sislumaonly ? det : ssispmt ? det.converttoy() : avs26 ? det.converttoy8() : det.converttoyv12()
  95.     det = det.pointresize(sisproslumonl || sis444 || sislumaonly ? int(det.width/(sis420 ? (srad*1.77) : srad)) : srad==4 ? det.width : int(det.width/2/srad+4)*4, sisproslumonl || sis444 || sislumaonly ? int(det.width/(sis420 ? (srad*1.77) : srad)) : srad==4 ? det.height : int(det.height/2/srad+4)*4).trim(2, 0)
  96.     det = !sislumaonly && dm<0 && sis420 ? stackvertical(stackhorizontal(ssispmt ? det.ExtractU() : avs26 ? det.utoy8() : det.utoy(), ssispmt ? det.ExtractV() : avs26 ? det.vtoy8() : det.vtoy()), ssispmt ? det.converttoy() : avs26 ? det.converttoy8() : det) : det
  97.     det = !sislumaonly && dm<0 && !sis420 ? stackhorizontal(stackhorizontal(ssispmt ? det.ExtractU() : avs26 ? det.utoy8() : det.utoy(), ssispmt ? det.ExtractV() : avs26 ? det.vtoy8() : det.vtoy()), ssispmt ? det.converttoy() : avs26 ? det.converttoy8() : det) : det
  98.     det = bom ? !avs26 ? det.mt_lut("x 0.5 * 64 +", y=3, u=1, v=1) : det.mt_lut("x 0.5 * 64 scalef +", use_expr=2, y=3, u=1, v=1) : det
  99.  
  100.         code0   = !avs26 ? "x 128 - y 128 - * 0 > x 128 - abs y 128 - abs < x 128 - 128 x - * y 128 - 128 y - * ? x y + 256 - x y + 256 - * ? 0.25 * 128 +"
  101.               \  : "x range_half - y range_half - * 0 > x range_half - abs y range_half - abs < x range_half - range_half x - * y range_half - range_half y - * ? x y + range_size - dup * ? 0.25 * range_half +"
  102.         code1   = !avs26 ? "x y - 2 ^ 3 * x y + 256 - 2 ^ - 128 +" : "x y - dup * 3 * x y + range_size - 2 ^ - range_half +"
  103.         diff    = mt_makediff(det, det.trim(1, 0), y=3, u=1, v=1)
  104.     bclp    = !bom ? !avs26 ? mt_lutxy(diff, diff.trim(1, 0), expr=code0, y=3, u=1, v=1).bilinearresize(bsize, bsize) : mt_lutxy(diff, diff.trim(1, 0), expr=code0, use_expr=2, y=3, u=1, v=1).bilinearresize(bsize, bsize) :
  105.                \ !avs26 ? mt_lutxy(diff.trim(1, 0), mt_adddiff(diff, diff.trim(2, 0), y=3, u=1, v=1), expr=code1, y=3, u=1, v=1).bilinearresize(bsize, bsize) : mt_lutxy(diff.trim(1, 0), mt_adddiff(diff, diff.trim(2, 0), y=3, u=1, v=1), expr=code1, use_expr=2, y=3, u=1, v=1).bilinearresize(bsize, bsize)
  106.     dclp    = !avs26 ? diff.trim(1, 0).mt_lut("x 128 - abs 1.1 ^ 1 -", y=3, u=1, v=1).bilinearresize(bsize, bsize)
  107.           \  : diff.trim(1, 0).mt_lut("x range_half - abs 1.1 ^ 1 scalef -", use_expr=2, y=3, u=1, v=1).bilinearresize(bsize, bsize)
  108.  
  109.     ###### POSTPROCESSING ######
  110.     unblend1    = bom ? average(out, 2.0, out.loop(2, 0, 0), -1.0) : nop()
  111.     unblend2    = bom ? average(out.trim(2, 0), -1.0, out.trim(1, 0), 2.0) : nop()
  112.  
  113.     qmask1  = bom ? mt_makediff(unblend1.removegrain(mode=19, modeU=-1, modeV=-1), unblend1, y=3, u=1, v=1) : nop()
  114.     qmask2  = bom ? mt_makediff(unblend2.removegrain(mode=19, modeU=-1, modeV=-1), unblend2, y=3, u=1, v=1) : nop()
  115.     diffm   = bom ? mt_makediff(out.loop(2, 0, 0), out, y=3, u=1, v=1).mt_expand() : nop() #A.SONY note: there were some buggy lut .mt_lut("x y - abs", y=3, u=1, v=1)
  116.     # 10/28/2013 note: next UPN expression is buggy, but correct expression not known
  117.     bmask   = bom ? !avs26 ? mt_lutxy(qmask1, qmask2, expr="x y - == 128 x 128 - 2 ^ x 128 - 2 ^ y 128 - 2 ^ + / 255 *", y=3, u=1, v=1)
  118.             \      : mt_lutxy(qmask1, qmask2, expr="x range_half - dup * dup y range_half - dup * + / range_max *", use_expr=2, scale_inputs="floatf", y=3, u=1, v=1) : nop()
  119.     dmask   = bom ? !avs26 ? mt_lutxy(diffm, diffm.trim(2, 0), expr="x 2 * y < x 4 < & 0 y 2 * x < y 4 < & 255 x x y + / 200 * 28 + ? ?", y=3, u=1, v=1)
  120.             \      : mt_lutxy(diffm, diffm.trim(2, 0), expr="x 2 * y < x 4 scalef < & 0 y 2 * x < y 4 scalef < & range_max x x y + / 200 scalef * 28 scalef + ? ?", use_expr=2, y=3, u=1, v=1) : nop()
  121.     pmask   = bom ? !avs26 ? mt_lutxy(dmask, bmask, expr="y 0 > y 255 < & x 0 == x 255 == | & x y ?", y=3, u=1, v=1)
  122.             \      : mt_lutxy(dmask, bmask, expr="y 0 > y range_max < & x 0 == x range_max == | & x y ?", use_expr=2, y=3, u=1, v=1) : nop()
  123.  
  124.     pp0 = bom ? average(out.trim(2, 0), -0.5, out.trim(1, 0), 1.0, out, 1.0, out.loop(2, 0, 0), -0.5) : nop()
  125.     pp1 = bom ? mt_merge(unblend1, unblend2, dmask.removegrain(mode=12, modeU=-1, modeV=-1).greyscale(), y=3, u=sislumaonly ? 1 : 3, v=sislumaonly ? 1 : 3) : nop()
  126.     pp2 = bom ? mt_merge(unblend1, unblend2, bmask.removegrain(mode=12, modeU=-1, modeV=-1), luma=!sislumaonly) : nop()
  127.     pp3 = bom ? mt_merge(unblend1, unblend2, pmask.removegrain(mode=12, modeU=-1, modeV=-1), luma=!sislumaonly).removegrain(mode=0, modeU=12, modeV=12) : nop()
  128.  
  129.     fin  = bom ? eval(om) : nop()
  130.  
  131.     #######################################
  132.     # Unique Identifier Definition
  133.     #######################################
  134.     Try { global Srestore_InstanceNumber = Srestore_InstanceNumber+1 } catch(err) { global Srestore_InstanceNumber = 1 }
  135.  
  136.     # Runtime Environment Preparation & Call
  137.     Eval(StrReplace(""" #"
  138.         #######################################
  139.         # 1) Unique Global Variables Initialization
  140.         #######################################
  141.         global  Srestore_lfr%%%     = -100
  142.         global  Srestore_offs%%%    = 0
  143.         global  Srestore_ldet%%%    = -100
  144.         global  Srestore_lpos%%%    = 0
  145.  
  146.         #######################################
  147.         # 2) Unique Runtime Call
  148.         #######################################
  149.         ###### evaluation call & output calculation ######
  150.         ARGS = "dm, om, bom, thr, frfac, numr, denm, mec, det, bclp, dclp, fin, ssispmt"
  151.         source
  152.         GScriptClip("srestore_inside_%%%(last, dm, om, bom, thr, frfac, numr, denm, mec, det, bclp, dclp, fin, ssispmt)", local=true, args=ARGS)
  153.  
  154.         ###### final decimation & caching ######
  155.         nonyuy2 ? nonyuy2clipout(true) : last
  156.         cache<0 ? last : last.RequestLinear(8, cache, 5, false, false)
  157.  
  158.         temp    = frameratenumerator(det)*float(numr)>2147483600. ? det.assumescaledfps(numr, denm) : nop()
  159.         isclip(temp) ? last.changefps(temp, linear=true) : last.changefps(frameratenumerator(source)*numr, frameratedenominator(source)*denm, linear=true)
  160.  
  161.         return last
  162.  
  163.         #######################################
  164.         # 3) Unique Runtime Function Definition
  165.         #######################################
  166.         function srestore_inside_%%%(clip source, dm, om, bom, thr, frfac, numr, denm, mec, det, bclp, dclp, fin, ssispmt) {
  167.             ssIsVF  = ssispmt ? source.IsVideoFloat() : false
  168.             shbdbpc = ssispmt ? source.BitsPerComponent() : 8
  169.             sIshbd  = shbdbpc > 8
  170.             sdoscal = !ssIsVF && sIshbd
  171.             sscalva = sdoscal ? shbdbpc == 10 ? 4 : shbdbpc == 12 ? 16 : shbdbpc == 14 ? 64 : 256 : 1
  172.                 ssIsVF ? eval("
  173.             v015625 = .0000612745098039
  174.             vp125   = .0004901960784314
  175.             vp01    = .0000392156862745
  176.             vp45    = .0017647058823529
  177.             vp55    = .002156862745098
  178.             vp51    = .002
  179.             vp35    = .0013725490196078
  180.             v0p5    = 0.0019607843137255
  181.             v1      = 0.003921568627451
  182.             v125    = 0.4901960784313725
  183.                         ") : \
  184.                             eval("
  185.             v015625 = .015625
  186.             vp125   = .125
  187.             vp01    = .01
  188.             vp45    = .45
  189.             vp55    = .55
  190.             vp51    = .51
  191.             vp35    = .35
  192.             v0p5    = 0.5
  193.             v1      = 1
  194.             v125    = sdoscal ? 125*sscalva : 125
  195.                                 ")
  196.             svhalf  = ssIsVF ? 0.5 : sdoscal ? shbdbpc == 10 ? 512 : shbdbpc == 12 ? 2048 : shbdbpc == 14 ? 8192 : 32768 : 128
  197.             thr     = ssIsVF ? thr/255 : sdoscal ? thr*sscalva : thr
  198.  
  199.             ### preparation ###
  200.             cfr = current_frame
  201.             jmp = Srestore_lfr%%%+1==cfr
  202.             cfo = (((cfr%denm)*numr*2+denm+(versionnumber()>2.575 ? numr : 0))%(2*denm))-denm
  203.             bfo = cfo>-numr && cfo<=numr
  204.  
  205.             global  Srestore_lfr%%%     = cfr
  206.             global  Srestore_offs%%%    = bfo && Srestore_offs%%%<=-4*numr
  207.                                                 \? Srestore_offs%%%+2*denm
  208.                                                 \: bfo && Srestore_offs%%%>=4*numr
  209.                                                     \? Srestore_offs%%%-2*denm
  210.                                                     \: Srestore_offs%%%
  211.  
  212.             pos = frfac==1 ? 0 : bfo ? -round((cfo+Srestore_offs%%%)/(2.*numr)) : Srestore_lpos%%%
  213.             cof = cfo+Srestore_offs%%%+2*numr*pos
  214.  
  215.             global  Srestore_ldet%%%    = cfr+pos==Srestore_ldet%%% ? -1 : cfr+pos
  216.  
  217.             ## diff value shifting ##
  218.             d_v = yplanemax(dclp)+v015625
  219.             Srestore_d43%%% = jmp ? Srestore_d32%%% : d_v
  220.             global  Srestore_d32%%% = jmp ? Srestore_d21%%% : d_v
  221.             global  Srestore_d21%%% = jmp ? Srestore_d10%%% : d_v
  222.             global  Srestore_d10%%% = jmp ? Srestore_d01%%% : d_v
  223.             global  Srestore_d01%%% = jmp ? Srestore_d12%%% : d_v
  224.             global  Srestore_d12%%% = jmp ? Srestore_d23%%% : d_v
  225.             global  Srestore_d23%%% = jmp ? Srestore_d34%%% : d_v
  226.             global  Srestore_d34%%% = d_v
  227.  
  228.             ## diff value shifting ##
  229.             m_v = isfloat(om) && abs(om)>5 ? lumadifference(det, det.trim(2, 0))+v015625 : v1
  230.             Srestore_m53%%% = jmp ? Srestore_m42%%% : m_v
  231.             global  Srestore_m42%%% = jmp ? Srestore_m31%%% : m_v
  232.             global  Srestore_m31%%% = jmp ? Srestore_m20%%% : m_v
  233.             global  Srestore_m20%%% = jmp ? Srestore_m11%%% : m_v
  234.             global  Srestore_m11%%% = jmp ? Srestore_m02%%% : m_v
  235.             global  Srestore_m02%%% = jmp ? Srestore_m13%%% : m_v
  236.             global  Srestore_m13%%% = jmp ? Srestore_m24%%% : m_v
  237.             global  Srestore_m24%%% = m_v
  238.  
  239.             ## get blend and clear values ##
  240.             b_v = svhalf-yplanemin(bclp)
  241.             b_v = b_v<v1 ? vp125 : b_v
  242.             c_v = yplanemax(bclp)-svhalf
  243.             c_v = c_v<v1 ? vp125 : c_v
  244.  
  245.             ## blend value shifting ##
  246.             Srestore_bp3%%% = jmp ? Srestore_bp2%%% : bom ? b_v-c_v : b_v
  247.             global  Srestore_bp2%%% = jmp ? Srestore_bp1%%% : Srestore_bp3%%%
  248.             global  Srestore_bp1%%% = jmp ? Srestore_bn0%%% : Srestore_bp3%%%
  249.             global  Srestore_bn0%%% = jmp ? Srestore_bn1%%% : Srestore_bp3%%%
  250.             global  Srestore_bn1%%% = jmp ? Srestore_bn2%%% : Srestore_bp3%%%
  251.             global  Srestore_bn2%%% = jmp ? Srestore_bn3%%% : Srestore_bp3%%%
  252.             global  Srestore_bn3%%% = bom ? b_v-c_v : b_v
  253.  
  254.             ## clear value shifting ##
  255.             Srestore_cp3%%% = jmp ? Srestore_cp2%%% : c_v
  256.             global  Srestore_cp2%%% = jmp ? Srestore_cp1%%% : c_v
  257.             global  Srestore_cp1%%% = jmp ? Srestore_cn0%%% : c_v
  258.             global  Srestore_cn0%%% = jmp ? Srestore_cn1%%% : c_v
  259.             global  Srestore_cn1%%% = jmp ? Srestore_cn2%%% : c_v
  260.             global  Srestore_cn2%%% = jmp ? Srestore_cn3%%% : c_v
  261.             global  Srestore_cn3%%% = c_v
  262.  
  263.             ## used detection values ##
  264.             bb  = select(pos+2, Srestore_bp3%%%, Srestore_bp2%%%, Srestore_bp1%%%, Srestore_bn0%%%, Srestore_bn1%%%)
  265.             bc  = select(pos+2, Srestore_bp2%%%, Srestore_bp1%%%, Srestore_bn0%%%, Srestore_bn1%%%, Srestore_bn2%%%)
  266.             bn  = select(pos+2, Srestore_bp1%%%, Srestore_bn0%%%, Srestore_bn1%%%, Srestore_bn2%%%, Srestore_bn3%%%)
  267.  
  268.             cb  = select(pos+2, Srestore_cp3%%%, Srestore_cp2%%%, Srestore_cp1%%%, Srestore_cn0%%%, Srestore_cn1%%%)
  269.             cc  = select(pos+2, Srestore_cp2%%%, Srestore_cp1%%%, Srestore_cn0%%%, Srestore_cn1%%%, Srestore_cn2%%%)
  270.             cn  = select(pos+2, Srestore_cp1%%%, Srestore_cn0%%%, Srestore_cn1%%%, Srestore_cn2%%%, Srestore_cn3%%%)
  271.  
  272.             dbb = select(pos+2, Srestore_d43%%%, Srestore_d32%%%, Srestore_d21%%%, Srestore_d10%%%, Srestore_d01%%%)
  273.             dbc = select(pos+2, Srestore_d32%%%, Srestore_d21%%%, Srestore_d10%%%, Srestore_d01%%%, Srestore_d12%%%)
  274.             dcn = select(pos+2, Srestore_d21%%%, Srestore_d10%%%, Srestore_d01%%%, Srestore_d12%%%, Srestore_d23%%%)
  275.             dnn = select(pos+2, Srestore_d10%%%, Srestore_d01%%%, Srestore_d12%%%, Srestore_d23%%%, Srestore_d34%%%)
  276.             dn2 = select(pos+2, Srestore_d01%%%, Srestore_d12%%%, Srestore_d23%%%, Srestore_d34%%%, Srestore_d34%%%)
  277.  
  278.             mb1 = select(pos+2, Srestore_m53%%%, Srestore_m42%%%, Srestore_m31%%%, Srestore_m20%%%, Srestore_m11%%%)
  279.             mb  = select(pos+2, Srestore_m42%%%, Srestore_m31%%%, Srestore_m20%%%, Srestore_m11%%%, Srestore_m02%%%)
  280.             mc  = select(pos+2, Srestore_m31%%%, Srestore_m20%%%, Srestore_m11%%%, Srestore_m02%%%, Srestore_m13%%%)
  281.             mn  = select(pos+2, Srestore_m20%%%, Srestore_m11%%%, Srestore_m02%%%, Srestore_m13%%%, Srestore_m24%%%)
  282.             mn1 = select(pos+2, Srestore_m11%%%, Srestore_m02%%%, Srestore_m13%%%, Srestore_m24%%%, vp01)
  283.  
  284.  
  285.             ### basic calculation ###
  286.             bbool   = .8*bc*cb>bb*cc && .8*bc*cn>bn*cc && bc*bc>cc
  287.             blend   = bbool && bc*5>cc && dbc+dcn>1.5*thr && (dbb<7*dbc || dbb<8*dcn) && (dnn<8*dcn || dnn<7*dbc) &&
  288.                     \ (mb<mb1 && mb<mc || mn<mn1 && mn<mc || (dbb+dnn)*4<dbc+dcn || (bb*cc*5<bc*cb || mb>thr) && (bn*cc*5<bc*cn || mn>thr) && bc>thr)
  289.  
  290.             clear   = dbb+dbc>thr && dcn+dnn>thr && (bc<2*bb || bc<2*bn) && (dbb+dnn)*2>dbc+dcn && (mc<.96*mb && mc<.96*mn && (bb*2>cb || bn*2>cn) &&
  291.                     \ cc>cb && cc>cn || frfac>vp45 && frfac<vp55 && .8*mc>mb1 && .8*mc>mn1 && mb>.8*mn && mn>.8*mb)
  292.  
  293.             highd   = dcn>5*dbc && dcn>5*dnn && dcn>thr && dbc<thr && dnn<thr
  294.  
  295.             lowd    = dcn*5<dbc && dcn*5<dnn && dbc>thr && dnn>thr && dcn<thr && frfac>vp35 && (frfac<vp51 || dcn*5<dbb)
  296.  
  297.             res     = (Srestore_d43%%%<thr
  298.                       \&& Srestore_d32%%%<thr
  299.                       \&& Srestore_d21%%%<thr
  300.                       \&& Srestore_d10%%%<thr
  301.                       \&& Srestore_d01%%%<thr
  302.                       \&& Srestore_d12%%%<thr
  303.                       \&& Srestore_d23%%%<thr
  304.                       \&& Srestore_d34%%%<thr)
  305.                       \|| (dbc*4<dbb && dcn*4<dbb && dnn*4<dbb && dn2*4<dbb)
  306.                       \|| (dcn*4<dbc && dnn*4<dbc && dn2*4<dbc)
  307.  
  308.  
  309.             ### offset calculation ###
  310.             odm     = blend ? denm : clear ? 0 : highd ? denm-numr : lowd ? 2*denm-numr : cof
  311.             odm     = odm+round((cof-odm)/(2.*denm))*2*denm
  312.             odr     = (blend ? denm-numr : clear ? numr : highd ? numr : frfac<v0p5 ? 2*numr : 2*(denm-numr)) * .9
  313.  
  314.             cof     = Srestore_ldet%%%<0
  315.                         \? cof
  316.                         \: cof>odm+odr
  317.                             \? cof-Srestore_offs%%%-odm-odr>denm && res
  318.                                 \? odm+2*denm-odr
  319.                                 \: odm+odr
  320.                             \: cof<odm-odr
  321.                                 \? Srestore_offs%%%>denm && res
  322.                                     \? odm-2*denm+odr
  323.                                     \: odm-odr
  324.                                 \: Srestore_offs%%%<-1.15*denm && res
  325.                                     \? cof+2*denm
  326.                                     \: Srestore_offs%%%>1.25*denm && res
  327.                                         \? cof-2*denm
  328.                                         \: cof
  329.  
  330.             global  Srestore_offs%%%    = frfac==1 ? 0 : cof-cfo-2*numr*pos
  331.             global  Srestore_lpos%%%    = pos
  332.             opos    = frfac==1 ? 0 : -round((cfo+Srestore_offs%%%+(bfo && Srestore_offs%%%<=-4*numr ? denm : 0))/(2.*numr))
  333.             pos     = opos<-2 ? -2 : opos>2 ? 2 : opos
  334.  
  335.             ### frame output calculation - resync - dup ###
  336.             dbb = select(pos+2, Srestore_d43%%%, Srestore_d32%%%, Srestore_d21%%%, Srestore_d10%%%, Srestore_d01%%%)
  337.             dbc = select(pos+2, Srestore_d32%%%, Srestore_d21%%%, Srestore_d10%%%, Srestore_d01%%%, Srestore_d12%%%)
  338.             dcn = select(pos+2, Srestore_d21%%%, Srestore_d10%%%, Srestore_d01%%%, Srestore_d12%%%, Srestore_d23%%%)
  339.             dnn = select(pos+2, Srestore_d10%%%, Srestore_d01%%%, Srestore_d12%%%, Srestore_d23%%%, Srestore_d34%%%)
  340.  
  341.             ## dup_hq - merge ##
  342.             dup     = opos!=pos || abs(dm)<2 || abs(dm)==3 ? 0 : dcn*5<dbc && dnn*5<dbc && (dcn<1.25*thr || bn<bc && pos==Srestore_lpos%%%) ||
  343.                     \ (dcn*dcn<dbc || dcn*5<dbc) && bn<bc && pos==Srestore_lpos%%% && dnn<.9*dbc || dnn*9<dbc && dcn*3<dbc ? 1 :
  344.                     \ (dbc*dbc<dcn || dbc*5<dcn) && bb<bc && pos==Srestore_lpos%%% && dbb<.9*dcn || dbb*9<dcn && dbc*3<dcn ||
  345.                     \ dbb*5<dcn && dbc*5<dcn && (dbc<1.25*thr || bb<bc && pos==Srestore_lpos%%%) ? -1 : 0
  346.             mer     = !bom && opos==pos && dup==0 && abs(dm)>2 && (dbc*8<dcn || dbc*8<dbb || dcn*8<dbc || dcn*8<dnn || dbc*2<thr ||
  347.                     \ dcn*2<thr || dnn*9<dbc && dcn*3<dbc || dbb*9<dcn && dbc*3<dcn)
  348.  
  349.             ## deblend - doubleblend removal - postprocessing ##
  350.             add     = Srestore_bp1%%%*Srestore_cn2%%%>Srestore_bn2%%%*Srestore_cp1%%%*(v1+thr*.01)
  351.                       \&& Srestore_bn0%%%*Srestore_cn2%%%>Srestore_bn2%%%*Srestore_cn0%%%*(v1+thr*.01)
  352.                       \&& Srestore_cn2%%%*Srestore_bn1%%%>Srestore_cn1%%%*Srestore_bn2%%%*(v1+thr*.01)
  353.             dup     = bom
  354.                         \? (Srestore_bn0%%%>Srestore_bp2%%%
  355.                             \&& Srestore_bn0%%%>=Srestore_bp1%%%
  356.                             \&& Srestore_bn0%%%>Srestore_bn1%%%
  357.                             \&& Srestore_bn0%%%>Srestore_bn2%%%
  358.                             \&& Srestore_cn0%%%<v125
  359.                             \? (Srestore_d12%%%*Srestore_d12%%%<Srestore_d10%%%
  360.                                 \|| Srestore_d12%%%*9<Srestore_d10%%%)
  361.                                 \? 1
  362.                                 \: (Srestore_d10%%%*Srestore_d10%%%<Srestore_d12%%%
  363.                                     \|| Srestore_d10%%%*9<Srestore_d12%%%)
  364.                                     \? 0
  365.                                     \: 4
  366.                             \: Srestore_bp1%%%>Srestore_bp3%%%
  367.                                 \&& Srestore_bp1%%%>=Srestore_bp2%%%
  368.                                 \&& Srestore_bp1%%%>Srestore_bn0%%%
  369.                                 \&& Srestore_bp1%%%>Srestore_bn1%%%
  370.                                 \? 1
  371.                                 \: 0)
  372.                         \: dup!=0
  373.                             \? dup
  374.                             \: om>0 && om<5
  375.                                 \? (bbool==false
  376.                                     \? 0
  377.                                     \: (om==4 && Srestore_bp1%%%*Srestore_cn1%%%<Srestore_bn1%%%*Srestore_cp1%%%)
  378.                                         \|| (om==3 && Srestore_d10%%%<Srestore_d01%%%)
  379.                                         \|| om==1
  380.                                         \? -1
  381.                                         \: 1)
  382.                                 \: om==5
  383.                                     \? (Srestore_bp1%%%*Srestore_cp2%%%>Srestore_bp2%%%*Srestore_cp1%%%*(v1+thr*.01)
  384.                                         \&& Srestore_bn0%%%*Srestore_cp2%%%>Srestore_bp2%%%*Srestore_cn0%%%*(v1+thr*.01)
  385.                                         \&& Srestore_cp2%%%*Srestore_bn1%%%>Srestore_cn1%%%*Srestore_bp2%%%*(v1+thr*.01)
  386.                                         \&& (add==false || Srestore_cp2%%%*Srestore_bn2%%%>Srestore_cn2%%%*Srestore_bp2%%%)
  387.                                         \? -2
  388.                                         \: add
  389.                                             \? 2
  390.                                             \: Srestore_bn0%%%*Srestore_cp1%%%>Srestore_bp1%%%*Srestore_cn0%%%
  391.                                                 \&& (Srestore_bn0%%%*Srestore_cn1%%%<Srestore_bn1%%%*Srestore_cn0%%%
  392.                                                 \|| Srestore_cp1%%%*Srestore_bn1%%%>Srestore_cn1%%%*Srestore_bp1%%%)
  393.                                                 \? -1
  394.                                                 \: Srestore_bn0%%%*Srestore_cn1%%%>Srestore_bn1%%%*Srestore_cn0%%%
  395.                                                     \? 1
  396.                                                     \: 0)
  397.                                     \: 0
  398.  
  399.             ### output clip ###
  400.             oclp    = mer && dup==0 ? mec : source
  401.             opos    = opos + dup - (dup==0 && mer && dbc<dcn ? 1 : 0)
  402.             dup==4 ? fin : opos<0 ? oclp.loop(1-opos, 0, 0) : oclp.trim(opos, 0)
  403.  
  404.         }
  405.     """, "%%%", string(Srestore_InstanceNumber)))   #"
  406. }
  407.  
  408.  
  409.  
  410. # Original:- By Vampiredom, Gavino, IanB
  411. # Repeated, string replacements
  412.  
  413. Function StrReplace(string s, string find, string replace)
  414. {
  415.  ssispmt = Findstr(VersionString(), "AviSynth+") != 0 && Findstr(VersionString(), "r1576") == 0
  416.  ssispmt ? ReplaceStr(s,find,replace) : eval("""i = s.FindStr(find) Chr(3) i ==0 || Replace=="" ? s : (s.LeftStr(i-1)+replace+s.MidStr(Strlen(find)+i)).StrReplace(find, replace)""")
  417. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!