alias bfile { return badnicks.ini }

alias badnick {
  if ($1 == add) {
    if ($2) {
      if (!$findfile($scriptdir,$bfile,1)) {
        writeini $bfile badnicks $2 $2 | Echo -a * Criando arquivo para os BADNICKS. | Echo -a * O nick $2 foi adicionado a lista de BADNICKS.
      }
      else {
        if !$ini($bfile,badnicks,$2) { writeini $bfile badnicks $2 $2 | Echo -a * O nick $2 foi adicionado a lista de BADNICKS. }
        else { Echo -a * O nick $2 ja consta na lista de BADNICKS }
      }
    }
  }
  if ($1 == del) {
    if ($2) {
      if ($findfile($scriptdir,$bfile,1)) {
        if $ini($bfile,badnicks,$2) { remini $bfile badnicks $2 | Echo -a * O nick $2 foi removido da lista de BADNICKS. }
        else { Echo -a * O nick $2 não consta na lista de BADNICKS. }
      }
    }
  }
  if ($1 == list) {
    if ($ini($bfile,badnicks,0) != 0) {
      var %c = $ini($bfile,badnicks,0)
      Echo -a * Lista de BADNICKS
      while (%c) {
        Echo 4 -a - $ini($bfile,badnicks,%c)
        dec %c
      }
      Echo -a * Fim da lista.
    }
    else { Echo * A lista de BADNICKS esta vazia. }
  }
  if ($1 == on) { .enable #badnick | Echo -a * Proteção para BADNICK esta agora ATIVADA. }
  if ($1 == off) { .disable #badnick | Echo -a * Proteção para BADNICK esta agora DESATIVADA. }
}

#badnick on
on *:join:#:{
  if ($me isop #) {
    if $ini($bfile,badnicks,$nick) { mode # +b $nick | kick # $nick Voce esta banido deste canal. (Badnick) }
  }
}

on *:nick:{
  if $ini($bfile,badnicks,$newnick) {
    var %y = 1
    while %y <= $comchan($newnick,0) {
      if ($me isop $comchan($newnick,%y)) {
        mode $comchan($newnick,%y) +b $newnick | kick $comchan($newnick,%y) $newnick Voce esta banido deste canal. (Badnick)
      }
      inc %y
    }
  }
}
#badnick end