# a szerver elérhetősége
host := 192.168.1.106
port := 7264
#home := /mentes/csillag/Canon/
home := /mentes/Canon/


#az aktuális nap lekérdezése a könyvtárnévhez
gettime time

home := ($home)($time.YEAR)($time.MONTH)($time.DAY)

# a home könyvtár létrehozása, ha nem létezik
exec mode; FALSE
exec mkdir -p $home
exec mode; TRUE

println Home könyvtár beállítása: $home
sethome $home

# az eszközök neveinek lekérdezése
getdevices $host; $port; devices

if $devices.size = 0 then
   println Egy eszköz sincs beállítva a szerverbe
   return
endif

to := $devices.size - 1

for i := 0 to $to

    println .$devices[$i]...

    if $devices[$i] = CCD Simulator || $devices[$i] = GPhoto CCD then

       println CCD beállítása: $devices[$i]
       ccd.set $host; $port; $devices[$i]
       ccd.connect

       if $devices[$i] = GPhoto CCD then

         # a fájlformátum átállítása CR2-re
         ccd.setprop Transfer Format; Native

       endif

    elseif $devices[$i] = Telescope Simulator || $devices[$i] = SynScan || $devices[$i] = EQMod Mount || $devices[$i] = LX200 Classic then

        println Mechanika beállítása: $devices[$i]
        mount.set $host; $port; $devices[$i]
        mount.connect


        if $devices[$i] = EQMod Mount || $devices[$i] = LX200 Classic then

          hotkey CTRL+UP; mount.north
	  hotkey CTRL+DOWN; mount.south
	  hotkey CTRL+RIGHT; mount.east
	  hotkey CTRL+LEFT; mount.west
	  hotkey CTRL+U; mount.slew_up
	  hotkey CTRL+D; mount.slew_down

        endif

        if $devices[$i] = EQMod Mount then

          # az óragép bekapcsolása
          mount.setprop TELESCOPE_TRACK_RATE; TRACK_SIDEREAL

        endif

    else
        println Ismeretlen eszköz: $devices[$i]
    endif

next

mount.addcatalog messier.txt
mount.addcatalog ngc.txt
mount.addcatalog Vend_alias.txt

mount.setprop GEOGRAPHIC_COORD; LAT; +47.442;
mount.setprop GEOGRAPHIC_COORD; LONG; +19.115;
mount.setprop GEOGRAPHIC_COORD; ELEV; 112;
mount.display GEOGRAPHIC_COORD

run.addfolder system