API tools faq
paste
Advertisement
Guest User

Untitled

a guest
May 28th, 2017
67
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
text 23.41 KB | None | 0 0
raw download clone embed print report
  1. //======================================================================================================
  2. //= Toasty's WoE Controller (formerly WoE Info Banner)
  3. //===== By: ============================================================================================
  4. //= ToastOfDoom (aka: iHeart)
  5. //===== Current Version: ===============================================================================
  6. //= 1.22
  7. //===== Description: ===================================================================================
  8. //= A WoE Controller function which controls castle based WoE by utilising npc events.
  9. //= Includes a NPC that provides information on the next WoE session
  10. //=
  11. //= This script is kinda @reloadscript/@loadnpc safe, provided that someone clicks the NPCs afterwards
  12. //= to start the OnInit function. That said..it is recommended that you don't use @reloadscript/@loadnpc
  13. //= but reset your server.
  14. //===== Changelog: =====================================================================================
  15. //= 1.22
  16. //= - Fixed an issue regarding the controller getting confused when using @reloadscript/loadnpc while
  17. //= WoE was still active. (thanks to annie for pointing out)
  18. //= 1.21
  19. //= - Fixed a misspelt variable name (thanks to rahuldev345 for pointing out)
  20. //= 1.20
  21. //= - Project renamed to 'Toasty's WoE Controller'. The script originally was only used to display WoE
  22. //= times then I 1st wrote it 3yrs ago and I feel it's purpose is more to control WoE these days. So
  23. //= name change to better reflect purpose.
  24. //= - Added support for novice WoE. Region teleport goes to the Novice Warper NPC (default in prontera)
  25. //= Change position in .region_maps, .region_x, .region_y if needed.
  26. //= - Region warp now only displays regions that have castles used at least once. (eg. If you don't
  27. //= configure any castles for Payon region, payon will not show up)
  28. //= - Optimised WoE Active/Inactive map notifier. Old method used too many loops for something that
  29. //= can happen alot.
  30. //= - Adjusted menus to be abit more friendly. 'next's will always display before 'menu's
  31. //= - Fixed bug with WoE autostarting when only configured for 2 sessions in one day
  32. //= - Added some nifty code that prevents catastrophic failure of the script if you try to run a trunk
  33. //= version on a stable server (ie. if you do, it will show an error message, but script will still
  34. //= run perfectly fine - check out WoEToggler function for those that want to peek at it =P)
  35. //= 1.11
  36. //= - Fixed timer glitch when players only configured sessions for one day of the week
  37. //= - Adjusted timer to show remaining time more accurately
  38. //= - Modified .num_woes calculation due to bug regarding 0's being counted as unset values in arrays
  39. //= 1.10
  40. //= - Expanded script to allow castle based configuration
  41. //= - Moved away from portal based woe control. Now using donpcevents to Onagitend/2 events. Provided
  42. //= castles are linked to the main agit commands in this manner, they will be controllable using this
  43. //= script.
  44. //= - Added an onLoadMap WoE available notifier. Can be disabled by setting .notify_woe to 0 in the
  45. //= CONFIG section.
  46. //= - Did some funky color coding.
  47. //= - Added Coordinate based warping per region (see .region_x & .region_y in the CONSTANTS section)
  48. //= 1.02
  49. //= - Added delwaitingroom to banner npc to prevent memory leaks from bug #2325
  50. //= - To reduce spamming of waitingroom packets to players banner NPC only now updates when the banner
  51. //= text changes. Thus min time between updates is now 1sec regardless of setting.
  52. //= - Added setting for rate which banner time is updated (.banner_refresh_rate) in the CONFIG section.
  53. //= - Added agitstart2/end2 to provide WoE2 support (Hope it works ^_^;)
  54. //= 1.01
  55. //= - Hardcoded in refresh value for banner npc instead of getting it from config from WoEInfoBase. Had
  56. //= issues starting the script after @reloadscript/@loadnpc
  57. //======================================================================================================
  58. - script WoEInfoBase -1,{
  59.  
  60. OnStartMenu:
  61. if(.init == 0)
  62. donpcevent strnpcinfo(3)+"::OnInit";
  63.  
  64. OnStartMenu2:
  65. mes "The " + ((.state)?"^00DD00current":"^DD0000next") + "^000000 WoE session is: ";
  66. mes " ";
  67. mes "Day: ^0000DD" + .daysOfWeek$[.woe_day[$@woe_index]];
  68. mes "^000000Start time: ^00DD00" + .woe_0_str$[$@woe_index];
  69. mes "^000000End time: ^DD0000" + .woe_1_str$[$@woe_index];
  70. mes "^000000Region:";
  71.  
  72. set .@state_strs$, "$@woe_state_str_" + $@woe_state[$@woe_index] + "$";
  73. for(set .@i, 0; .@i < .num_regions; set .@i, .@i + 1) {
  74. set .@output$, getd(.@state_strs$ + "[" + .@i + "]");
  75. if(.@output$ != "")
  76. mes "^000000- ^0000DD" + .@output$;
  77. }
  78. next;
  79.  
  80. if(getgmlevel() >= .gm_access)
  81. select(
  82. "Warp to Castle Grounds",
  83. "View Castle Owners",
  84. "View all WoE times",
  85. ((!.state)?"Start next WoE":"End current WoE"),
  86. ((.state)?"":"Skip next WoE session")
  87. );
  88. else
  89. select(
  90. "Warp to Castle Grounds",
  91. "View Castle Owners",
  92. "View all WoE times");
  93.  
  94. switch(@menu) {
  95. case 1: //warp
  96. mes "Which region would you like to warp to?";
  97. next;
  98. select(.region_warp$[$@woe_state[$@woe_index]]);
  99. if(@menu < 1 || @menu > .num_regions)
  100. close;
  101.  
  102. close2;
  103. warp .region_maps$[@menu - 1], .region_x[@menu - 1], .region_y[@menu - 1];
  104. end;
  105. case 2: //view
  106. set .@woe_state_array$, "$@woe_state_" + $@woe_state[$@woe_index];
  107. for(set .@i, 0; .@i < .num_regions; set .@i, .@i + 1) {
  108. set .@k, 0;
  109. set .@castles$, ".castles_" + .regions$[.@i] + "$";
  110. set .@castle_check, getd(.@woe_state_array$ + "[" + .@i + "]");
  111. while(.@castle_check && .@k < .num_castles[.@i]) {
  112. if(.@castle_check & (1 << .@k)) {
  113. set .@map$, getd(.@castles$+"["+.@k+"]");
  114. if (getcastledata(.@map$,1)) {
  115. dispbottom "The [" + getcastlename(.@map$) + "] castle of the [" + .region_names$[.@i] + "] region is currently held by the [" + getguildname(getcastledata(.@map$,1)) + "] guild.";
  116. } else {
  117. dispbottom "The [" + getcastlename(.@map$) + "] castle of the [" + .region_names$[.@i] + "] region is currently unoccupied.";
  118. }
  119. set .@castle_check, .@castle_check - (1 << .@k);
  120. }
  121. set .@k, .@k + 1;
  122. }
  123. }
  124. break;
  125. case 3: //woe times
  126. for(set .@i, 0; .@i < .num_woes; set .@i, .@i + 1) {
  127. dispbottom "- " + .daysOfWeek$[.woe_day[.@i]] + " " + .woe_0_str$[.@i] + "-" + .woe_1_str$[.@i];
  128. set .@woe_state_str_array$, "$@woe_state_str_" + $@woe_state[.@i] + "$";
  129. for(set .@k, 0; .@k < .num_regions; set .@k, .@k + 1) {
  130. set .@output$, getd(.@woe_state_str_array$ + "[" + .@k + "]");
  131. if(.@output$ != "")
  132. dispbottom " " + .@output$;
  133. }
  134. }
  135. break;
  136. case 4: //start next;
  137. if(getgmlevel() <.gm_access) close;
  138.  
  139. mes "^FF0000Are you sure you want to " + ((!.state)?"start the next WoE session?":"end the current WoE session?");
  140. next;
  141. if(select("Yes:No") == 2) break;
  142.  
  143. set .remaintime, 0; //might not work sometimes...you have like a 500ms window out of 505ms i guess..
  144. sleep2 .timer_refresh_rate; //wait abit so the menu doesn't screw up (how long it takes for the timer to update)
  145. break;
  146. case 5: //skip next;
  147. if(getgmlevel() <.gm_access || .state) close;
  148.  
  149. mes "^FF0000Are you sure you want to skip the next WoE session^000000";
  150. next;
  151. if(select("Yes:No") == 2) break;
  152. if(.state) { //you really can't do this with woe active
  153. next;
  154. mes "Sorry, in the time you took making your decision, WoE started";
  155. mes "Please either manually end it first or wait";
  156. break;
  157. }
  158. set $@woe_index, ($@woe_index + 1) % .num_woes;
  159. donpcevent strnpcinfo(3)+"::OnUpdateCountTick";
  160. sleep2 .timer_refresh_rate;
  161. break;
  162. default: close;
  163. }
  164. goto OnStartMenu2;
  165.  
  166. OnInit:
  167.  
  168. //-----------------------------------------------------------------------------------------//
  169. //CONFIG START //
  170. //-----------------------------------------------------------------------------------------//
  171.  
  172. set .gm_access, 60;
  173.  
  174. //WoE timings needs to be ordered ascendingly unless you want to do weird
  175. //stuff like skip a region every other week or so...
  176. //Also times can't overlap. Uses second of day(gettimetick(1)) for timing
  177. // eg 1am -> 3600, 2:30pm -> 52200, midnight -> 86400 (anything past that doesn't work)
  178. //Note: woe_0 is start times, woe_1 is end times. Ignore how it's called but
  179. // don't change it either since it's dynamically used
  180. // Also..woe has to end on the same day it starts (it's easier that way..)
  181. setarray .woe_day[0], 0, 1, 2, 3, 4, 5, 6;
  182. setarray .woe_0[0], 75600,75600,75600,75600,75600,75600,75600;
  183. setarray .woe_1[0], 81000,81000,81000,81000,81000,81000,81000;
  184. setarray $@woe_state[0], 0, 1, 2, 0, 1, 2, 0;
  185.  
  186. //WoE state settings. Every WoE session can be defined as a particular state of castle configuration.
  187. //$@woe_state_#[%] = $
  188. // # - state number
  189. // % - region number
  190. // $ - binary representation of castles that are active for that region in that state (
  191. // (ie. 0 is no castles, 5 is castle 0 and 2 (2^0 + 2^2 = 5))
  192. setarray $@woe_state_0[0],1,8,8,16,0,0,0;
  193. setarray $@woe_state_1[0],0,2,0,2,0,0,0;
  194. setarray $@woe_state_2[0],1,1,2,4,0,0,0;
  195.  
  196. //Setting for if script handles WoE controller function. Disable agit_controller.txt if you are using this.
  197. //For if you want to use something else to handle your woe stuff but only this script
  198. //to show info (1 - on, 0 - off...duh)
  199. set .active_woe, 1;
  200.  
  201.  
  202. //WoE inactive on map notifier. Basically notifies player if the castle they are entering is
  203. //WoE active or not
  204. set .notify_woe, 1;
  205.  
  206. //-----------------------------------------------------------------------------------------//
  207. //CONFIG END //
  208. //-----------------------------------------------------------------------------------------//
  209.  
  210.  
  211. //-----------------------------------------------------------------------------------------//
  212. //CONSTANTS START - Don't touch this unless you know what you are doing //
  213. //-----------------------------------------------------------------------------------------//
  214.  
  215. //castle maps by region
  216. setarray .castles_prtg$[0],"prtg_cas01","prtg_cas02","prtg_cas03","prtg_cas04","prtg_cas05";
  217. setarray .castles_payg$[0],"payg_cas01","payg_cas02","payg_cas03","payg_cas04","payg_cas05";
  218. setarray .castles_gefg$[0],"gefg_cas01","gefg_cas02","gefg_cas03","gefg_cas04","gefg_cas05";
  219. setarray .castles_aldeg$[0],"aldeg_cas01","aldeg_cas02","aldeg_cas03","aldeg_cas04","aldeg_cas05";
  220. setarray .castles_arug$[0],"arug_cas01","arug_cas02","arug_cas03","arug_cas04","arug_cas05";
  221. setarray .castles_schg$[0],"schg_cas01","schg_cas02","schg_cas03","schg_cas04","schg_cas05";
  222. setarray .castles_novi$[0],"nguild_alde","nguild_gef","nguild_pay","nguild_prt";
  223.  
  224. //woe kill functions for each castle
  225. setarray .woe_kill_prtg$[0],"Agit#prtg_cas01::Onagitend","Agit#prtg_cas02::Onagitend","Agit#prtg_cas03::Onagitend","Agit#prtg_cas04::Onagitend","Agit#prtg_cas05::Onagitend";
  226. setarray .woe_kill_payg$[0],"Agit#payg_cas01::Onagitend","Agit#payg_cas02::Onagitend","Agit#payg_cas03::Onagitend","Agit#payg_cas04::Onagitend","Agit#payg_cas05::Onagitend";
  227. setarray .woe_kill_gefg$[0],"Agit#gefg_cas01::Onagitend","Agit#gefg_cas02::Onagitend","Agit#gefg_cas03::Onagitend","Agit#gefg_cas04::Onagitend","Agit#gefg_cas05::Onagitend";
  228. setarray .woe_kill_aldeg$[0],"Agit#aldeg_cas01::Onagitend","Agit#aldeg_cas02::Onagitend","Agit#aldeg_cas03::Onagitend","Agit#aldeg_cas04::Onagitend","Agit#aldeg_cas05::Onagitend";
  229. setarray .woe_kill_arug$[0],"Manager#aru01_02::Onagitend2","Manager#aru02_02::Onagitend2","Manager#aru03_02::Onagitend2","Manager#aru04_02::Onagitend2","Manager#aru05_02::Onagitend2";
  230. setarray .woe_kill_schg$[0],"Manager#sch01_02::Onagitend2","Manager#sch02_02::Onagitend2","Manager#sch03_02::Onagitend2","Manager#sch04_02::Onagitend2","Manager#sch05_02::Onagitend2";
  231. setarray .woe_kill_novi$[0],"Agit_N01::Onagitend","Agit_N02::Onagitend","Agit_N03::Onagitend","Agit_N04::Onagitend";
  232.  
  233. //region prefixs
  234. setarray .regions$[0],"prtg","payg","gefg","aldeg","arug","schg","novi";
  235.  
  236. //region info
  237. setarray .region_names$[0],"Prontera", "Payon", "Geffen", "Aldebaran", "Arunafeltz", "Schwarzwald", "Novice Castles";
  238. setarray .region_maps$[0],"prt_gld", "pay_gld", "gef_fild13", "alde_gld", "aru_gld", "sch_gld", "prontera";
  239. //coords to warp player to region (0 is random)
  240. setarray .region_x[0],0, 0, 0, 0, 0, 0, 148;
  241. setarray .region_y[0],0, 0, 0, 0, 0, 0, 163;
  242.  
  243. setarray .waitMsg$[0], "WoE Starts: ", "WoE Ends: ";
  244. setarray .startMsg$[0], "WoE is Starting", "WoE is Ending";
  245.  
  246. set .ticks_in_day, 86400; //mmm...magic numbers
  247. setarray .daysOfWeek$[0], "Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday";
  248.  
  249. set .timer_refresh_rate, 500; //how many ms per timer refresh...keep less than 1000 (in milliseconds)
  250. set .change_state_sleep, 3000; //how long to show "WoE is Start|End-ing" msg for in ms. (in milliseconds)
  251. //Make sure WoE sessions are longer than this xD
  252. set .banner_refresh_rate, 10; //how many seconds per banner refresh...keep 1 or above (in seconds)
  253.  
  254. //-----------------------------------------------------------------------------------------//
  255. //CONSTANTS END //
  256. //-----------------------------------------------------------------------------------------//
  257.  
  258. set .num_regions, getarraysize(.regions$);
  259. set .num_woes, getarraysize(.woe_1);
  260.  
  261. //force WoE to end if active
  262. callfunc "WoEToggler", 0;
  263.  
  264. for(set .@i, 0; .@i < .num_regions; set .@i, .@i + 1) {
  265. //count num castles per region
  266. set .num_castles[.@i], getarraysize(getd(".castles_" + .regions$[.@i] + "$"));
  267. }
  268.  
  269. //convert timestamps to readable format
  270. for(set .@i, 0; .@i < .num_woes; set .@i, .@i + 1)
  271. {
  272. set .@hrs, .woe_0[.@i] / 3600;
  273. set .@mins, .woe_0[.@i] % 3600 / 60;
  274. set .@output$, ((.@hrs % 12)?.@hrs%12:12) + ":" + ((.@mins < 10)?"0"+.@mins:.@mins) + " " + ((.@hrs > 12)?"PM":"AM");
  275.  
  276. set .woe_0_str$[.@i], .@output$;
  277.  
  278. set .@hrs, .woe_1[.@i] / 3600;
  279. set .@mins, .woe_1[.@i] % 3600 / 60;
  280. set .@output$, ((.@hrs % 12)?.@hrs%12:12) + ":" + ((.@mins < 10)?"0"+.@mins:.@mins) + " " + ((.@hrs > 12)?"PM":"AM");
  281.  
  282. set .woe_1_str$[.@i], .@output$;
  283. }
  284.  
  285. //calc number of woe states and consolidate states to create list of castles used
  286. set .num_states, 0;
  287. while(getarraysize(getd("$@woe_state_" + (.num_states)))) {
  288. set .@state$, "$@woe_state_" + .num_states;
  289. set .@i, 0;
  290. while(.@i < getarraysize(getd(.@state$))) {
  291. set .castleUsage[.@i], .castleUsage[.@i] | getd(.@state$ + "[" + .@i + "]");
  292. set .@i, .@i + 1;
  293. }
  294. set .num_states, .num_states + 1;
  295. }
  296.  
  297. for(set .@i, 0; .@i < .num_states; set .@i, .@i + 1) {
  298. set .@woe_state_array$, "$@woe_state_" + .@i;
  299. for(set .@k, 0; .@k < .num_regions; set .@k, .@k + 1) {
  300. if(.castleUsage[.@k] > 0) {
  301. set .@castles$, ".castles_" + .regions$[.@k] + "$";
  302. set .@castle_check, getd(.@woe_state_array$ + "[" + .@k + "]");
  303. if(.@castle_check == 0) { //region not in this state
  304. //region warp menu string
  305. set .region_warp$[.@i], .region_warp$[.@i] + "^DD0000" + .region_names$[.@k] + "^000000:";
  306. continue;
  307. } else {
  308. if(.@castle_check >= ((1 << .num_castles[.@k]) - 1)) {
  309. //includes all castles...just list as region.
  310. setd("$@woe_state_str_" + .@i + "$[" + .@k + "]", .region_names$[.@k]);
  311.  
  312. //region warp menu string
  313. set .region_warp$[.@i], .region_warp$[.@i] + "^00DD00" + .region_names$[.@k] + "^000000:";
  314. } else {
  315. set .@j, 0;
  316. set .@output$, "";
  317. while(.@j < .num_castles[.@k]) {
  318. if(.@castle_check & (1 << .@j)) {
  319. set .@output$, .@output$ + getcastlename(getd(.@castles$+"["+.@j+"]"));
  320. set .@castle_check, .@castle_check - (1 << .@j);
  321. if(.@castle_check) {
  322. if(.@output$ != "")
  323. set .@output$, .@output$ + ", ";
  324. } else
  325. break;
  326. }
  327. set .@j, .@j + 1;
  328. }
  329. setd("$@woe_state_str_" + .@i + "$[" + .@k + "]", .region_names$[.@k] + " ("+ .@output$ + ")");
  330.  
  331. //region warp menu string
  332. set .region_warp$[.@i], .region_warp$[.@i] + "^00DD00" + .region_names$[.@k] + " ("+ .@output$ + ")^000000:";
  333. }
  334. }
  335. } else {
  336. set .region_warp$[.@i], .region_warp$[.@i] + ":";
  337. }
  338. }
  339. }
  340.  
  341. donpcevent strnpcinfo(3)+"::OnFindCurIndex";
  342. donpcevent strnpcinfo(3)+"::OnUpdateCountTick";
  343.  
  344. if(.active_woe) {
  345. if(.notify_woe) {
  346. //set mapflag for all castle maps
  347. for(set .@i, 0; .@i < .num_regions; set .@i, .@i + 1) {
  348. set .@region_array$, ".castles_" + .regions$[.@i] + "$";
  349. for(set .@k, 0; .@k < .num_castles[.@i]; set .@k, .@k + 1) {
  350. setmapflag getd(.@region_array$ + "[" + .@k + "]"), mf_loadevent;
  351. setd("$@loadmap_region_" + getd(.@region_array$ + "[" + .@k + "]"), .@i + 1);
  352. setd("$@loadmap_castleIndex_" + getd(.@region_array$ + "[" + .@k + "]"), .@k);
  353. }
  354. }
  355. }
  356. //activates WoE if needed
  357. donpcevent strnpcinfo(3)+"::OnDoWoE";
  358. }
  359. //flag that init occured
  360. set .init, 1;
  361.  
  362. OnWoETimer:
  363. //timer stuff
  364. while (1) {
  365. set .remaintime, .count_tick - gettimetick(2);
  366. set .bannerTimer, .remaintime - (.remaintime % .banner_refresh_rate) + .banner_refresh_rate;
  367. set .min, .bannerTimer / 60;
  368. set .sec, .bannerTimer - .min * 60;
  369. set .hr, .min / 60;
  370. set .min, .min - .hr * 60;
  371. set .roomMsg$, .waitMsg$[.state] + .hr + ":" + ((.min < 10 )?"0":"") + .min + ":" + ((.sec < 10 )?"0":"") + .sec;
  372. sleep .timer_refresh_rate;
  373.  
  374. if(.remaintime <= 0) {
  375. if(.active_woe) {
  376. donpcevent strnpcinfo(3)+"::OnDoWoE";
  377. }
  378. set .roomMsg$, .startMsg$[.state];
  379.  
  380. set $@woe_index, ($@woe_index + .state) % .num_woes; //go to next index if needed
  381. set .state, (.state + 1) % 2; //flip state
  382.  
  383. donpcevent strnpcinfo(3)+"::OnUpdateCountTick";
  384. sleep .change_state_sleep;
  385. }
  386. }
  387. end; //obligatory end =D
  388.  
  389. OnUpdateCountTick:
  390. set .count_tick, getd(".woe_" + .state + "[" + $@woe_index + "]");
  391. set .count_tick, gettimetick(2) + .count_tick - gettimetick(1) + (.woe_day[$@woe_index] - gettime(4) + 7) % 7 * .ticks_in_day;
  392.  
  393. if(gettimetick(2) > .count_tick)
  394. set .count_tick, .count_tick + 7 * .ticks_in_day;
  395. end;
  396.  
  397. OnFindCurIndex:
  398.  
  399. set .@cur_day, gettime(4);
  400. set .@cur_tick, gettimetick(1);
  401.  
  402. set $@woe_index, 0;
  403. set .state, 0;
  404.  
  405. for(set .@i, 0; .@i < .num_woes; set .@i, .@i + 1) {
  406. if(.woe_day[.@i] < .@cur_day)
  407. continue;
  408.  
  409. if(.woe_day[.@i] == .@cur_day) {
  410. if(.woe_0[.@i] >= .@cur_tick) {
  411. set $@woe_index, .@i;
  412. set .state, 0;
  413. break;
  414. }
  415. if(.woe_1[.@i] >= .@cur_tick) {
  416. set $@woe_index, .@i;
  417. set .state, 1;
  418. break;
  419. }
  420. }
  421. if(.woe_day[.@i] > .@cur_day) {
  422. set $@woe_index, .@i;
  423. set .state, 0;
  424. break;
  425. }
  426. }
  427. end;
  428.  
  429. //On map notifier
  430. //Comment out OnPCLoadMapEvent label if .notify_woe is disabled to prevent unnecessary triggering
  431. OnPCLoadMapEvent:
  432. if(.state && .notify_woe) {
  433. getmapxy(.@map$, .@x, .@y, 0);
  434. set .@region, getd("$@loadmap_region_" + .@map$) - 1;
  435. if(.@region >= 0) {
  436. set .@castleIndex, getd("$@loadmap_castleIndex_" + .@map$);
  437. if(getd("$@woe_state_" + $@woe_state[$@woe_index] + "[" + .@region + "]") & 1 << .@castleIndex)
  438. dispbottom "The [" + getcastlename(.@map$) + "] castle is available for conquering during this WoE session";
  439. else
  440. dispbottom "The [" + getcastlename(.@map$) + "] castle is NOT available for conquering during this WoE session";
  441. }
  442. }
  443. end;
  444.  
  445. //------------------------------------------------------------------------------
  446. // WoE Controller Stuff Here
  447. //------------------------------------------------------------------------------
  448.  
  449. OnDoWoE:
  450. if((.state == 0 && .init) || (.state == 1 && !agitcheck())) { //starting
  451. callfunc "WoEToggler", 1;
  452.  
  453. //kills WoE in all castles that shouldn't have WoE
  454. set .@woe_state_array$, "$@woe_state_" + $@woe_state[$@woe_index];
  455. for(set .@i, 0; .@i < .num_regions; set .@i, .@i + 1) {
  456. set .@castles$, ".castles_" + .regions$[.@i] + "$";
  457. set .@castle_check, getd(.@woe_state_array$ + "[" + .@i + "]");
  458.  
  459. for(set .@k, 0; .@k < .num_castles[.@i]; set .@k, .@k + 1) {
  460. set .@map$, getd(.@castles$+"["+.@k+"]");
  461. if((.@castle_check & (1 << .@k)) == 0) {
  462. donpcevent getd(".woe_kill_" + .regions$[.@i] + "$[" + .@k + "]");
  463. }
  464. }
  465. }
  466.  
  467. announce "The War Of Emperium has begun!",bc_all;
  468. donpcevent strnpcinfo(3)+"::OnDisplayOwners";
  469. } else { //ending
  470. if(agitcheck()) {
  471. callfunc "WoEToggler", 0;
  472. announce "The War Of Emperium is over!",bc_all;
  473. donpcevent strnpcinfo(3)+"::OnDisplayOwners";
  474. }
  475. }
  476. end;
  477.  
  478. OnDisplayOwners: //displays based on current region
  479. set .@woe_state_array$, "$@woe_state_" + $@woe_state[$@woe_index];
  480. for(set .@i, 0; .@i < .num_regions; set .@i, .@i + 1) {
  481. set .@k, 0;
  482.  
  483. set .@castle_check, getd(.@woe_state_array$ + "[" + .@i + "]");
  484. set .@castles$, ".castles_" + .regions$[.@i] + "$";
  485.  
  486. while(.@castle_check && .@k < .num_castles[.@i]) {
  487. if(.@castle_check & (1 << .@k)) {
  488. set .@map$, getd(.@castles$+"["+.@k+"]");
  489. if (getcastledata(.@map$,1)) {
  490. announce "The [" + getcastlename(.@map$) + "] castle of the [" + .region_names$[.@i] + "] region is currently held by the [" + getguildname(getcastledata(.@map$,1)) + "] guild.",bc_all;
  491. } else {
  492. announce "The [" + getcastlename(.@map$) + "] castle of the [" + .region_names$[.@i] + "] region is currently unoccupied.",bc_all;
  493. }
  494. set .@castle_check, .@castle_check - (1 << .@k);
  495. }
  496. set .@k, .@k + 1;
  497. }
  498. }
  499. end;
  500. }
  501. prontera,200,180,6 script WoE Info 2_BULLETIN_BOARD,{
  502. if(getwaitingroomstate(3, strnpcinfo(3)) == -1)
  503. donpcevent strnpcinfo(3)+"::OnInit";
  504.  
  505. doevent "WoEInfoBase::OnStartMenu";
  506. end;
  507.  
  508. OnInit:
  509. while (1) {
  510. //only updates if msg is different
  511. set .banner$, getwaitingroomstate(4, strnpcinfo(3));
  512. if(getvariableofnpc(.roomMsg$, "WoEInfoBase") != .banner$) {
  513. delwaitingroom;
  514. waitingroom getvariableofnpc(.roomMsg$, "WoEInfoBase"), 0;
  515. }
  516. sleep 500;
  517. }
  518. end;
  519. }
  520.  
  521. //zomg! it duplicates!!
  522. //prontera,156,196,6 duplicate(WoE Info) WoE Info#2winfo 837
  523.  
  524. //---------------------------------------------------------------------------------------------------------------------
  525.  
  526. //These two functions handle WoE's activation/deactivation. Since stable does not have agitstart2/agitend2,
  527. //using the trunk version will result in catastrophic failure of the script. Double declaration of the following
  528. //functions fixes this (you will get warning messages though)
  529.  
  530. //if stable script will fail parsing this function, but the rest of the script will still be usable
  531. function script WoEToggler { //<state> = 0|1
  532. if(getarg(0)) {
  533. agitstart;
  534. agitstart2;
  535. } else {
  536. agitend;
  537. agitend2;
  538. }
  539. return;
  540. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!