MIDIdistributor

#include "charlesMIDI.h"

// You cannot change the



MidiWord currentMessage;

MCArray midiChArray;

// set midi in to Channel 1,  unfortunately because of all the
// "greater than" and "less than" logic, you cannot change the midi input channel
const byte MIDI_IN_CHANNEL = 0x00;

// these define the channel status feedback pins
// they go high when the channel is currently playing a note

const int ledChOne = 5;
const int ledChTwo = 6;
const int ledChThree =7;
const int ledChFour = 8;

// these deifne the number of channels to distribute the midi commands to
// if 3 HIGH then 4 Channels, if 4 HIGH then 2 Channels, no HIGH: 3 Channels
// allows use of a simple center off switch to control 3 options
const int selectPinOne = 3;
const int selectPinTwo = 4;

// these define the pins used to select the priority algorithm
// if pin 2 is high, then drop note by time, if pin 9 is high then drop high note.
// if no pins high, MONO MODE
const int modeSelectOne = 2;
const int modeSelectTwo = 9;

void setup(){
  // MIDI baud rate
  Serial.begin(31250);
  pinMode(ledChOne, OUTPUT);
  pinMode(ledChTwo, OUTPUT);
  pinMode(ledChThree, OUTPUT);
  pinMode(ledChFour, OUTPUT);

  pinMode(selectPinOne, INPUT);
  pinMode(selectPinTwo, INPUT);
  pinMode(modeSelectOne, INPUT);
  pinMode(modeSelectTwo, INPUT);

}
void loop(){

  // tempCh is passed into function to return channel the note shall be played on
  byte tempCh;

  // initialize current command, used to store current midi command
  byte currentCommand = 0x00;

  // check how many channels are in play
  byte numberOfChannels = getNumberOfChannels();

  // read capture midi "word"
  currentMessage.getWord();

  // get the current midi command from incoming word
  currentCommand = currentMessage.getCommand();

  // if pitch bend command outside of the range channels, just send it on through
  if(currentCommand >= 0xE0 + numberOfChannels){
    currentMessage.writeWord();
  }
  // if pitch bend for receive channel. bend all notes.
  else if (currentCommand == 0xE0){
    for(int i = 0x00; i < numberOfChannels; i++){
      currentMessage.writeWord(i);
    }
  }

  // if it is a command for a channel that our distributor does not occupy
  // send it on through
  else if(currentCommand >= noteOff + numberOfChannels && currentCommand < noteOn){
    currentMessage.writeWord();
  }
  else if(currentCommand >= noteOn + numberOfChannels){
    currentMessage.writeWord();
  }

  // if mono mode is engaged. send message out on all selected channels
  else if(!digitalRead(modeSelectOne) && !digitalRead(modeSelectTwo)){
    for(int i = 0x00; i < numberOfChannels; i++){
      currentMessage.writeWord(i);
     updateLEDs(currentMessage, i, ledChOne, ledChTwo, ledChThree, ledChFour);
    }
  }

  // for all non-mono-mode midi messages
  else if(currentCommand == noteOn + MIDI_IN_CHANNEL){
   // kill note is used in case when all channels are currently playing a note
   // one of those notes must be dropped,  this is the kill note.
   MidiWord killNote;
   // checks the switch status for sort algorithm
   if(digitalRead(modeSelectOne)){
    tempCh = midiChArray.nextNotePlayTime(killNote, numberOfChannels);
   }
   else if(digitalRead(modeSelectTwo)){
     tempCh = midiChArray.nextNotePlayPitch(killNote, numberOfChannels);
   }
   killNote.writeWord(tempCh);
   currentMessage.writeWord(tempCh);
   midiChArray.updateStatus(currentMessage, tempCh);
   updateLEDs(currentMessage, tempCh, ledChOne, ledChTwo, ledChThree, ledChFour);
  }

  // regular mode note off
  else if(currentCommand == noteOff + MIDI_IN_CHANNEL){
    tempCh = midiChArray.noteOffMatch(currentMessage.getPitch());
    currentMessage.writeWord(tempCh);
    midiChArray.updateStatus(currentMessage, tempCh);
    updateLEDs(currentMessage, tempCh, ledChOne, ledChTwo, ledChThree, ledChFour);
  }



}

boolean flipState(boolean current){
  if(current){
    return LOW;
  }
  else{
    return HIGH;
  }
}

void updateLEDs(const MidiWord& inWord, const byte& tempCh, const int& ledChOne, const int& ledChTwo, const int& ledChThree, const int& ledChFour){
  byte inCommand = inWord.getCommand();
  if(inCommand == noteOn){
    switch (tempCh){
      case 0x00:
      digitalWrite(ledChOne, HIGH);
      break;
      case 0x01:
      digitalWrite(ledChTwo, HIGH);
      break;
      case 0x02:
      digitalWrite(ledChThree, HIGH);
      break;
      case 0x03:
      digitalWrite(ledChFour, HIGH);
      break;
    }
  }
    if(inCommand == noteOff){
    switch (tempCh){
      case 0x00:
      digitalWrite(ledChOne, LOW);
      break;
      case 0x01:
      digitalWrite(ledChTwo, LOW);
      break;
      case 0x02:
      digitalWrite(ledChThree, LOW);
      break;
      case 0x03:
      digitalWrite(ledChFour, LOW);
      break;
    }
  }
}

byte getNumberOfChannels(){
  if(digitalRead(selectPinOne)){
    return 0x04;
  }
  else if(digitalRead(selectPinTwo)){
    return 0x02;
  }
  else{
    return 0x03;
  }
}