# make some replacements in default dosbox config files
# run like: sed -r -i -f editconfs.sed Games/Games/*/dosboxz.conf

/\[sdl\]/,/\[dosbox\]/ {
	s/^fullresolution=.*/fullresolution=0x0/
	s/^output=.*/output=direct3d/
	s/^priority=.*/priority=higher,lower/

	/^mapperfile=/ a\
pixelshader=hq2x.fx
}

/\[dosbox\]/,/\[render\]/ {
	s/^captures=.*/captures=X:\\Temp\\Capture/
	s/^memsize=.*/memsize=16/

	/^machine=.*/ {
		a\
vmemsize=8
		c\
machine=svga_s3
	}
}

/\[render\]/,/\[cpu\]/ {
	/^aspect=/ {
		a\
linewise=false\
char9=false\
multiscan=false
		c\
aspect=true
	}

	s/^scaler=.*/scaler=hardware2x/

	/\[cpu\]/ i\
[vsync]\
vsyncmode=off\
vsyncrate=75\

}

/\[cpu\]/,/\[mixer\]/ {
	/^core=/ a\
cputype=auto
}

/\[mixer\]/,/\[joystick\]/ {
	s/rate=[0-9]+/rate=44100/
}

/\[mixer\]/,/\[midi\]/ {
	s/^blocksize=.*/blocksize=1024/
	s/^prebuffer=.*/prebuffer=20/
}

/\[midi\]/,/\[sblaster\]/ {
	s/^device=.*/mididevice=synth/
	s/^config=.*/midiconfig=D:\\DL\\Utils\\Multimedia\\sf2\\WeedsGM3.sf2/
}

/\[sblaster\]/,/\[gus\]/ {
	s/^mixer=.*/sbmixer=true/

	/^oplmode=/ a\
oplemu=default

	/^oplrate=/ a\
hardwarebase=220
}

/\[gus\]/,/\[speaker\]/ {
	s/^irq1=.*/gusirq=5/
	/^irq2=/ d
	s/^dma1=.*/gusdma=3/
	/^dma2=/ d
}

/\[dos\]/,/\[autoexec\]/ {
	/^umb=/ a\
automount=true

	/^keyboardlayout=/ {
		a\
files=127
		c\
keyboardlayout=auto
	}
}