List2Dialog

///////////llList2Dialog() Menu generator script ///////////////////
// Script by RumbleR Boa

//Script is in NO RUNNING mode. Please mark box Running in lower left corner.

//This script is full perm. You may sell it as part of your products, but you MUST NOT sell it as individual script!




//This list "MainMenu" is a system list, and its name must not be changed!
//All other lists are flexible, and represent user created content
//In this list you will write options that will appear in the Main menu

list MainMenu = [
"Colors",
"Textures",
"Sounds"
];

//List "Colors" is here only as an example, it can be called how ever you want
//You can put as many lists and options as you want, but you need to take care also about script's memory which is not unlimited
list Colors = [
"Red",
"Green",
"Blue",
"White"
];

//List "Textures" is here only as an example, it can be called how ever you want
//You can put as many lists and options as you want, but you need to take care also about script's memory which is not unlimited
list Textures = [
"Brick",
"Rock",
"Grass"
];

//List "Sounds" is here only as an example, it can be called how ever you want
//You can put as many lists and options as you want, but you need to take care also about script's memory which is not unlimited
list Sounds = [
"Comedy",
"Clap",
"Whistle"
];


list ActiveMenu; //Every time when we generate some menu or submenu, all the current menu options will be stored in this list
                 //We can think about this as RAM and Hard Disc. ActiveMenu is Ram where we operate with options which we loaded from
                 //other lists (Hard Disc)

integer NumberOfButtonsInTheMenu = 9; //This is the number of option buttons that will appear in the generated Dialog menu.
                                      //Do not put number less than 2 and greater than 9!!!

list ShortMenuForButtons = [];          // in this list we will store the button names for the current Dialog menu
integer NumberOfCurrentDialogMenu = 0;  // this is the "Serial" number of current Dialog menu
integer NumberOfItemsInTheContent = 0;  // here we will store how many options there are in the ActiveMenu list
integer MaximumNumberOfMenus = 0;       // in this variable we will see what is the maximum possible number of Dialog menus
                                        // depending on the number of items in the ActiveMenu
string ListOfItemNamesInStringForm = ""; // here we store the names of the files that will appear in the curent Dialog menu
integer i = 0;                          //variable that we will use for a loop counter
key PersonThatClicked;                  // Clicker :)
integer channel;                        // channel for communication between Clicker and our Script



list order_buttons(list buttons)
{ // Code that will sort our -list ShortMenuForButtons- in the best "human" readable order
    return llList2List(buttons, -3, -1) + llList2List(buttons, -6, -4)
         + llList2List(buttons, -9, -7) + llList2List(buttons, -12, -10);
}



generateMenu()  //Every time when we click on some sub menu, we need to generate new menu based on some params...
{
  NumberOfItemsInTheContent = llGetListLength(ActiveMenu); // we ask how many items are in the new (sub)menu

  MaximumNumberOfMenus = llFloor(NumberOfItemsInTheContent/NumberOfButtonsInTheMenu); // here by default we devide with 9 because we want 9 generated buttons for objects (remember that we put number 9 as default value: integer NumberOfButtonsInTheMenu = 9), but you can change this value how it suits you



        // This line here can look strange, but its purpose is very important. In the previous line, when we devided
        // the NumberOfItemsInTheContent with NumberOfButtonsInTheMenu, we set llFloor in order to get the Lower value of integer
        // number, BUT if it happens that during devision we have 0 as remaing decimal part after the "." we will have
        // one "ghost" dialog menu that will not show any Item buttons. With this code we actually protect our selves
        // from posible "bug".
        if (NumberOfItemsInTheContent % NumberOfButtonsInTheMenu == 0) MaximumNumberOfMenus--;



        NumberOfCurrentDialogMenu = 0; //we reset this variable because we want to start every new menu from the beggining
                                       //(from first option)
}



showMenu() // Code that will create the menu
{

    ShortMenuForButtons = [];         // Reset the starting variables to create a new menu
    ListOfItemNamesInStringForm = ""; // Reset the starting variables to create a new menu

    i=0;
    do {
        // This part is IMPORTANT! Here we ask if "i" NAME for "i" menu option exists, and if it
        // exists make button for that option, and put name in the -string ListOfItemNamesInStringForm-
        if (llList2String(ActiveMenu, NumberOfCurrentDialogMenu*NumberOfButtonsInTheMenu+i) != "")
        {
            //here we generate buttons
            ShortMenuForButtons += llList2String(ActiveMenu, NumberOfCurrentDialogMenu*NumberOfButtonsInTheMenu+i);

            //here we add name of the "i" item in the Text that will appear in the Dialog menu
            //if you don't want this, you can simply deactivate this line. It is not neccessary in the rest of the code
            ListOfItemNamesInStringForm += "\n" + (string)(NumberOfCurrentDialogMenu*NumberOfButtonsInTheMenu+i) + ") " +
                        llList2String(ActiveMenu, NumberOfCurrentDialogMenu*NumberOfButtonsInTheMenu+i);
        }
    } while (i++ < NumberOfButtonsInTheMenu-1); //by default we want 9 buttons, but because we also count Zero we have to decrease for 1 (NumberOfButtonsInTheMenu-1 = 8)

    ShortMenuForButtons += "<---"; //We add arrow for left in our menu
    ShortMenuForButtons += "MAIN MENU"; // We put "MAIN MENU" button so that we can easier go to first menu
    ShortMenuForButtons += "--->"; //We add arrow for right in our menu


    // Here we generate the ActiveMenu. We will add +1 on counters for NumberOfCurrentDialogMenu and MaximumNumberOfMenus
    // to have better written results (i.e. Good -> Menu No.1/1 ; Bad -> Menu No.0/0)
    llDialog(PersonThatClicked,
             "\nPlease select item.  Menu No." + (string)( NumberOfCurrentDialogMenu+1) + "/" +
             (string)(MaximumNumberOfMenus+1) + "\n"+ListOfItemNamesInStringForm,
             order_buttons(ShortMenuForButtons),
             channel);
}




