@echo off

call "%VS140COMNTOOLS%VsDevCmd.bat"

set _7Z=C:\Program Files\7-Zip\7z.exe
set CMAKE_PATH=C:\Program Files\CMake

if "%1"=="win32" goto win32
if "%1"=="win32p" goto win32p
if "%1"=="win64" goto win64
if "%1"=="win64p" goto win64p

echo Invalid argument: %1
goto end

:win32
set QT_PATH=E:\Qt\5.6.3\msvc2015
set ARCH_CMAKE_OPT=-G "Visual Studio 14 2015"
set ARCH_SUFFIX=win32
set OPENSSL_BIN=openssl-1.0.2p-i386-win32
goto build

:win64
set QT_PATH=E:\Qt\5.6.3\msvc2015_64
set ARCH_CMAKE_OPT=-G "Visual Studio 14 2015 Win64"
set ARCH_SUFFIX=win64
set OPENSSL_BIN=openssl-1.0.2p-x64_86-win64
goto build

:win32p
set QT_PATH=E:\Qt\5.6.3\msvc2015
set ARCH_CMAKE_OPT=-G "Visual Studio 14 2015" -DBUILD_PORTABLE=ON
set ARCH_SUFFIX=win32-portable
set OPENSSL_BIN=openssl-1.0.2p-i386-win32
goto build

:win64p
set QT_PATH=E:\Qt\5.6.3\msvc2015_64
set ARCH_CMAKE_OPT=-G "Visual Studio 14 2015 Win64" -DBUILD_PORTABLE=ON
set ARCH_SUFFIX=win64-portable
set OPENSSL_BIN=openssl-1.0.2p-x64_86-win64
goto build

:build
set CONFIG=Release

for /f %%x in ('git describe --tags --always') do set TAG=%%x

mkdir build-msvc-%ARCH_SUFFIX%
cd build-msvc-%ARCH_SUFFIX%

"%CMAKE_PATH%\bin\cmake.exe" .. "-DCMAKE_PREFIX_PATH=%QT_PATH%" -T v140_xp %ARCH_CMAKE_OPT%
msbuild DwarfTherapist.sln /p:Configuration=%CONFIG%
pause

set SRC=..
set DEST=DwarfTherapist-%TAG%-%ARCH_SUFFIX%
mkdir "%DEST%"

copy "%CONFIG%\DwarfTherapist.exe" "%DEST%"
"%QT_PATH%\bin\windeployqt.exe" "%DEST%\DwarfTherapist.exe"

xcopy "%SRC%\README.rst" "%DEST%" /Y
xcopy "%SRC%\LICENSE.txt" "%DEST%" /Y
xcopy "%SRC%\CHANGELOG.txt" "%DEST%" /Y
xcopy "%SRC%\lnp\manifest.json" "%DEST%" /Y

mkdir "%DEST%\data"
xcopy "%SRC%\share" "%DEST%\data" /E /Y

mkdir "%DEST%\doc"
xcopy "%SRC%\Dwarf Therapist.pdf" "%DEST%\doc" /Y

xcopy "%SRC%\%OPENSSL_BIN%\libeay32.dll" "%DEST%" /Y
xcopy "%SRC%\%OPENSSL_BIN%\ssleay32.dll" "%DEST%" /Y

"%_7Z%" a "../%DEST%.zip" "%DEST%"

:end
pause