rem Маленький скрипт, который мониторит появление новых *.exe файлов на диске
echo off
cls
cd /d %~dp0
title In progress

rem Создание папки бэкапа
if /i not exist "backup" md "backup"

rem Если нет списка, создание и выход
if /i not exist list.txt (
dir /s /b /a-d "C:\*.exe">list.txt
exit
)

rem Создание второго списка
dir /s /b /a-d "C:\*.exe">list2.txt
type "c:\WINDOWS\system32\drivers\etc\hosts">>list2.txt

rem Сравнение
fc list.txt list2.txt

rem Если без изменений, выход
if /i "%errorlevel%"=="0" (
title Done: ok
pause
del /f /q list2.txt
exit
)
title Done: changes

rem Если с изменениями, запрос действия
<nul set /p nu=Подтвердить изменения? (y/n):
set /p main_order=

if /i not "%main_order%"=="y" (
del /f /q list2.txt
exit
)


call :gettime list.txt
move /y list.txt "backup\%vdate%_%vtime%.txt"
move /y list2.txt list.txt
exit









rem Модуль даты файла
:gettime
set vtime=%~t1
set vdate=%vtime:~0,-6%
set vtime=%vtime:~11,5%
set vtime=%vtime::=.%
set vtime=%vtime: =0%
goto :eof