ZED_Husk2

class ZED_Husk2 extends ZED_Husk;

var() byte ArchTypeIndex;
var transient ContentRep_Pawn NetworkRep;

simulated event PreBeginPlay()
{
    DefaultCollisionRadius = CylinderComponent.default.CollisionRadius;
    Super(KFPawn).PreBeginPlay();
    NormalGroundSpeed = default.GroundSpeed;

    NetworkRep = class'ContentRep_Pawn'.Static.FindContentRep(WorldInfo);
    if( NetworkRep!=None )
        InitPawn(NetworkRep.ObjRef);
}

simulated function InitPawn( ObjectReferencer O )
{
    SetCharacterArch(KFCharacterInfoBase(O.ReferencedObjects[ArchTypeIndex]));
    if( CharacterMICs.Length>0 && CharacterMICs[0]!=None )
        InitBodyMIC(CharacterMICs[0]);
}

simulated static function InitBodyMIC( MaterialInstanceConstant B )
{
    CloneMIC(B);
}

simulated static final function CloneMIC( MaterialInstanceConstant B )
{
    local int i;
    local MaterialInstanceConstant M;

    M = MaterialInstanceConstant(B.Parent);
    B.SetParent(M.Parent);

    for( i=0; i<M.TextureParameterValues.Length; ++i )
        if( M.TextureParameterValues[i].ParameterValue!=None )
            B.SetTextureParameterValue(M.TextureParameterValues[i].ParameterName,M.TextureParameterValues[i].ParameterValue);
}

DefaultProperties
{
    LocalizationKey="Husk Test"
    ArchTypeIndex=0
 }