@ECHO OFF

GoTo FixPath

:Author
REM "CREATED BY WILL“
REM “10 JUNE 2015”
REM “BASED ON SCRIPT BY ALON.OR AT https://social.technet.microsoft.com/Forums/windows/en-US/425bd101-8a87-488c-b2e2-9f2f8113a0d9/sysprep-fatal-error-occurred-while-trying-to-sysprep-the-machine?forum=w7itproinstall”

:Requires
REM This Script Requires psexec From https://technet.microsoft.com/en-us/sysinternals/bb897553.aspx
REM Simply Drop psexec In The Path Stated Below

:FixPath
REM "Change Directory To Virtual Drive As CMD Does NOT Support UNC Paths
REM Set This Path To Where This Script And psexec Is Located
pushd "\\Imaging\Windows 7\SysPrep"
cls

TITLE SysPrep - Shutdown
Color FC
echo PLEASE READ ALL THE INSTRUCTIONS!
echo.
echo This process can take up to 5 minutes. Please be patient.
echo.
echo DO NOT CLOSE THIS WINDOW OR SHUTDOWN THE COMPUTER DURING THIS PROCESS!
echo.
echo YOUR COMPUTER WILL AUTOMATICALLY SHUT-DOWN ONCE SYSPREP FINISHES
echo.

echo **************Preparing Computer For SysPrep******************
echo.

REM Verify The User Has Admin Rights
"%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system" >nul 2>&1
if errorlevel 1 echo *** ERROR: SysPrep Requires Admin Rights *** && echo. && pause && exit

REM Stop Windows Media Player Sharing Service - Known To Cause Major SysPrep Issues
echo Stopping Windows Media Player Sharing Service
echo.
net stop wmpnetworksvc >NUL  2>NUL
echo.

REM Lets Get Clean SysPrep Logs In Case Something Goes Wrong
echo Deleting Old Sysprep Logs
echo.
del /f /s /q %windir%\System32\sysprep\panther\*.* >NUL  2>NUL
echo.

REM Fix Known Registry Problems
echo Adding Required SysPrep Registry Keys
echo.

REM Do NOT Try and Rearm Windows Activation
REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SoftwareProtectionPlatform" /v SkipRearm /t REG_DWORD /d 00000001 /f >NUL  2>NUL

REM GeneralizationState Must Be Set To Value Of 7
REG ADD HKLM\SYSTEM\Setup\Status\SysprepStatus /v GeneralizationState /t REG_DWORD /d 00000007 /f >NUL  2>NUL

REM CleanUpState Must Be Set To Value Of 2
REG ADD HKLM\SYSTEM\Setup\Status\SysprepStatus /v CleanupState /t REG_DWORD /d 00000002 /f >NUL  2>NUL

REM WorkAround Known IE Bug - Repair Bad Paths
psexec -accepteula -i -s REG ADD HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Setup\Sysprep\Cleanup /v "{EC9FE15D-99DD-4FB9-90D5-5B56E42A0F80}" /t REG_SZ /d "C:\Windows\System32\iesysprep.dll,Sysprep_Cleanup_IE" /f >NUL  2>NUL
psexec -accepteula -i -s REG ADD HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Setup\Sysprep\Generalize /v "{EC9FE15D-99DD-4FB9-90D5-CE53C91AB9A1}" /t REG_SZ /d "C:\Windows\System32\iesysprep.dll,Sysprep_Cleanup_IE" /f >NUL  2>NUL
psexec -accepteula -i -s REG ADD HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Setup\Sysprep\Specialize /v "{EC9FE15D-99DD-4FB9-90D5-676C338DC1DA}" /t REG_SZ /d "C:\Windows\System32\iesysprep.dll,Sysprep_Cleanup_IE" /f >NUL  2>NUL

REM Not Sure What This Key Does But It Was Causing SysPrep To Fail - Check Logs In “%windir%\System32\sysprep\panther”
psexec -accepteula -i -s REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Setup\Sysprep\Generalize /v "{68595905-7ae9-f26e-af73-72df2987e480}" /f >NUL  2>NUL

REM Reinstalling Microsoft Distributed Transaction Coordinator As It’s Known To Cause A Major Problem While Trying To SysPrep
echo.
echo Uninstalling MSDTC...
echo.
msdtc -uninstall >NUL  2>NUL
timeout 5
echo.
echo Reinstalling MSDTC...
echo.
msdtc -install >NUL  2>NUL
timeout 5
echo.
echo Running SysPrep
echo.
%windir%\System32\sysprep\sysprep /generalize /oobe /shutdown >NUL  2>NUL
exit