{$CLEO .cs}

//-------------MAIN---------------
thread 'MINE'

:Initial
wait 0
Player.Defined($PLAYER_CHAR) // Если условие одно - if можно не ставить, а вот jf(else_goto, else_jump) ставить после каждого условия обязательно!
jf @Initial

:Load_Stuff_1
Model.Load(582)
038B: load_requested_models

:Load_Stuff_2
wait 0
Model.Available(582)
jf @Load_Stuff_2

:Main_Cycle
wait 0
Player.Defined($PLAYER_CHAR)
jf @Main_Cycle // Нужно выполнять эту проверку отдельно, т.к. если игрок не существует, дальнейшие проверки и действия с игроком(типа Actor.Driving($PLAYER_ACTOR)) будут вызывать краш
Model.Available(582)
jf @Load_Stuff_1 // В дальнейших повторениях цикла желательно перепроверять, доступна ли модель(на случай, если её выгрузили другим скриптом)
if and
Actor.Driving($PLAYER_ACTOR)
0AB0: key_pressed 49 // 1
jf @Main_Cycle

:Mine_Drop_1
wait 0
8AB0: not key_pressed 49
jf @Mine_Drop_1 // Проверка, что клавишу отпустили
Player.Defined($PLAYER_CHAR)
jf @Main_Cycle // Игрок мог перестать существовать, пока была зажата кнопка, так что нужно перепроверить, т.к. если игрок не существует, дальнейшие проверки и действия с игроком(типа Actor.Driving($PLAYER_ACTOR)) будут вызывать краш
Actor.Driving($PLAYER_ACTOR)
jf @Main_Cycle // Игрок мог перестать водить авто, пока была зажата кнопка, так что нужно перепроверить
0@ = Actor.CurrentCar($PLAYER_ACTOR)
04C4: store_coords_to 1@ 2@ 4@ from_actor $PLAYER_ACTOR with_offset 0.0 -3.5 1.0
02CE: 3@ = ground_z 1@ 2@ 4@ // Z координата земли в данной точке, чтобы поместить мину прямо на землю
0063: 4@ -= 3@
0023:   10.0 > 4@
jf @Main_Cycle // Если мина сбрасывается с высоты более 10 метров - отмена сброса
4@ = Object.Create(582, 1@, 2@, 3@)
Object.CollisionDetection(4@) = False
Object.ToggleInMovingList(4@) = False

:Mine_Drop_2
wait 0
Player.Defined($PLAYER_CHAR)
jf @Delete_Mine_2
8039:   NOT 0@ == -1 // Проверка, что тачка 0@ еще существует
jf @Mine_Drop_3 // Если нет - ничто нам не мешает активировать мину
00AA: store_car 0@ position_to 5@ 6@ 7@
050A: 7@ = distance_between_XYZ 5@ 6@ 7@ and_XYZ 1@ 2@ 3@
0021:   7@ > 5.0
jf @Mine_Drop_2 // Мина становится активной, когда транспорт, из которого она была выброшена, отъехал/отлетел от нее на 5 метров

:Mine_Drop_3
Object.CollisionDetection(4@) = True
Object.ToggleInMovingList(4@) = True
0167: 15@ = create_marker_at 1@ 2@ 3@ color 1 flag 2
16@ = 0 // запускаем таймер "жизни" мины

:Mine_Checks
wait 0
if and
Player.Defined($PLAYER_CHAR)
03CA:   object 4@ exists
001B:   60000 > 16@
jf @Delete_Mine // Если игрок перестал существовать ИЛИ объект исчез ИЛИ прошло больше минуты(60000мс) - мина удаляется
8AB0: not key_pressed 50
jf @Delete_Mine // Если игрок нажал кнопку "2" - мина удаляется
8366: NOT object 4@ damaged
jf @Mine_Explode
0AB0: key_pressed 49
jf @Mine_Checks

:Mine_Explode
wait 0
03CA:   object 4@ exists
jf @Delete_Mine // Если объект за этовремя исчез - мина удаляется
01BB: store_object 4@ position_to 1@ 2@ 3@
020C: create_explosion_with_radius 1 at 1@ 2@ 3@
020C: create_explosion_with_radius 6 at 1@ 2@ 3@
020C: create_explosion_with_radius 7 at 1@ 2@ 3@
0AE2: 7@ = random_vehicle_near_point 1@ 2@ 3@ in_radius 10.0 find_next 0 pass_wrecked 1 // find_next 0 означает старт поиска, pass_wrecked 1 - пропуск взорванных транспортных средств
jf @Delete_Mine // Если не найдено ни одно авто - мина удаляется
jump @Rhino_Check

:Next_Vehicle_Check
0AE2: 7@ = random_vehicle_near_point 1@ 2@ 3@ in_radius 10.0 find_next 1 pass_wrecked 1 // find_next 1 означает продолжение поиска, pass_wrecked 1 - пропуск взорванных транспортных средств
jf @Delete_Mine // Если больше не найдено ни одного авто - мина удаляется

:Rhino_Check
0137: car 7@ model == #RHINO
jf @Next_Vehicle_Check
Actor.Driving($PLAYER_ACTOR)
jf @Rhino_Check_2
0@ = Actor.CurrentCar($PLAYER_ACTOR)
803B:   NOT 7@ == 0@
jf @Delete_Mine // Если найденное авто и транспорт игрока - одно и то же - поиск останавливается, мина удаляется

:Rhino_Check_2
02AC: set_car 7@ immunities BP 0 FP 0 EP 0 CP 0 MP 0
02AA: set_car 7@ immune_to_nonplayer 0
01EC: make_car 7@ very_heavy 0
03AB: set_car 7@ strong 0
0224: set_car 7@ health_to -5000
jump @Next_Vehicle_Check // продолжаем поиск других танков в радиусе

:Delete_Mine
Marker.Disable(15@)

:Delete_Mine_2
Object.Destroy(4@)

:Delete_Mine_3
wait 0
if and
8AB0: not key_pressed 49
8AB0: not key_pressed 50
jf @Delete_Mine_3 // Пока игрок не отпустит кнопки "1" и "2" - ничего не произойдет
jump @Main_Cycle