* Delineamento e Análise de Experimentos 1
* Assunto: Análise de Covariância
* Exemplos: Kuehl, capitulo 17
* Professor: George Freitas von Borries;

TITLE '';

* EXEMPLO 17.1 - EFEITOS DE EXERCICIO NA CAPACIDADE CARDIOVASCULAR;

TITLE 'EXEMPLO 17.1 - CARDIOVASCULAR';

DATA VENT;
  INPUT GRUPO IDADE Y @@;
  IDADE_C = IDADE - 24.5;
  DATALINES;
1 31 17.05 1 23 4.96 1 27 10.40 1 28 11.05 1 22 0.26 1 24 2.51
2 23 -0.87 2 22 -10.74 2 22 -3.27 2 25 -1.97 2 27 7.50 2 20 -7.25
;

ODS GRAPHICS ON;

PROC GLM DATA=VENT;
  CLASS GRUPO;
  MODEL Y = IDADE_C GRUPO;
  LSMEANS GRUPO / PDIFF STDERR;
RUN;
QUIT;

PROC GLM DATA=VENT;
  CLASS GRUPO;
  MODEL Y = GRUPO;
RUN;

PROC GLM DATA=VENT;
  MODEL Y = IDADE_C;
RUN;

* EXEMPLO 17.2 - PERCEPção AUDITIVA;

TITLE 'EXEMPLO 17.2 - AUDITIVA';

DATA AUDIO1;
  INPUT PRETESTE GANHO @@;
  CULTURA = 1;
  PT_C  = PRETESTE - 51.8;
  PT_CC = PRETESTE - 55.8;
  DATALINES;
 64 7 39 32 69 2 56 20 67 4 39 26 32 34 62 8 64 4 66 2
;

DATA AUDIO2;
  INPUT PRETESTE GANHO @@;
  CULTURA = 2;
  PT_C  = PRETESTE - 51.8;
  PT_CC = PRETESTE - 47.8;
  DATALINES;
52 2 50 12 59 6 42 10 62 1 35 9 41 6 36 8 37 8 64 6
;

DATA AUDIO;
  SET AUDIO1 AUDIO2;
RUN;

PROC GLM DATA=AUDIO;
  CLASS CULTURA;
  MODEL GANHO = PT_C CULTURA;
RUN;

PROC GLM DATA=AUDIO;
  MODEL GANHO = PT_C;
  BY CULTURA;
RUN;

PROC GLM DATA=AUDIO;
  CLASS CULTURA;
  MODEL GANHO = PT_C CULTURA PT_C*CULTURA / SOLUTION;
RUN;
QUIT;

* EXEMPLO 17.3 - DISPOSIÇÃO DE NUTRIENTES COM CEVADA EM CASA DE VEGETAÇÃO;

TITLE 'EXEMPLO 17.3 - NUTRIENTES';

DATA NUTRIENTES;
  DO TRT="C", "F", "N0", "P0";
    DO BLOCO = 1 TO 5;
      INPUT Y X @@;
      OUTPUT;
    END;
  END;
  DATALINES;
23.1 13 20.9 12 28.3 7 25.0 9 25.1 8
30.1 7 31.8 5 32.4 6 30.6 7 27.5 9
26.4 10 27.2 9 28.6 6 28.5 6 30.8 5
26.2 8 25.3 9 29.7 7 26.0 7 24.9 9
;

PROC GLM DATA=NUTRIENTES;
  CLASS TRT BLOCO;
  MODEL Y = X BLOCO TRT;
  LSMEANS TRT / STDERR PDIFF;
RUN;
QUIT;

ODS GRAPHICS OFF;