Mailspring 1.4.1 PKGBUILD

# Maintainer: Joakim Nylén <me@jnylen.nu>
# Contributor: guydep

pkgname=mailspring
_pkgver=1.4.1
pkgver=${_pkgver}
pkgrel=1
pkgdesc="A beautiful, fast and maintained fork of Nylas Mail by one of the original authors."
arch=('x86_64')
license=('custom: GPL3 and (C) 2016-2017 Foundry 376, LLC.')
url="https://getmailspring.com/"
makedepends=("patchelf")
options=("!strip" "staticlibs")


source=(
"https://archive.archlinux.org/packages/g/glibc/glibc-2.27-3-${CARCH}.pkg.tar.xz"
)

noextract=("glibc-2.27-3-${CARCH}.pkg.tar.xz")
sha256sums=(
'a9e1b18d7f613be660556dbd6883781e88a0f5113230147e230d3e2f268792dc'
)
sha256sums_x86_64=(
'9ce1439261d3909bdc9c3039a1cd8b4440c8dfc8a16210d7c2eada3868e66e0a'
)

source_x86_64=("https://github.com/Foundry376/Mailspring/releases/download/${_pkgver}/mailspring-${_pkgver}-amd64.deb")
depends=("libgnome-keyring" "gnome-keyring" "libxss" "libtool" "c-ares" "ctemplate" "tidy" "libxkbfile" "libsecret" "gconf" "gtk2" "nss")

package() {
    _ldir="/usr/share/$pkgname"
    _pdir="$pkgdir/$_ldir"
    _pexe="$pkgdir/usr/bin/$pkgname"

    cd ${srcdir}

    mkdir -p "$_pdir/glibc"

    tar -xJC "$_pdir/glibc" -f "glibc-2.27-3-$CARCH.pkg.tar.xz"
    rm "$_pdir/glibc/"{.BUILDINFO,.INSTALL,.MTREE,.PKGINFO}

    tar -xvf data.tar.xz -C ${pkgdir} --exclude='./control'

    patchelf --set-interpreter "$_ldir/glibc/usr/lib/ld-linux-x86-64.so.2" "$_pexe"
    patchelf --set-rpath "$_ldir:$_ldir/glibc/usr/lib" "$_pexe"

    chmod -R go-w "${pkgdir}"/usr
}