@@ Book (#353)

@@ Basics
@create Book
@link Book = #340
@set Book = LINK_OK
@set Book = QUIET
@set Book = !NO_COMMAND

@@ Description strings (you ought to override these)
@DESCRIBE Book=A book entitled [name(me)]. It contains [v(PAGE_LAST)] pages of text.
@set Book/DESCRIBE=no_command visual prefixmatch public nearby
@SUCCESS Book=You picked up a book entitled [name(me)].
@set Book/SUCCESS=no_command prefixmatch
@OSUCCESS Book=picked up [name(me)].
@set Book/OSUCCESS=no_command prefixmatch
@FAILURE Book=You can't pick up this book.
@set Book/FAILURE=no_command prefixmatch

@@ Book data
&PAGE Book=
@set Book/PAGE=no_command
&PAGE_CURRENT Book=0
@set Book/PAGE_CURRENT=no_command
&PAGE_LAST Book=0
@set Book/PAGE_LAST=no_command

@@ Verbs
@@ Help
&DO_HELP Book=$howto *:@include me/DO_CHECK_USE; @pemit/silent %#=Usage:%r [ansi(h, << [name(me)])] %t go to the first page%r [ansi(h, >> [name(me)])] %t go to the last page %r [ansi(h, < [name(me)])] %t go to the previous page %r [ansi(h, > [name(me)])] %t go to the next page %r [ansi(h, ># [name(me)]=pg#)] %t go to specific page %r [ansi(h, ># [name(me)])] %t show current page and total page count %r [ansi(h, _ [name(me)])] %t read current page %r [ansi(h, ! [name(me)])] %t read current page aloud %r [ansi(h, >_ [name(me)])] %t go to the next page and read it %r [ansi(h, >! [name(me)])] %t go to the next page and read it aloud %r [ansi(h, ? [name(me)]=text)] %t show page numbers where text is found (case-insensitive) %r [ansi(h, >>+ [name(me)]=text)] %t add new page with specified text to the end %r [ansi(h, ++ [name(me)]=text)] %t insert new page with specified text before current page %r [ansi(h, -- [name(me)]=pg#)] %t delete specified page %r [ansi(h, howto [name(me)])] %t show this help %r To use a book you must pass its [ansi(h, @lock/user:use)]. To change book's content you must pass its [ansi(h, @lock/user:edit)].;

@@ Go to the first page: << BookName
&DO_FIRSTPAGE Book=$<< *:@include me/DO_CHECK_USE; &PAGE_CURRENT me=1; @pemit/silent %#=You open [name(me)] at the first page.

@@ Go to the previous page: < BookName
&DO_PREVPAGE Book=$< *:@include me/DO_CHECK_USE; @assert gt(v(PAGE_CURRENT),1)={@pemit/silent %#=You're on the first page.}; &PAGE_CURRENT me=[SUB(v(PAGE_CURRENT),1)]; @pemit/silent %#=You flip to the previous page of [name(me)].

@@ Go to the next page: > BookName
&DO_NEXTPAGE Book=$> *:@include me/DO_CHECK_USE; @assert lt(v(PAGE_CURRENT),v(PAGE_LAST))={@pemit/silent %#=You're on the last page.}; &PAGE_CURRENT me=[ADD(v(PAGE_CURRENT),1)]; @pemit/silent %#=You flip to the next page of [name(me)].

@@ Go to the last page: >> BookName
&DO_LASTPAGE Book=$>> *:@include me/DO_CHECK_USE;&PAGE_CURRENT me=v(PAGE_LAST); @pemit/silent %#=You open [name(me)] at the last page.

@@ Go to the specified page: ># BookName=page#
&DO_GOTOPAGE Book=$># *=*:@include me/DO_CHECK_USE; @assert CAND(isnum(%1), gte(%1,1), lte(%1, v(PAGE_LAST) ) ); &PAGE_CURRENT me=%1; @pemit/silent %#=You open [name(me)] at page [v(PAGE_CURRENT)].

@@ Get current page # and total pages count: ># BookName
&DO_GETPAGE Book=$># *:@include me/DO_CHECK_USE; @pemit/silent %#=[v(PAGE_CURRENT)]/[v(PAGE_LAST)]

@@ Read current page: _ BookName
&DO_READ Book=$_ *:@include me/DO_CHECK_USE; @assert hasattr(me,PAGE`[v(PAGE_CURRENT)])={@pemit/silent %#=This page is blank.}; @pemit/silent %#= "[v(PAGE`[v(PAGE_CURRENT)])]"

@@ Read current page aloud: ! BookName
&DO_ALOUD Book=$! *:@include me/DO_CHECK_USE; @assert hasattr(me,PAGE`[v(PAGE_CURRENT)])={@pemit/silent %#=This page is blank.}; @oemit %#=%N reads, "[v(PAGE`[v(PAGE_CURRENT)])]"; @pemit/silent %#=You read, "[v(PAGE`[v(PAGE_CURRENT)])]"

@@ Read next page: >_ BookName
&DO_READNEXT Book=$>_ *:@include me/DO_CHECK_USE; @assert lt(v(PAGE_CURRENT),v(PAGE_LAST))={@pemit/silent %#=You're on the last page.}; &PAGE_CURRENT me=[ADD(v(PAGE_CURRENT),1)]; {@pemit/silent %#=You flip to the next page of [name(me)].}; @pemit/silent %#="[v(PAGE`[v(PAGE_CURRENT)])]"

@@ Read next page aloud: >_ BookName
&DO_ALOUDNEXT Book=$>! *:@include me/DO_CHECK_USE; @assert lt(v(PAGE_CURRENT),v(PAGE_LAST))={@pemit/silent %#=You're on the last page.}; &PAGE_CURRENT me=[ADD(v(PAGE_CURRENT),1)]; {@pemit/silent %#=You flip to the next page of [name(me)].}; @oemit %#=%N reads, "[v(PAGE`[v(PAGE_CURRENT)])]"; @pemit/silent %#=You read, "[v(PAGE`[v(PAGE_CURRENT)])]"

@@ Look for text: ? BookName=text
&DO_SEARCH Book=$\? *=*: @break comp(num(%0),%!); @pemit/silent %#=Pages: [iter(grepi(Diary, {PAGE`*}, {%1}), after(##,`))]

@@ Append page to the end: >>+ BookName=Page text
&DO_ADDPAGE Book=$>>+ *=*:@include me/DO_CHECK_USE; @include me/DO_CHECK_EDIT; @assert gt(strlen(%1),0); &PAGE_LAST me=add(get(me/PAGE_LAST),1); &PAGE_CURRENT me=get(me/PAGE_LAST); &PAGE`[get(me/PAGE_LAST)] me={%1}; @pemit/silent %#=You added new page into [name(me)].

@@ Add page before the current page: ++ BookName=Page text
&DO_INSPAGE Book=$++ *=*:@include me/DO_CHECK_USE; @include me/DO_CHECK_EDIT; @assert gt(strlen(%1),0); @switch gte(v(PAGE_CURRENT),1)=0,{&PAGE_CURRENT me=1};@wait me={&PAGE_LAST me=add(v(PAGE_LAST),1); &PAGE`[v(PAGE_CURRENT)] me={%1}; @pemit/silent %#=You added new page into [name(me)].}; @tr me/DO_SHIFTPAGES=[v(PAGE_CURRENT)],[v(PAGE_LAST)],1;

@@ Delete specified page: -- BookName=page#
&DO_DELPAGE Book=$-- *=*:@include me/DO_CHECK_USE; @include me/DO_CHECK_EDIT; @assert CAND(gt(%1,0),lte(%1,v(PAGE_LAST))); @wait me={&PAGE`[v(PAGE_LAST)] me; &PAGE_LAST me=sub(v(PAGE_LAST),1); @switch gt(v(PAGE_CURRENT),v(PAGE_LAST))=1,&PAGE_CURRENT me=[v(PAGE_LAST)]; @pemit/silent %#=You tore out page #[%1] from [name(me)].}; @break eq(%1,v(PAGE_LAST))=@notify me; @tr me/DO_SHIFTPAGES=add(%1,1),[v(PAGE_LAST)],-1;

@@ Helper functions
@@ helper function that shifts pages. warning: pretty slow. Usage: @tr BookName/DO_SHIFTPAGES=startpage,endpage,offset
&DO_SHIFTPAGES Book=@dolist/notify/delimit | [cond( gt(%2,0), lnum(%1,%0,|) , lnum(%0,%1,|) )]={&PAGE`[add(##,%2)] me=v(PAGE`[##])}

@@ Helper function that checks if user can do anything to the book
&DO_CHECK_USE Book=@break comp(num(%0),%!); @assert elock(me/user:use, %#)={@pemit/silent %#=You can't do anything with this book.};
&DO_CHECK_EDIT Book=@assert elock(me/user:edit, %#)={@pemit/silent %#=You can't change contents of this book.};