* Delineamento e Análise de Experimentos 1
* Delineamentos Fatoriais completamente casualizados
* Modelo Fatorial com Tratamentos Não Balanceados
* Prof. George von Borries
* CAP. 9 de Johnson e Milliken;

OPTIONS NODATE PAGENO=1 nodate center;

 DATA ONE;
  INPUT A B Y;
 CARDS;
  1    1    19
  1    1    20
  1    1    21
  1    2    24
  1    2    26
  1    3    22
  1    3    25
  1    3    25
  2    1    25
  2    1    27
  2    2    21
  2    2    24
  2    2    24
  2    3    31
  2    3    32
  2    3    33
;

 TITLE1 'Ex. #9.1 - Exp. com dois fatores e não balanceado';
 TITLE2 'Análise pelo Modelo de Médias';

PROC GLM;
   CLASS A B;
   MODEL Y = A B A*B;
 RUN; QUIT;

PROC GLM;
   CLASS A B;
   MODEL Y =A*B / NOINT E SOLUTION CLPARM;
   ESTIMATE '(01)' A*B 1 1 1 1 1 1/DIVISOR=6;
   ESTIMATE '(02)' A*B 1 1 1 0 0 0/DIVISOR=3;
   ESTIMATE '(03)' A*B 0 0 0 -1 -1 -1/DIVISOR=3;
   ESTIMATE '(04)' A*B 1 1 1 -1 -1 -1/DIVISOR=3 ;
   ESTIMATE '(05)' A*B 1 0 0 1 0 0/DIVISOR=2;
   ESTIMATE '(06)' A*B 0 1 0 0 1 0/DIVISOR=2;
   ESTIMATE '(07)' A*B 0 0 1 0 0 1/DIVISOR=2;
   ESTIMATE '(08)' A*B .5 0 -.5  .5 0 -.5;
   ESTIMATE '(09)' A*B 0 .5 -.5 0 .5 -.5;
   ESTIMATE '(10)' A*B 0.5 -0.5 0 0.5 -0.5 0;
   ESTIMATE '(11)' A*B 1 0 -1 -1 0 1;
   ESTIMATE '(12)' A*B 0 1 -1 0 -1 1;

   CONTRAST '(13)' A*B 1 1 1 -1 -1 -1;
   CONTRAST '(14)' A*B 0.5 0   -0.5 0.5 0   -0.5,
                   A*B 0   0.5 -0.5 0   0.5 -0.5;
   CONTRAST '(15)' A*B 1 0 -1 1 0 -1,
                   A*B 0 1 -1 0 1 -1;
   CONTRAST '(16)' A*B 0.5 0 -0.5 0.5 0 -0.5,
                   A*B 0   1 -1   0   1 -1;
   CONTRAST '(17)' A*B 1 0 -1 -1 0 1,
                   A*B 0 1 -1 0 -1 1;

   LSMEANS A*B/PDIFF STDERR;
   ODS LISTING EXCLUDE NOBS CLASSLEVELS;
RUN; QUIT;