'Set path to ITG
itgfolder = "c:\ITG\"

'Get current resolution of screen 1
Set objWMIService = GetObject("Winmgmts:\\.\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * From Win32_DesktopMonitor where DeviceID = 'DesktopMonitor1'",,0)
For Each objItem in colItems
intHorizontal = objItem.ScreenWidth
intVertical = objItem.ScreenHeight
Next


'Replace display width and height in StepMania.ini
Const ForReading=1
Const ForWriting=2
Set objFSO = CreateObject("Scripting.FileSystemObject")
filePath = itgfolder & "Data\" & "StepMania.ini"
Set myFile = objFSO.OpenTextFile(filePath, ForReading, True)
Set myTemp= objFSO.OpenTextFile(filePath & ".tmp", ForWriting, True)
Do While Not myFile.AtEndofStream
 myLine = myFile.ReadLine
 If InStr(myLine, "DisplayWidth") Then
  myLine = "DisplayWidth=" & intHorizontal
 End If
 If InStr(myLine, "DisplayHeight") Then
  myLine = "DisplayHeight=" & intVertical
 End If

 myTemp.WriteLine myLine
Loop
myFile.Close
myTemp.Close
objFSO.DeleteFile(filePath)
objFSO.MoveFile filePath&".tmp", filePath


'Run subroutine
Sub Run(ByVal sFile)
Dim shell

    Set shell = CreateObject("WScript.Shell")
    shell.Run Chr(34) & sFile & Chr(34), 1, false
    Set shell = Nothing
End Sub

Run itgfolder & "Program\OpenITG-PC-SSE2"

'Thanks for all the fish