;
;  ADVENTURE LOG SCRIPT BY CAT
;
;  Zet alog.timer in perform
;  Verander "Ilovearagorn" in jouw RSN op regel 22
;  Zet een ; voor regel 81
;
;  Hf.
;

alias alog.timer {
  .timeralog 0 300 sockopen alog services.runescape.com 80
}
alias alog.do {
  sockopen alog services.runescape.com 80
}
on *:SOCKOPEN:alog: {
  if ($sockerr) {
    .notice $me Error while connecting to the page: $sock(alog).wsmsg
    return
  }
  sockwrite -n alog GET /m=adventurers-log/rssfeed?searchName=Ilovearagorn HTTP/1.1
  sockwrite -n alog Host: services.runescape.com $+ $str($crlf ,2)
}

on *:SOCKREAD:alog: {
  if ($sockerr) {
    .notice $me Error while connecting to the alog page: $sock(alog).wsmsg
    return
  }
  else {
    .sockread %alog.read
    ;echo -s %alog.read
    if (%alog.start) {
      ;echo -s %alog.read
      if ($numtok(%alog.events,140) >= 5) {
        sockclose alog
        alog.close
      }
      if (description isin %alog.read) {
        if (<description>*</description> iswm %alog.read) {
          set %alog.event $remove($html2chr(%alog.read),<description>,</description>)
        }
        elseif (<description> isin %alog.read) {
          set %alog.desc open
          set %alog.event $gettok($replace(%alog.read,$v1,¶),2,182)
        }
        elseif (</description> isin %alog.read) {
          set %alog.desc closed
          set %alog.event $addtok(%alog.event,$html2chr($gettok($replace(%alog.read,$v1,¶),1,182)),32)
        }
      }
      elseif (<pubDate> isin %alog.read) {
        set %alog.event $addtok(%alog.event,( $+ $remove(%alog.read,<pubDate>,</pubDate>,$chr(44),$chr(32) $+ 00:00:00 GMT) $+ ),32)
        var %addtok $remove($replace(%alog.event,$chr(32) $+ $chr(44),$chr(44)),$chr(9))
        var %addtok $html2chr(%addtok)
        if ($istok(%alog.events,%addtok,140)) set %alog.events  %alog.events $+ $chr(140) $+ %addtok
        else set %alog.events $addtok(%alog.events,%addtok,140)
        unset %alog.event
      }
      elseif (%alog.desc == open) {
        set %alog.event $addtok(%alog.event,%alog.read,32)
      }
    }
    if (<item> isin %alog.read) { set %alog.start 1 }
    if (error isin %alog.read) echo 4 -st [ALOG] $v2
  }
}
on *:SOCKCLOSE:alog: {
  alog.close
}
alias alog.close {
  ;echo 4 %alog.events
  if (%alog.events != %alogreeks) && (%alog.events) {
    var %n $numtok(%alog.events,140)
    while (%n > 0) {
      var %event $gettok(%alog.events,%n,140)
      if (!$istok(%alogreeks,%event,140)) {
        ;echo 12 -at [ALOG]1 %event
        msg #RSR [ALOG] %event
        splay -q rss.wav
      }
      set %alogreeks $remtok(%alogreeks,%event,1,140)
      dec %n
    }
    set %alogreeks %alog.events
  }
  unset %alog.*
}
alias html2chr {
  return $replace($regsubex($1-,/(&#(\d*));?/g,$chr(\2)),&nbsp;,$chr(32),&,&,&apos;,',",",>,>,&st;,<)
}