# Contributor: Leonard von Hagen <lennivh24 at gmail dot com>
# Contributor: Benjamin Landis <bmlandis2010@gmail.com>
# Contributor: Kent Fredric <kentfredric@gmail.com>
pkgname=bitmeteros
#replaces=(bitmeter-os) this would also result in a downgrade
# (0.8.0 -> 0_7_6) and might destroy some people's installations
conflicts=(bitmeter-os)
pkgver=0_7_6
pkgrel=10
pkgdesc="Bandwidth monitor for the browser or cli. Source version"
arch=('x86_64' 'i686')
url="https://github.com/codebox/bitmeteros"
license=('GPL3')
depends=( 'sqlite3' ) # pcap not needed?
install=
# bitmeteros.install
source=(
  $pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz
  "bitmeter.service" "bitmeter-web.service" "bitmeter.target"
)

sha256sums=('0c7344b16b02cdcc171cc70b6f75637d8469818f02281d856a24f8710f49579c'
            'ae07787753f2ee22c9e5578f844fe891035388b14f2930c883dc3bd218708e5e'
            '3f9c724ff71117f9d00eaaf43ae24543bbc299fbac85e8c3734af9c31aac16c6'
            '46d97032d45c83e94ac40cd74dbd7675b2af76caf71acb60ed8542352fbbe53f')

build() {
  cd "$srcdir/$pkgname-$pkgver/build/linux/"
    ./makeHelpTextC.sh
    make bmcapture bmclient bmws bmdb bmsync
}

package() {
    cd "$srcdir/$pkgname-$pkgver/build/linux/"
  mkdir -p "$pkgdir/usr/bin/"
    install -m 755 bmcapture bmclient bmws bmdb bmsync "$pkgdir/usr/bin/"

    cd "$srcdir/$pkgname-$pkgver/webserver/web"
    WEB_TARGET="$pkgdir/usr/share/webapps/$pkgname"
    mkdir -p "$WEB_TARGET/css/images/" "$WEB_TARGET/js/"
    mkdir -p "$WEB_TARGET/m/js" "$WEB_TARGET/m/css"

    install -m 644 index.html rss.xml favicon.ico "$WEB_TARGET/"
    install -m 644 css/*.css "$WEB_TARGET/css/"
    install -m 644 css/images/*.png css/images/*.gif \
        "$WEB_TARGET/css/images/"
    install -m 644 js/*.js "$WEB_TARGET/js/"
    install -m 644 m/*.xml "$WEB_TARGET/m/"
    install -m 644 m/js/*.js "$WEB_TARGET/m/js/"
    install -m 644 m/css/*.css "$WEB_TARGET/m/css/"
    touch "$WEB_TARGET/config"

    mkdir -p "$pkgdir/var/lib/bitmeter/"
    install -m 644 "$srcdir/$pkgname-$pkgver/build/bitmeter.db" \
        "$pkgdir/var/lib/bitmeter/bitmeter.db"

    MAN_TARGET="$pkgdir/usr/share/man/man1"
    mkdir -p $MAN_TARGET/
    gzip -cn "$srcdir/$pkgname-$pkgver/bmclient/man.txt" > "$MAN_TARGET/bmclient.1.gz"
    gzip -cn "$srcdir/$pkgname-$pkgver/bmdb/man.txt" > "$MAN_TARGET/bmdb.1.gz"
    gzip -cn "$srcdir/$pkgname-$pkgver/bmsync/man.txt" > "$MAN_TARGET/bmsync.1.gz"

  install -v -Dm0644 "${srcdir}/bitmeter.service"         "${pkgdir}/usr/lib/systemd/system/bitmeter.service"
  install -v -Dm0644 "${srcdir}/bitmeter.target"          "${pkgdir}/usr/lib/systemd/system/bitmeter.target"
  install -v -Dm0644 "${srcdir}/bitmeter-web.service"     "${pkgdir}/usr/lib/systemd/system/bitmeter-web.service"

    mkdir -p "$pkgdir/var/log/bitmeter/"
    touch "$pkgdir/var/log/bitmeter/bitmeter.log"
}