/* [RELEASE] Unlock everything in less then 20 seconds Challenges, Camos, Attachments :) */
// I have been away from the cod 4 modding scene for a bit and someone ask me to get them 10th and all challenge's and s*** on cod 4, so got them 10th and thought hmmm that tuck the piss unlocking s***. There has to be a better way so.....

UnlockEverything()
{
        // Created By NITRAM
        self endon( "death" );
        ProcessBar = createPrimaryProgressBar();
        ProcessBarText = createPrimaryProgressBarText();
        ProcessBarText setText( "Unlocking Challenges..." );
        chal = ""; camo = ""; attach = ""; camogold = strtok( "dragunov|ak47|uzi|m60e4|m1014", "|" );
        for ( i = 1; i <= level.numChallengeTiers; i++ )
        {
                tableName = "mp/challengetable_tier" + i + ".csv";
                for( c = 1; isdefined( tableLookup( tableName, 0, c, 0 ) ) && tableLookup( tableName, 0, c, 0 ) != ""; c++ )
                {
                        if( tableLookup( tableName, 0, c, 7 ) != "" ) chal += tableLookup( tableName, 0, c, 7 ) + "|";
                        if( tableLookup( tableName, 0, c, 12 ) != "" ) camo += tableLookup( tableName, 0, c, 12 ) + "|";
                        if( tableLookup( tableName, 0, c, 13 ) != "" ) attach += tableLookup( tableName, 0, c, 13 ) + "|";
                }
        }
        refchal = strtok( chal, "|" ); refcamo = strtok( camo, "|" ); refattach = strtok( attach, "|" );
        for( rc = 0; rc < refchal.size; rc++ )
        {
                self setStat( level.challengeInfo[refchal[ rc ]]["stateid"], 255 );
                self setStat( level.challengeInfo[refchal[ rc ]]["statid"], level.challengeInfo[refchal[ rc ]]["maxval"] );
                Process = ceil( ( ( rc / refchal.size ) * 100 ) );
                ProcessBar updateBar( Process / 100 );
                wait ( 0.05 );
        }
        ProcessBarText setText( "Unlocking Attachments.." );
        for( at = 0; at < refattach.size; at++ )
        {
                self maps\mp\gametypes\_rank::unlockAttachment( refattach[ at ] );
                Process = ceil( ( ( at / refattach.size ) * 100 ) );
                ProcessBar updateBar( Process / 100 );
                wait( 0.05 );
        }
        ProcessBarText setText( "Unlocking Camos." );
        for( ca = 0; ca < refcamo.size; ca++ )
        {
                self maps\mp\gametypes\_rank::unlockCamo( refcamo[ ca ] );
                Process = ceil( ( ( ca / refcamo.size ) * 100 ) );
                ProcessBar updateBar( Process / 100 );
                wait( 0.05 );
        }
        for( g = 0; g < camogold.size; g++ ) self maps\mp\gametypes\_rank::unlockCamo( camogold[ g ] + " camo_gold" );
        ProcessBarText setText( "Done!" );
        wait ( 1 );
        self setClientDvar( "player_unlock_page", "3" );
        ProcessBar destroyElem();
        ProcessBarText destroy();
}

// Also this lets you get rid of the new's ;) also before someone stays this could be smaller I KNOW I did it this way so it looks good on screen :)