public fw_PlayerPreThink(id)
{
    if(!is_user_alive(id) || !g_IsSlenderman[id])
        return

    static Float:flGametime; flGametime = get_gametime();

    static iTotalPlayers, iPlayers[32], Float:fvOrigin[3]; entity_get_vector(id, EV_VEC_origin, fvOrigin);

    iTotalPlayers = find_sphere_class(id, "player", SLENDER_RADIUS, iPlayers, 32, fvOrigin)

    //client_print(id, print_center, "JUGADORES EN EL RADIO: %d", iTotalPlayers);
    if(iTotalPlayers)
    {
        static i, victim;

        for(i = 0; i < iTotalPlayers; i++)
        {
            victim = iPlayers[i];

            if(g_IsSlenderman[victim] || !is_user_alive(victim) || !is_in_viewcone(victim, fvOrigin) || flGametime < g_flSlayDelay[victim])
                continue;

            if(flGametime > g_flLaughDelay[victim])
            {
                emit_sound(victim, CHAN_ITEM, g_szSlenderLaugh, VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
                g_flLaughDelay[victim] = flGametime + SLENDER_L_DELAY
            }

            shake_user_screen(victim);
            ExecuteHamB(Ham_TakeDamage, victim, id, id, 15.0, DMG_SHOCK)
            g_flSlayDelay[victim] = flGametime + SLENDER_DELAY
        }
    }
}