class_name MT

const MATRIX_A   : int   = 0x9908b0df
const UPPER_MASK : int = 0x80000000
const LOWER_MASK : int = 0x7fffffff

var mt : Array = []
var n  : int   = 624
var m  : int   = 397

func _init(sd : int = 1337) :
    self.mt.append(sd)
    for i in range(1,624):
        self.mt.append(self._int_32(1812433253 * (self.mt[i - 1] ^ (self.mt[i - 1] >> 30)) + i))

func _int_32(num : int) -> int :
    return int(0xffffffff & num)

func twist() -> void :
    var temp
    var temp_shift
    for i in range(624):
        temp = self._int_32((self.mt[i] & self.UPPER_MASK) + (self.mt[(i + 1) % 624] & self.LOWER_MASK))
        temp_shift = temp >> 1
        if temp % 2 != 0:
            temp_shift = temp_shift ^ self.MATRIX_A
        self.mt[i] = self.mt[(i + self.m) % 624] ^ temp_shift
    self.n = 0

# Generates a random number on [0,0xffffffff]-interval
func random_int() -> int :
    var y
    if self.n >= 624:
        self.twist()
    y = self.mt[self.n]
    y = y ^ (y >> 11)
    y = y ^ ((y << 7) & 0x9d2c5680)
    y = y ^ ((y << 15) & 0xefc60000)
    y = y ^ (y >> 18)
    self.n = self.n + 1
    return self._int_32(y)

# Generates a random number on [0,0x7fffffff]-interval
func random_int31() -> int :
    return (self.random_int() >> 1)

# Generates a random number on [0,1]-real-interval
func random_incl() -> float :
    return self.random_int() * (1.0 / 4294967295.0)

# Generates a random number on [0,1)-real-interval
func random() -> float :
    return self.random_int() * (1.0 / 4294967296.0)

# Generates a random number on (0,1)-real-interval
func random_excl() -> float :
    return (self.random_int() + 0.5) * (1.0 / 4294967296.0)

# Generates a random number on [0,1) with 53-bit resolution
func random_long() -> float :
    var a = self.random_int() >> 5
    var b = self.random_int() >> 6
    return(a * 67108864.0 + b) * (1.0 / 9007199254740992.0)