include Base2.cmd


action var metal $1 when ^In the granite crucible you see some molten (.*)\.
action goto DONE when ^There is nothing in there\.

   gosub get my rod
STIR:
   matchre STIR ^\.\.\.wait|^Sorry
   matchre DONE ^You can only mix a crucible if it has something inside of it\.|^At last the metal appears to be thoroughly mixed and you pour it into an ingot mold.
   matchre BELLOWS ^As you finish the fire flickers and is unable to consume its fuel\.
   matchre SHOVEL ^As you complete working the fire dies down and needs more fuel\.
   matchre TURN.CRUCIBLE ^Upon finishing you observe clumps of molten metal accumulating along the crucible\'s sides\.
   matchre STIR Roundtime
   send stir crucible with my rod
   matchwait

CHECK.METAL:
   if ("$lefthandnoun" = "ingot") then goto DONE
   send look in crucible
   pause .5
ANALYZE.METAL:
   gosub analyze %metal in crucible
   goto STIR

BELLOWS:
   gosub put my rod in $craftpack
   gosub get my bellow
BELLOWS.1:
   matchre BELLOWS.1 ^\.\.\.wait|^Sorry
   matchre STOW.BELLOWS Roundtime|^You force copious amounts of air into the hot coals by pumping the bellows\.
   send push bellows
   matchwait

STOW.BELLOWS:
   gosub put my bellow in $craftpack
   gosub get my rod
   goto STIR

SHOVEL:
   gosub put my rod in $craftpack
   gosub get my shovel
SHOVEL.1:
   matchre SHOVEL.1 ^\.\.\.wait|^Sorry
   matchre STOW.SHOVEL Roundtime|^With wide sweeps of the shovel you scatter fuel evenly across the fire
   send push fuel with my shovel
   matchwait

STOW.SHOVEL:
   gosub put my shovel in $craftpack
   gosub get my rod
   goto STIR

TURN.CRUCIBLE:
   matchre TURN.CRUCIBLE ^\.\.\.wait|^Sorry
   matchre STIR Roundtime|^You lower the crucible down towards the fire to provide for more even heating\.|^You tilt the crucible slightly and tap one side to settle the cooler metal over the fire\.
   send turn crucible
   matchwait

DONE:
   if (("$righthandnoun" != "ingot") && ("$lefthandnoun" != "ingot")) then
   {
      gosub stow right in $craftpack
      gosub stow left in $craftpack
      gosub get ingot
   }
   gosub analyze my ingot
   gosub appraise my ingot careful
   gosub stow right in $craftpack
   echo SMELTING DONE
   send #parse SMELTING DONE
   exit