exit
                    lda  #$00
                    tax
@                   sta  pmb+$400,x
                    sta  pmb+$500,x
                    sta  pmb+$600,x
                    sta  pmb+$700,x
                    inx
                    bne  @-

                    ldy  #0
@                   lda  col_fadeout,y
                    sta  COLOR1
                    jsr  wait5
                    iny
                    cpy  #15
                    bne  @-

                    lda  #$00                     ; revoke P/M
                    sta  GRACTL

                    lda  #$40                     ; disable DLI interrupts
                    sta  NMIEN

                    lda  #$ff                     ; reset keyboard
                    sta  CH

                    lda  #$e0                     ; restore default font
                    sta  CHBAS

                    jsr  wait5

                    ldy  #14
@                   jsr  wait5
                    lda  RMTGLOBALVOLUMEFADE
                    add  #$10
                    sta  RMTGLOBALVOLUMEFADE
                    dey
                    bne  @-

                    jsr  RASTERMUSICTRACKER+9
                    jsr  wait
                    jsr  wait

                    lda  #$07
                    ldy  save_vvblkd
                    ldx  save_vvblkd+1
                    jsr  SETVBV

                    jsr  wait
                    jsr  gr0

                    lda  save_color0
                    sta  COLOR0
                    lda  save_color1
                    sta  COLOR1
                    lda  save_color2
                    sta  COLOR2
                    lda  save_color3
                    sta  COLOR3
                    lda  save_color4
                    sta  COLOR4

                    jsr  wait
                    jsr  wait

                    jmp  ($000a)


ename               .byte "E:",$9b

gr0                 ldx  #$00        ;zamkniecie IOCB #0
                    lda  #$0c        ;CLOSE
                    jsr  xcio

                    lda  <ename
                    sta  icbufa,x
                    lda  >ename
                    sta  icbufa+1,x
                    lda  #$0c        ;READ/WRITE
                    sta  icax1,x
                    lda  #$00
                    sta  icax2,x
                    lda  #$03        ;OPEN
xcio                sta  iccmd,x
                    jmp  $E456


; --------------------------------------------------------------------------------------

                    org  fonts