default
{
    state_entry()
    {

        channel = (integer)(llFrand(-1000000000.0) - 1000000000.0); //we generate random channel...
        llListen(channel,"", "","");        //...and we start to listen it
    }

    on_rez(integer start_param)
    {
        llResetScript();
    }








    touch_start(integer total_number)
    {
        PersonThatClicked = llDetectedKey(0); //We take the UUID of person that clicked

        ActiveMenu = MainMenu; //We say that current active menu will be main menu
        generateMenu(); //We process the params...
        showMenu();     //...and we generate the menu
    }




    listen(integer _chan, string _name, key _id, string _option)
    {

        //IMPORTANT!!! First we will code user interface part, and then at the end of the listening event we will take care of activities based on clicking the each Menu button


        if (_option == "--->") // If arrow for Right is clicked...
        {
            if (NumberOfCurrentDialogMenu<MaximumNumberOfMenus) {NumberOfCurrentDialogMenu++; } else {NumberOfCurrentDialogMenu = 0;}
            //...we ask if the current menu number is lower than number of total possible menus.
            //If it is: ADD 1, and if it is not: RESET to ZERO
            showMenu();
        }




        if (_option == "<---")  //If arrow for Left is clicked...
        {

        if (NumberOfCurrentDialogMenu>0) {--NumberOfCurrentDialogMenu; } else {NumberOfCurrentDialogMenu =  MaximumNumberOfMenus;}
        //...we ask if the current menu number is bigger than ZERO.
        //If it is: SUBTRACT 1, and if it is not: SET to maximum number of menus

        showMenu();

        }


         //As you can notice below, calling every (sub)menu is always done via 3 same operations
        // a) ActiveMenu = name of submenu list;
        // b) generateMenu();
        // c) showMenu();

        //Only difference between menus is in using IF function,
        //...to check if name of a clicked button is the same as name of some submenu


        if (_option == "Colors") //Here we ask if button that was clicked suits to name of our submenu "Colors"
        {                         //...and if it does then we need to "copy" all items from menu/list  Colors to list ActiveMenu
            ActiveMenu=Colors;
            generateMenu();       //Since ActiveMenu list is now changed, we need to generate menu based on some params...
            showMenu();           //...and to "shoot" menu to person who clicked the button
        }

        if (_option == "Textures") //Here we ask if button that was clicked suits to name of our submenu "Textures"
        {                         //...and if it does then we need to "copy" all items from menu/list  Textures to list ActiveMenu
            ActiveMenu=Textures;
            generateMenu();       //Since ActiveMenu list is now changed, we need to generate menu based on some params...
            showMenu();           //...and to "shoot" menu to person who clicked the button
        }

        if (_option == "Sounds") //Here we ask if button that was clicked suits to name of our submenu "Sounds"
        {                         //...and if it does then we need to "copy" all items from menu/list  Sounds to list ActiveMenu
            ActiveMenu=Sounds;
            generateMenu();       //Since ActiveMenu list is now changed, we need to generate menu based on some params...
            showMenu();           //...and to "shoot" menu to person who clicked the button
        }

        if (_option == "MAIN MENU") //If button for Main menu was clicked, then we "shoot" the main menu to person who clicked
        {
          ActiveMenu = MainMenu;
          generateMenu();
          showMenu();
        }


       //Except calling the submenus we can also execute some functions after the certain button was pressed
       //To do this, we don't need to copy any list to ActiveMenu
       //We will just ask "IF something"..."THEN do something"

       //Lets pick some option from list "Colors"
       //For example "Red"

       if (_option == "Red")
       {
        llSetColor(<1,0,0>,ALL_SIDES); //As you can notice, here we have only one operation.
                                       //To test this, click the prim, click the button "Colors", and then click the button "Red"
                                       //...and you will see that prim changed color to red

         showMenu();
       }

       if (_option == "Green")
       {
        llSetColor(<0,1,0>,ALL_SIDES);
        showMenu();
       }

       if (_option == "Blue")
       {
        llSetColor(<0,0,1>,ALL_SIDES);
        showMenu();
       }

       if (_option == "White")
       {
        llSetColor(<1,1,1>,ALL_SIDES);
        showMenu();
       }



       if (_option == "Brick")
       {
        llSetTexture("75c0ae9b-bd5a-12f7-bfce-311271475122",ALL_SIDES);
        showMenu();
       }

       if (_option == "Rock")
       {
        llSetTexture("ebb6d25a-7192-a65c-7a39-903468df57ca",ALL_SIDES);
        showMenu();
       }

       if (_option == "Grass")
       {
        llSetTexture("28b33b68-5fd2-8ffc-8e13-19cdfae50117",ALL_SIDES);
        showMenu();
       }



        if (_option == "Comedy")
       {
        llPlaySound("8c10b6f1-b659-03c5-deb3-9459040de4cf",1);
        showMenu();
       }

        if (_option == "Clap")
       {
        llPlaySound("6089e539-2b45-67b9-0c9f-8cfac82465a8",1);
        showMenu();
       }

        if (_option == "Whistle")
       {
        llPlaySound("977dac77-7f0b-d022-74db-62d1f6862844",1);
        showMenu();
       }

    }






}