PS Vita Rejuvenate For Unity

@ECHO OFF
SET SCE_PSM_SDK=%CD%\support

:init
CLS
COLOR 2F
ECHO Rejuvenate Setup For Unity
ECHO Ported By John
ECHO(
ECHO You only need to run this script once. However, if you need to change any
ECHO settings (such as version or keys), you can run this script again.
ECHO(
PAUSE

:checkfiles
IF NOT EXIST "support\tools\lib\host_transport32.dll" GOTO getfiles
IF NOT EXIST "support\tools\lib\host_transport64.dll" GOTO getfiles
IF NOT EXIST "support\tools\lib\psm_device32.dll" GOTO getfiles
IF NOT EXIST "support\tools\lib\psm_device64.dll" GOTO getfiles
IF NOT EXIST "support\tools\lib\psm_encrypter32.dll" GOTO getfiles
IF NOT EXIST "support\tools\lib\psm_encrypter64.dll" GOTO getfiles
IF NOT EXIST "support\tools\runtime.ver" GOTO getfiles
IF NOT EXIST "support\tools\sdk_version.txt" GOTO getfiles
IF NOT EXIST "support\dpinst.exe" GOTO getfiles

GOTO installdriver

:getfiles
IF EXIST "PSMToolSetForUnity_1.1.0.7.exe" GOTO extractfiles
ECHO Please download "PSMToolSetForUnity_1.1.0.7.exe" and place it in this directory.
PAUSE
GOTO getfiles
:extractfiles
MKDIR support\tools\lib 2> nul
MKDIR support\tools\PublishingUtility 2> nul
MKDIR support\tools\PsmDevice 2> nul
ECHO Extracting PSM files. Please wait...
START /WAIT support\7z.exe x -o"%TEMP%" -y "PSMToolSetForUnity_1.1.0.7.exe"
ECHO Copying files...
COPY /Y "%TEMP%\tools\lib\host_kdbg_acquirer32.dll" "support\tools\lib\host_kdbg_acquirer32.dll"
COPY /Y "%TEMP%\tools\lib\host_kdbg_acquirer64.dll" "support\tools\lib\host_kdbg_acquirer64.dll"
COPY /Y "%TEMP%\tools\lib\host_transport32.dll" "support\tools\lib\host_transport32.dll"
COPY /Y "%TEMP%\tools\lib\host_transport64.dll" "support\tools\lib\host_transport64.dll"
COPY /Y "%TEMP%\tools\lib\kpub_generator32.dll" "support\tools\lib\kpub_generator32.dll"
COPY /Y "%TEMP%\tools\lib\kpub_generator64.dll" "support\tools\lib\kpub_generator64.dll"
COPY /Y "%TEMP%\tools\lib\psm_device32.dll" "support\tools\lib\psm_device32.dll"
COPY /Y "%TEMP%\tools\lib\psm_device64.dll" "support\tools\lib\psm_device64.dll"
COPY /Y "%TEMP%\tools\lib\submission_archive_generator32.dll" "support\tools\lib\submission_archive_generator32.dll"
COPY /Y "%TEMP%\tools\lib\submission_archive_generator64.dll" "support\tools\lib\submission_archive_generator64.dll"
COPY /Y "%TEMP%\tools\lib\target_kdbg_acquirer32.dll" "support\tools\lib\target_kdbg_acquirer32.dll"
COPY /Y "%TEMP%\tools\lib\target_kdbg_acquirer64.dll" "support\tools\lib\target_kdbg_acquirer64.dll"
COPY /Y "%TEMP%\tools\lib\psm_encrypter32.dll" "support\tools\lib\psm_encrypter32.dll"
COPY /Y "%TEMP%\tools\lib\psm_encrypter64.dll" "support\tools\lib\psm_encrypter64.dll"
DEL "lib\RUN_SETUP_BAT.txt" 2> nul
COPY /Y "%TEMP%\tools\PublishingUtility\PublishingUtilityForUnity.exe" "support\tools\PublishingUtility\PublishingUtilityForUnity.exe"
COPY /Y "%TEMP%\tools\PublishingUtility\PanelManager.dll" "support\tools\PublishingUtility\PanelManager.dll"
COPY /Y "%TEMP%\tools\PsmDevice\PsmDeviceForUnity.exe" "support\tools\PsmDevice\PsmDeviceForUnity.exe"
COPY /Y "%TEMP%\tools\runtime.ver" "support\tools\runtime.ver"
COPY /Y "%TEMP%\tools\sdk_version.txt" "support\tools\sdk_version.txt"
SET DPINST_TYPE=x86
IF EXIST "%systemroot%\sysnative\" set DPINST_TYPE=amd64
IF EXIST "%systemroot%\syswow64\" set DPINST_TYPE=amd64
COPY /Y "%TEMP%\tools\PS_Vita\driver\dpinst\%DPINST_TYPE%\dpinst.exe" "support\dpinst.exe"
COPY /Y "%TEMP%\tools\PS_Vita\driver\dpinst.xml" "support\dpinst.xml"
COPY /Y "%TEMP%\tools\PS_Vita\driver\vita_usbser.cat" "support\vita_usbser.cat"
COPY /Y "%TEMP%\tools\PS_Vita\driver\vita_usbser.inf" "support\vita_usbser.inf"

:installdriver
ECHO Installing driver for PSM...
support\dpinst.exe /SA /EL

:checkkeys
IF NOT EXIST "kdev.p12" GOTO checkkeys2
IF NOT EXIST "+asterisk+.khapp" GOTO checkkeys2
GOTO getversion

:checkkeys2
IF NOT EXIST "%APPDATA%\SCE\PSM Publishing Utility For Unity\PublisherKey\kdev.p12" GOTO generatekeys
IF NOT EXIST "%APPDATA%\SCE\PSM Publishing Utility For Unity\HostAppsKey\+asterisk+.khapp" GOTO generatekeys
CLS
COPY /Y "%APPDATA%\SCE\PSM Publishing Utility For Unity\PublisherKey\kdev.p12" "kdev.p12"
COPY /Y "%APPDATA%\SCE\PSM Publishing Utility For Unity\HostAppsKey\+asterisk+.khapp" "+asterisk+.khapp"
ECHO Copied keys from Publishing Utility.
ECHO(
PAUSE
GOTO getversion

:generatekeys
IF NOT EXIST "support\tools\PublishingUtility\PublishingUtilityForUnity.exe" GOTO getfiles
IF NOT EXIST "support\tools\PsmDevice\PsmDeviceForUnity.exe" GOTO getfiles
CLS
ECHO You do not have "kdev.p12" and "+asterisk+.khapp" keys.
ECHO If you have a publisher's license, you can generate the keys.
ECHO Otherwise, please obtain the files elsewhere and place them in
ECHO this directory.
ECHO(
SET GEN_KEY=y
SET /P GEN_KEY=Would you like to generate a key? [y/n] (default - y)?:
IF "%GEN_KEY%"=="y" GOTO locatedevice
GOTO checkkeys
:locatedevice
ECHO Please plug in your Vita and open PSM DevAssistant For Unity
ECHO (Then wait until the driver finishes installing before continuing)
PAUSE
START support\tools\PsmDevice\PsmDeviceForUnity.exe
REM So we have to wait a bit because of a bug in PsmDeviceForUnity where it freezes
REM when it is ran right after installing driver.
ECHO Waiting...
ping -n 6 127.0.0.1 > nul
FOR /F "Tokens=4 Skip=1" %%A IN (
    'support\tools\PsmDevice\PsmDeviceForUnity.exe -list_devices'
) DO (
    SET DEVICEID=%%A
)
IF "%DEVICEID%"=="" GOTO locatedevice
ECHO Device found: %DEVICEID%
START /WAIT support\tools\PublishingUtility\PublishingUtilityForUnity.exe --updatekey "%DEVICEID%" "*"
GOTO checkkeys2

:getversion
CLS
ECHO You need to specify the version of your PSM DevAssistant For Unity on the Vita
ECHO To find this, go to LiveArea and find the icon for "PSM Dev For Unity"
ECHO Press and hold the icon, then press the "..." next to the icon
ECHO Select "Information" and look at what it says next to "Version"
ECHO (If your Vita is another language, translate accordingly)
ECHO(
SET /P PSM_VERSION=Version:
set DEFILER_EXE="VitaDefiler-115.exe"
IF "%PSM_VERSION%"=="1.15" SET DEFILER_EXE="VitaDefiler-115.exe"
IF "%PSM_VERSION%"=="1.14" SET DEFILER_EXE="VitaDefiler-115.exe"
IF "%PSM_VERSION%"=="1.11" SET DEFILER_EXE="VitaDefiler-111.exe"
IF NOT "%DEFILER_EXE%"=="" GOTO copydefiler
ECHO Version '%PSM_VERSION%' is currently unsupported!
ECHO Defaulting to 1.15, however VitaDefiler will likely not work.
ECHO(
PAUSE

:copydefiler
COPY /Y "vitadefiler\%DEFILER_EXE%" "VitaDefiler.exe"

:createpackage
CLS
ECHO Signing VitaDefiler client with keys...
support\PsmSigner.exe "+asterisk+.khapp" "kdev.p12" "support\VitaDefilerClient" "VitaDefilerClient.psdp"

:done
ECHO Done with Rejuvenate setup.
ECHO(
ECHO You may now delete "PSMToolSetForUnity_1.1.0.7.exe" if you have it
ECHO(
ECHO To run homebrew, drag the homebrew ELF to "start_homebrew.bat"
ECHO To run the RPC, run "start_rpc.bat"
ECHO Enjoy!
PAUSE